1 files changed, 98 insertions, 0 deletions
diff --git a/recipes-qt/maliit/maliit-framework-qt5_git.bb b/recipes-qt/maliit/maliit-framework-qt5_git.bb
new file mode 100644
index 00000000..ccd0c4cb
--- /dev/null
+++ b/recipes-qt/maliit/maliit-framework-qt5_git.bb
@@ -0,0 +1,98 @@
+DESCRIPTION = "A virtual keyboard for touch-screen based user interfaces"
+HOMEPAGE = "https://wiki.maliit.org/Main_Page"
+
+LICENSE = "LGPLv2.1"
+LIC_FILES_CHKSUM = "file://LICENSE.LGPL;md5=5c917f6ce94ceb8d8d5e16e2fca5b9ad"
+
+inherit qmake5
+
+# Set path of qt5 headers as qmake5_base.bbclass sets this to just ${includedir}
+# but
+# actually it is ${includedir}/qt5
+OE_QMAKE_PATH_HEADERS = "${OE_QMAKE_PATH_QT_HEADERS}"
+
+
+SRC_URI = "git://github.com/maliit/framework.git;branch=master \
+    file://0001-Fix-MALIIT_INSTALL_PRF-to-allow-the-build-with-opene.patch \
+    file://maliit-server.desktop \
+"
+
+SRCREV = "dbc0403f329d7f6ce2f5a09e6ff5adbd2548a8c9"
+PV = "0.99.0+git${SRCPV}"
+
+
+PACKAGES =+ "${PN}-gtk"
+GTKIMMODULES_PACKAGES = "${PN}-gtk"
+
+# FIXME: Do we need something like this with qt5?
+#RDEPENDS_${PN} = "qt4-plugin-inputmethod-imsw-multi libqtsvg4"
+
+RRECOMMENDS_${PN} = "maliit-plugins-qt5"
+
+FILES_${PN} += "\
+    ${libdir}/*.so* \
+    ${bindir} \
+    ${datadir}/applications/maliit-server.desktop \
+    ${datadir}/dbus-1 \
+"
+
+FILES_${PN}-dbg += "\
+    ${libdir}/maliit-framework-tests \
+"
+
+FILES_${PN}-dev += "\
+    ${includedir}/maliit \
+    ${libdir}/pkgconfig \
+    ${libdir}/qt5 \
+"
+
+EXTRA_QMAKEVARS_PRE = "\
+    PREFIX=${prefix} \
+    LIBDIR=${libdir} \
+    QT_IM_PLUGIN_PATH=${libdir}/qt4/plugins/inputmethods \
+    MALIIT_INSTALL_PRF=${QMAKE_MKSPEC_PATH}/mkspecs/features \
+    SCHEMADIR=${sysconfdir}/gconf/schemas \
+    CONFIG+=disable-gconf \
+    CONFIG+=disable-gtk-cache-update \
+    CONFIG+=local-install \
+    CONFIG+=nosdk \
+    CONFIG+=nodoc \
+    CONFIG+=noxcb \
+    CONFIG+=enable-dbus-activation \
+"
+
+EXTRA_OEMAKE += "INSTALL_ROOT=${D}"
+
+do_install_append() {
+    #Fix absolute paths
+    sed -i -e "s|/usr|${STAGING_DIR_TARGET}${prefix}|" ${D}/${libdir}/${QT_DIR_NAME}/mkspecs/features/maliit-framework.prf
+    sed -i -e "s|/usr|${STAGING_DIR_TARGET}${prefix}|" ${D}/${libdir}/${QT_DIR_NAME}/mkspecs/features/maliit-plugins.prf
+    sed -i -e "s|/usr|${STAGING_DIR_TARGET}${prefix}|" ${D}/${libdir}/${QT_DIR_NAME}/mkspecs/features/maliit-defines.prf
+
+    install -d ${D}${datadir}/applications
+    install -m 644 ${WORKDIR}/maliit-server.desktop ${D}${datadir}/applications
+}
+
+pkg_postinst_${PN} () {
+#!/bin/sh
+# should run online
+if [ "x$D" != "x" ]; then
+    exit 1
+fi
+echo "export QT_IM_MODULE=Maliit" >> /etc/xprofile
+ln -s /usr/share/applications/maliit-server.desktop /etc/xdg/autostart/maliit-server.desktop
+}
+
+pkg_postrm_${PN} () {
+#!/bin/sh
+# should run online
+if [ "x$D" = "x" ]; then
+    exit 1
+fi
+if [ -e "/etc/xprofile" ]; then
+    sed -i -e "g|export QT_IM_MODULE=Maliit|d" /etc/xprofile
+fi
+rm -f /etc/xdg/autostart/maliit-server.desktop
+}
+
+S = "${WORKDIR}/git"