qtwebengine: disable autodetection from sysroot

* couple dependencies were autodetected from sysroot, e.g.:
  WARNING: QA Issue: qtwebengine rdepends on libflac, but it isn't a build dependency? [build-deps]
* bundled nspr fails to build when system nss is used
  | work/i586-oe-linux/qtwebengine/5.5.99+5.6.0-alpha1+gitAUTOINC+64dc919d31_7e655fbb76-r0/git/src/3rdparty/chromium/third_party/nss/nspr/pr/include/md/_unixos.h:596:9: error: unknown type name 'off64_t'
  |  typedef off64_t _MDOff64_t;
  |          ^
* addin qtlocation to resolve:
  WARNING: Failure to find: git/src/core/Release/obj/src/core/QtWebEngineCore.location_provider_qt.o

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>

1 files changed, 24 insertions, 0 deletions

diff --git a/recipes-qt/qt5/qtwebengine_git.bb b/recipes-qt/qt5/qtwebengine_git.bb
index 0d6cd8f4..957931f8 100644
--- a/recipes-qt/qt5/qtwebengine_git.bb
+++ b/recipes-qt/qt5/qtwebengine_git.bb
@@ -13,6 +13,7 @@ DEPENDS += " \
     ninja-native \
     qtwebchannel \
     qtbase qtdeclarative qtxmlpatterns qtquickcontrols \
+    qtlocation \
     libdrm fontconfig pixman openssl pango cairo icu pciutils \
     libcap \
 "
@@ -26,6 +27,21 @@ DEPENDS += "${@base_contains('DISTRO_FEATURES', 'x11', 'libxscrnsaver', '', d)}"
 DEPENDS += "yasm-native"
 EXTRA_QMAKEVARS_PRE += "GYP_CONFIG+=use_system_yasm"
 
+# To use system ffmpeg you need to enable also libwebp, opus, vpx											    
+# Only depenedencies available in oe-core are enabled by default
+PACKAGECONFIG ??= "libwebp flac libevent libxslt speex"
+PACKAGECONFIG[opus] = "WEBENGINE_CONFIG+=use_system_opus,,libopus"
+PACKAGECONFIG[icu] = "WEBENGINE_CONFIG+=use_system_icu,,icu"
+PACKAGECONFIG[ffmpeg] = "WEBENGINE_CONFIG+=use_system_ffmpeg,,libav"
+PACKAGECONFIG[libwebp] = "WEBENGINE_CONFIG+=use_system_libwebp,,libwebp"
+PACKAGECONFIG[flac] = "WEBENGINE_CONFIG+=use_system_flac,,flac"
+PACKAGECONFIG[libevent] = "WEBENGINE_CONFIG+=use_system_libevent,,libevent"
+PACKAGECONFIG[libxslt] = "WEBENGINE_CONFIG+=use_system_libxslt,,libxslt"
+PACKAGECONFIG[speex] = "WEBENGINE_CONFIG+=use_system_speex,,speex"
+PACKAGECONFIG[vpx] = "WEBENGINE_CONFIG+=use_system_vpx,,libvpx"
+
+EXTRA_QMAKEVARS_PRE += "${EXTRA_OECONF}"
+
 COMPATIBLE_MACHINE = "(-)"
 COMPATIBLE_MACHINE_x86 = "(.*)"
 COMPATIBLE_MACHINE_x86-64 = "(.*)"
@@ -37,6 +53,10 @@ inherit gettext
 inherit pythonnative
 inherit perlnative
 
+# we don't want gettext.bbclass to append --enable-nls
+def gettext_oeconf(d):
+    return ""
+
 require qt5.inc
 require qt5-git.inc
 
@@ -54,6 +74,10 @@ do_configure() {
     export CC_host="gcc"
     export CXX_host="g++"
     export QMAKE_MAKE_ARGS="${EXTRA_OEMAKE}"
+    export QMAKE_CACHE_EVAL="${EXTRA_OECONF}"
+
+    # Disable autodetection from sysroot:
+    sed -i 's/packagesExist([^)]*vpx[^)]*):/false:/g; s/config_srtp:/false:/g; s/config_snappy:/false:/g; s/packagesExist(nss):/false:/g; s/packagesExist(minizip, zlib):/false:/g; s/packagesExist(libwebp,libwebpdemux):/false:/g; s/packagesExist(libxml-2.0,libxslt):/false:/g; s/^ *packagesExist($$package):/false:/g' ${S}/tools/qmake/mkspecs/features/configure.prf
 
     # qmake can't find the OE_QMAKE_* variables on it's own so directly passing them as
     # arguments here