From 65b8e152f65fe89e62beefb251ec572500cc8407 Mon Sep 17 00:00:00 2001
From: Philip Balister <philip@opensdr.com>
Date: Mon, 13 Jul 2020 18:51:00 -0400
Subject: python3-pyqt5: Update to 5.15.1.dev2007111314

 * Resolves missing source tarball for me.

Signed-off-by: Philip Balister <philip@opensdr.com>
---
 .../pyqt5/python3-pyqt5_5.15.1.dev2007111314.bb    | 65 ++++++++++++++++++++++
 1 file changed, 65 insertions(+)
 create mode 100644 recipes-python/pyqt5/python3-pyqt5_5.15.1.dev2007111314.bb

(limited to 'recipes-python/pyqt5/python3-pyqt5_5.15.1.dev2007111314.bb')

diff --git a/recipes-python/pyqt5/python3-pyqt5_5.15.1.dev2007111314.bb b/recipes-python/pyqt5/python3-pyqt5_5.15.1.dev2007111314.bb
new file mode 100644
index 00000000..ef14e206
--- /dev/null
+++ b/recipes-python/pyqt5/python3-pyqt5_5.15.1.dev2007111314.bb
@@ -0,0 +1,65 @@
+SUMMARY = "Python Qt5 Bindings"
+AUTHOR = "Phil Thomson @ riverbank.co.uk"
+HOMEPAGE = "http://riverbankcomputing.co.uk"
+SECTION = "devel/python"
+LICENSE = "GPLv3"
+LIC_FILES_CHKSUM = "\
+    file://LICENSE;md5=d32239bcb673463ab874e80d47fae504 \
+"
+
+SRC_URI = "\
+    https://www.riverbankcomputing.com/static/Downloads/PyQt5/PyQt5-${PV}.tar.gz \
+"
+SRC_URI[sha256sum] = "d0bbefff23a29c64d8fd9378389f54462029425a6765619843a2b6fc44cb167e"
+
+S = "${WORKDIR}/PyQt5-${PV}"
+
+inherit qmake5
+inherit python3native python3-dir
+
+DEPENDS = "qtbase qtdeclarative qtquickcontrols2"
+DEPENDS += "sip3 sip3-native python3"
+
+export BUILD_SYS
+export HOST_SYS
+export STAGING_INCDIR
+export STAGING_LIBDIR
+
+PARALLEL_MAKEINST = ""
+
+DISABLED_FEATURES = "PyQt_Desktop_OpenGL PyQt_Accessibility PyQt_SessionManager ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', '', 'PyQt_OpenGL', d)}"
+
+PYQT_MODULES = "QtCore QtGui QtNetwork QtXml QtNetwork QtQml ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'QtQuick QtWidgets QtQuickWidgets', '', d)}"
+
+do_configure_prepend() {
+    cd ${S}
+    echo "py_platform = linux" > pyqt.cfg
+    echo "py_inc_dir = %(sysroot)/$includedir/python%(py_major).%(py_minor)${PYTHON_ABI}" >> pyqt.cfg
+    echo "py_pylib_dir = %(sysroot)/${libdir}/python%(py_major).%(py_minor)" >> pyqt.cfg
+    echo "py_pylib_lib = python$%(py_major).%(py_minor)" >> pyqt.cfg
+    echo "pyqt_module_dir = ${D}/${libdir}/python%(py_major).%(py_minor)/site-packages" >> pyqt.cfg
+    echo "pyqt_bin_dir = ${D}/${bindir}" >> pyqt.cfg
+    echo "pyqt_sip_dir = ${D}/${datadir}/sip/PyQt5" >> pyqt.cfg
+    echo "pyuic_interpreter = ${D}/${bindir}/python%(py_major).%(py_minor)" >> pyqt.cfg
+    echo "pyqt_disabled_features = ${DISABLED_FEATURES}" >> pyqt.cfg
+    echo "qt_shared = True" >> pyqt.cfg
+    QT_VERSION=`${OE_QMAKE_QMAKE} -query QT_VERSION`
+    echo "[Qt $QT_VERSION]" >> pyqt.cfg
+    echo "pyqt_modules = ${PYQT_MODULES}" >> pyqt.cfg
+    echo yes | ${PYTHON} configure.py --verbose --qmake  ${STAGING_BINDIR_NATIVE}/${QT_DIR_NAME}/qmake --configuration pyqt.cfg --sysroot ${STAGING_DIR_HOST}
+}
+
+do_compile() {
+    cd ${S}
+    oe_runmake
+}
+
+do_install() {
+    cd ${S}
+    oe_runmake MAKEFLAGS='-j 1' install
+}
+
+FILES_${PN} += "${libdir}/${PYTHON_DIR}/site-packages ${datadir}/sip/PyQt5/"
+
+RDEPENDS_${PN} = "qtbase qtdeclarative qtquickcontrols2 qtquickcontrols2-mkspecs"
+RDEPENDS_${PN} += "python3-core python3-sip3"
-- 
cgit v1.2.3