aboutsummaryrefslogtreecommitdiffstats
path: root/recipes-qt/qt5/qttools_git.bb
blob: 86bda33df3ec8bf72c60f22824877e5180198d75 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
require qt5.inc
require qt5-git.inc

HOMEPAGE = "http://www.qt.io"
LICENSE = "GFDL-1.3 & BSD & ( GPL-3.0 & The-Qt-Company-GPL-Exception-1.0 | The-Qt-Company-Commercial ) & ( GPL-2.0+ | LGPL-3.0 | The-Qt-Company-Commercial )"
LIC_FILES_CHKSUM = " \
    file://LICENSE.LGPL3;md5=e6a600fd5e1d9cbde2d983680233ad02 \
    file://LICENSE.GPL2;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
    file://LICENSE.GPL3;md5=d32239bcb673463ab874e80d47fae504 \
    file://LICENSE.GPL3-EXCEPT;md5=763d8c535a234d9a3fb682c7ecb6c073 \
    file://LICENSE.FDL;md5=6d9f2a9af4c8b8c3c769f6cc1b6aaf7e \
"

inherit ptest

DEPENDS += "qtbase qtdeclarative qtxmlpatterns"

# Patches from https://github.com/meta-qt5/qttools/commits/b5.9
# 5.9.meta-qt5.5
SRC_URI += " \
    file://run-ptest \
    file://0001-add-noqtwebkit-configuration.patch \
    file://0002-linguist-tools-cmake-allow-overriding-the-location-f.patch \
"

FILES_${PN}-tools += "${datadir}${QT_DIR_NAME}/phrasebooks"
FILES_${PN}-examples = "${datadir}${QT_DIR_NAME}/examples"

PACKAGECONFIG ??= ""
PACKAGECONFIG[qtwebkit] = ",,qtwebkit"

EXTRA_QMAKEVARS_PRE += "${@bb.utils.contains('PACKAGECONFIG', 'qtwebkit', '', 'CONFIG+=noqtwebkit', d)}"

SRCREV = "f8e4006ab9100e5bb3a597fd09a7980d88edc3cc"

BBCLASSEXTEND = "native nativesdk"

do_compile_ptest() {
    export PATH=${STAGING_DIR_NATIVE}/usr/include/qt5:$PATH
    cd ${S}/tests
    qmake -o Makefile tests.pro
    oe_runmake
}

do_install_ptest() {
    mkdir -p ${D}${PTEST_PATH}
    t=${D}${PTEST_PATH}
    cp ${S}/tests/auto/qtdiag/tst_tdiag $t
    cp ${S}/tests/auto/qtattributionsscanner/tst_qtattributionsscanner $t
}