qt5-native: rename to qtbase-native to avoid confusion

* we also had PROVIDES for qt5-tools-native, this makes it a bit easier to see what is what
* drop FILESEXTRAPATHS, not needed after renaming to match BPN with qtbase patches

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>

1 files changed, 63 insertions, 0 deletions

diff --git a/recipes-qt/qt5/qtbase-native.inc b/recipes-qt/qt5/qtbase-native.inc
new file mode 100644
index 00000000..db1292cd
--- /dev/null
+++ b/recipes-qt/qt5/qtbase-native.inc
@@ -0,0 +1,63 @@
+DESCRIPTION = "Native version of Qt/[X11|Mac|Embedded]"
+DEPENDS = "zlib-native dbus-native"
+SECTION = "libs"
+HOMEPAGE = "http://qt-project.org"
+
+INC_PR = "r0"
+
+inherit native
+
+QT_MODULE = "qtbase"
+
+SRC_URI += " \
+  file://0001-qlibraryinfo-Allow-the-specification-of-where-to-loa.patch \
+  file://0003-qtbase-Allow-qt.conf-override-when-bootstrapping.patch \
+  file://0001-Always-build-uic.patch \
+"
+
+EXTRA_OECONF = " \
+  -prefix ${prefix} \
+  -L ${STAGING_LIBDIR_NATIVE} \
+  -I ${STAGING_INCDIR_NATIVE} \
+  -system-zlib \
+  -no-libjpeg \
+  -no-libpng \
+  -no-gif \
+  -no-accessibility \
+  -no-cups \
+  -no-nis \
+  -no-gui \
+  -no-qml-debug \
+  -no-sql-mysql \
+  -no-sql-sqlite \
+  -no-opengl \
+  -no-openssl \
+  -no-xcb \
+  -verbose -release \
+  -headerdir ${includedir}/qt5 \
+  -datadir ${datadir}/qt5 \
+  -docdir ${docdir}/qt5 \
+  -no-glib \
+  -no-iconv \
+  -silent \
+  -nomake examples \
+  -nomake tests \
+  -nomake demos \
+  -no-rpath \
+"
+
+do_configure() {
+	# Avoid setting QMAKE_LINK from LD (since we want the linker to be g++)
+	unset LD
+
+	(echo o; echo yes) | ./configure ${EXTRA_OECONF} || die "Configuring qt failed. EXTRA_OECONF was ${EXTRA_OECONF}"
+}
+
+do_install() {
+	install -d ${D}${bindir}/
+	for i in findtr fixqt4headers.pl moc qdoc qmake rcc qdbuscpp2xml qdbusxml2cpp syncqt uic; do
+		install -v -m 0755 bin/${i} ${D}${bindir}/${i}
+	done
+	install -d ${D}${datadir}/qt5/
+	cp -PfR mkspecs ${D}${datadir}/qt5/
+}