1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
|
// Copyright (C) 2023 The Qt Company Ltd.
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR GPL-3.0-only WITH Qt-GPL-exception-1.0
import QtQuick
import QtQuick.Controls
import QtQuick.Layouts
import CollectionDetails 1.0 as CollectionDetails
import HelperWidgets 2.0 as HelperWidgets
import StudioControls 1.0 as StudioControls
import StudioTheme 1.0 as StudioTheme
Rectangle {
id: root
required property var model
required property var backend
required property var sortedModel
implicitWidth: 300
implicitHeight: 400
color: StudioTheme.Values.themeControlBackground
function closeDialogs() {
editPropertyDialog.reject()
deleteColumnDialog.reject()
toolbar.closeDialogs()
}
MouseArea {
anchors.fill: parent
onClicked: tableView.model.deselectAll()
}
Column {
id: topRow
readonly property real maxAvailableHeight: root.height
visible: root.model.collectionName !== ""
width: parent.width
spacing: 10
CollectionDetailsToolbar {
id: toolbar
model: root.model
backend: root.backend
width: parent.width
}
GridLayout {
id: gridLayout
readonly property real maxAvailableHeight: topRow.maxAvailableHeight
- topRow.spacing
- toolbar.height
columns: 3
rowSpacing: 1
columnSpacing: 1
width: parent.width
anchors {
left: parent.left
leftMargin: StudioTheme.Values.collectionTableHorizontalMargin
}
Rectangle {
id: tableTopLeftCorner
clip: true
visible: !tableView.model.isEmpty
color: StudioTheme.Values.themeControlBackgroundInteraction
border.color: StudioTheme.Values.themeControlBackgroundInteraction
border.width: 2
Layout.preferredWidth: rowIdView.width
Layout.preferredHeight: headerView.height
Layout.minimumWidth: rowIdView.width
Layout.minimumHeight: headerView.height
Text {
anchors.fill: parent
font: headerTextMetrics.font
text: "#"
horizontalAlignment: Text.AlignHCenter
verticalAlignment: Text.AlignVCenter
color: StudioTheme.Values.themeTextColor
MouseArea {
anchors.fill: parent
acceptedButtons: Qt.LeftButton
property int order: Qt.AscendingOrder
onClicked: {
order = (order == Qt.AscendingOrder) ? Qt.DescendingOrder : Qt.AscendingOrder;
tableView.closeEditor()
tableView.model.sort(-1, order)
}
}
}
}
HorizontalHeaderView {
id: headerView
property real topPadding: 5
property real bottomPadding: 5
Layout.preferredHeight: headerTextMetrics.height + topPadding + bottomPadding
Layout.columnSpan: 2
syncView: tableView
clip: true
delegate: HeaderDelegate {
selectedItem: tableView.model.selectedColumn
color: StudioTheme.Values.themeControlBackgroundInteraction
MouseArea {
id: topHeaderMouseArea
anchors.fill: parent
anchors.leftMargin: StudioTheme.Values.borderHover
anchors.rightMargin: StudioTheme.Values.borderHover
acceptedButtons: Qt.LeftButton | Qt.RightButton
hoverEnabled: true
onClicked: (mouse) => {
tableView.model.selectColumn(index)
if (mouse.button === Qt.RightButton) {
let posX = index === root.model.columnCount() - 1 ? parent.width - editPropertyDialog.width : 0
headerMenu.clickedHeaderIndex = index
headerMenu.dialogPos = parent.mapToGlobal(posX, parent.height)
headerMenu.popup()
} else {
headerMenu.close()
}
}
}
ToolTip {
id: topHeaderToolTip
property bool expectedToBeShown: topHeaderMouseArea.containsMouse
visible: expectedToBeShown && text !== ""
delay: 1000
onExpectedToBeShownChanged: {
if (expectedToBeShown)
text = root.model.propertyType(index)
}
}
}
StudioControls.Menu {
id: headerMenu
property int clickedHeaderIndex: -1
property point dialogPos
onClosed: {
headerMenu.clickedHeaderIndex = -1
}
StudioControls.MenuItem {
text: qsTr("Edit")
onTriggered: editPropertyDialog.openDialog(headerMenu.clickedHeaderIndex,
headerMenu.dialogPos)
}
StudioControls.MenuItem {
text: qsTr("Delete")
onTriggered: deleteColumnDialog.popUp(headerMenu.clickedHeaderIndex)
}
StudioControls.MenuItem {
text: qsTr("Sort Ascending")
onTriggered: {
tableView.closeEditor()
tableView.model.sort(headerMenu.clickedHeaderIndex, Qt.AscendingOrder)
}
}
StudioControls.MenuItem {
text: qsTr("Sort Descending")
onTriggered: {
tableView.closeEditor()
tableView.model.sort(headerMenu.clickedHeaderIndex, Qt.DescendingOrder)
}
}
}
}
VerticalHeaderView {
id: rowIdView
syncView: tableView
clip: true
Layout.preferredHeight: tableView.height
Layout.rowSpan: 2
Layout.alignment: Qt.AlignTop + Qt.AlignLeft
width: implicitWidth // suppresses GridLayout warnings when resizing
delegate: HeaderDelegate {
selectedItem: tableView.model.selectedRow
color: StudioTheme.Values.themeControlBackgroundHover
MouseArea {
anchors.fill: parent
anchors.topMargin: StudioTheme.Values.borderHover
anchors.bottomMargin: StudioTheme.Values.borderHover
acceptedButtons: Qt.LeftButton
onClicked: tableView.model.selectRow(index)
}
}
}
TableView {
id: tableView
model: root.sortedModel
clip: true
readonly property real maxAvailableHeight: gridLayout.maxAvailableHeight
- addRowButton.height
- headerView.height
- (2 * gridLayout.rowSpacing)
readonly property real maxAvailableWidth: gridLayout.width
- StudioTheme.Values.collectionTableHorizontalMargin
- rowIdView.width
- addColumnButton.width
- gridLayout.columnSpacing
property real childrenWidth: tableView.contentItem.childrenRect.width
property real childrenHeight: tableView.contentItem.childrenRect.height
property int targetRow
property int targetColumn
Layout.alignment: Qt.AlignTop + Qt.AlignLeft
Layout.preferredWidth: tableView.contentWidth
Layout.preferredHeight: tableView.contentHeight
Layout.minimumWidth: 100
Layout.minimumHeight: 20
Layout.maximumWidth: maxAvailableWidth
Layout.maximumHeight: maxAvailableHeight
columnWidthProvider: function(column) {
if (!isColumnLoaded(column))
return -1
let w = explicitColumnWidth(column)
if (w < 0)
w = implicitColumnWidth(column)
return Math.max(w, StudioTheme.Values.collectionCellMinimumWidth)
}
rowHeightProvider: function(row) {
if (!isRowLoaded(row))
return -1
let h = explicitRowHeight(row)
if (h < 0)
h = implicitRowHeight(row)
return Math.max(h, StudioTheme.Values.collectionCellMinimumHeight)
}
function ensureRowIsVisible(row) {
let rows = tableView.model.rowCount()
let rowIsLoaded = tableView.isRowLoaded(row)
if (row < 0 || row >= rows || rowIsLoaded) {
if (rowIsLoaded)
tableView.positionViewAtRow(row, Qt.AlignLeft | Qt.AlignTop)
tableView.targetRow = -1
return
}
tableView.targetRow = row
tableView.positionViewAtRow(row, Qt.AlignLeft | Qt.AlignTop)
ensureTimer.start()
}
function ensureColumnIsVisible(column) {
let columns = tableView.model.columnCount()
let columnIsLoaded = tableView.isColumnLoaded(column)
if (column < 0 || column >= columns || columnIsLoaded) {
if (columnIsLoaded)
tableView.positionViewAtColumn(column, Qt.AlignLeft | Qt.AlignTop)
tableView.targetColumn = -1
return
}
tableView.targetColumn = column
tableView.positionViewAtColumn(column, Qt.AlignLeft | Qt.AlignTop)
ensureTimer.start()
}
onMaxAvailableHeightChanged: resetSizeTimer.start()
onMaxAvailableWidthChanged: resetSizeTimer.start()
onChildrenWidthChanged: resetSizeTimer.start()
onChildrenHeightChanged: resetSizeTimer.start()
delegate: Rectangle {
id: itemCell
clip: true
implicitWidth: 100
implicitHeight: StudioTheme.Values.baseHeight
color: itemSelected ? StudioTheme.Values.themeControlBackgroundInteraction
: StudioTheme.Values.themeControlBackground
border.width: 1
border.color: {
if (dataTypeWarning !== CollectionDetails.Warning.None)
return StudioTheme.Values.themeWarning
if (itemSelected)
return StudioTheme.Values.themeControlOutlineInteraction
return StudioTheme.Values.themeControlBackgroundInteraction
}
HelperWidgets.ToolTipArea {
anchors.fill: parent
text: root.model.warningToString(dataTypeWarning)
enabled: dataTypeWarning !== CollectionDetails.Warning.None && text !== ""
hoverEnabled: true
acceptedButtons: Qt.NoButton
}
MouseArea {
anchors.fill: parent
acceptedButtons: Qt.RightButton
onClicked: (mouse) => {
let row = index % tableView.model.rowCount()
tableView.model.selectRow(row)
cellContextMenu.showMenu(row)
}
}
Loader {
id: cellContentLoader
property int cellColumnType: columnType ? columnType : 0
Component {
id: cellText
Text {
text: display ?? ""
color: itemSelected ? StudioTheme.Values.themeInteraction
: StudioTheme.Values.themeTextColor
leftPadding: 5
topPadding: 3
bottomPadding: 3
font.pixelSize: StudioTheme.Values.baseFontSize
horizontalAlignment: Text.AlignLeft
verticalAlignment: Text.AlignVCenter
elide: Text.ElideRight
}
}
Component {
id: checkBoxComponent
StudioControls.CheckBox {
id: checkBoxDelegate
readonly property bool editValue: edit
text: ""
actionIndicatorVisible: false
checked: checkBoxDelegate.editValue
onCheckedChanged: {
if (checkBoxDelegate.editValue !== checkBoxDelegate.checked)
edit = checkBoxDelegate.checked
}
}
}
Component {
id: colorEditorComponent
ColorViewDelegate {}
}
function resetSource() {
if (columnType === CollectionDetails.DataType.Color)
cellContentLoader.sourceComponent = colorEditorComponent
else if (columnType === CollectionDetails.DataType.Boolean)
cellContentLoader.sourceComponent = checkBoxComponent
else
cellContentLoader.sourceComponent = cellText
}
Component.onCompleted: resetSource()
onCellColumnTypeChanged: resetSource()
}
TableView.editDelegate: CollectionDetailsEditDelegate {
anchors {
top: itemCell.top
left: itemCell.left
}
Component.onCompleted: tableView.model.deselectAll()
}
}
Timer {
id: resetSizeTimer
interval: 100
repeat: false
onTriggered: {
let cWidth = Math.min(tableView.maxAvailableWidth, tableView.childrenWidth)
let cHeight = Math.min(tableView.maxAvailableHeight, tableView.childrenHeight)
if (tableView.contentWidth !== cWidth || tableView.contentHeight !== cHeight)
tableView.returnToBounds()
}
}
Timer {
id: ensureTimer
interval: 100
repeat: false
onTriggered: {
tableView.ensureRowIsVisible(tableView.targetRow)
tableView.ensureColumnIsVisible(tableView.targetColumn)
}
}
Connections {
target: tableView.model
function onModelReset() {
root.closeDialogs()
tableView.clearColumnWidths()
tableView.clearRowHeights()
}
function onRowsInserted(parent, first, last) {
tableView.closeEditor()
tableView.model.selectRow(first)
tableView.ensureRowIsVisible(first)
}
function onColumnsInserted(parent, first, last) {
tableView.closeEditor()
tableView.model.selectColumn(first)
tableView.ensureColumnIsVisible(first)
}
function onRowsRemoved(parent, first, last) {
let nextRow = first - 1
if (nextRow < 0 && tableView.model.rowCount(parent) > 0)
nextRow = 0
tableView.model.selectRow(nextRow)
}
function onColumnsRemoved(parent, first, last) {
let nextColumn = first - 1
if (nextColumn < 0 && tableView.model.columnCount(parent) > 0)
nextColumn = 0
tableView.model.selectColumn(nextColumn)
}
}
HoverHandler { id: hoverHandler }
ScrollBar.horizontal: StudioControls.TransientScrollBar {
id: horizontalScrollBar
style: StudioTheme.Values.viewStyle
orientation: Qt.Horizontal
show: (hoverHandler.hovered || tableView.focus || horizontalScrollBar.inUse)
&& horizontalScrollBar.isNeeded
}
ScrollBar.vertical: StudioControls.TransientScrollBar {
id: verticalScrollBar
style: StudioTheme.Values.viewStyle
orientation: Qt.Vertical
show: (hoverHandler.hovered || tableView.focus || verticalScrollBar.inUse)
&& verticalScrollBar.isNeeded
}
}
HelperWidgets.IconButton {
id: addColumnButton
iconSize:16
Layout.preferredWidth: 24
Layout.preferredHeight: tableView.height
Layout.minimumHeight: 24
Layout.alignment: Qt.AlignLeft + Qt.AlignVCenter
icon: StudioTheme.Constants.create_medium
tooltip: "Add Column"
onClicked: toolbar.addNewColumn()
}
HelperWidgets.IconButton {
id: addRowButton
iconSize:16
Layout.preferredWidth: tableView.width
Layout.preferredHeight: 24
Layout.minimumWidth: 24
Layout.alignment: Qt.AlignTop + Qt.AlignHCenter
icon: StudioTheme.Constants.create_medium
tooltip: "Add Row"
onClicked: toolbar.addNewRow()
}
Item {
Layout.fillWidth: true
Layout.fillHeight: true
}
}
}
ColumnLayout {
id: importsProblem
visible: !topRow.visible && rootView.dataStoreExists && !rootView.projectImportExists
width: parent.width
anchors.verticalCenter: parent.verticalCenter
clip: true
Text {
text: qsTr("Import the project to your design document to make the Model Editor enabled.")
Layout.alignment: Qt.AlignCenter
Layout.maximumWidth: parent.width
leftPadding: StudioTheme.Values.collectionItemTextPadding
rightPadding: StudioTheme.Values.collectionItemTextPadding
color: StudioTheme.Values.themeTextColor
font.pixelSize: StudioTheme.Values.mediumFontSize
wrapMode: Text.Wrap
}
HelperWidgets.Button {
text: qsTr("Enable DataStore (This will add the required import)")
Layout.alignment: Qt.AlignCenter
onClicked: rootView.addProjectImport()
leftPadding: StudioTheme.Values.collectionItemTextPadding
rightPadding: StudioTheme.Values.collectionItemTextPadding
}
}
Text {
anchors.centerIn: parent
text: qsTr("There are no models in this project.\nAdd or import a model.")
visible: !topRow.visible && !importsProblem.visible
color: StudioTheme.Values.themeTextColor
font.pixelSize: StudioTheme.Values.mediumFontSize
}
TextMetrics {
id: headerTextMetrics
font.pixelSize: StudioTheme.Values.baseFontSize
text: "Xq"
}
StudioControls.Menu {
id: cellContextMenu
property int rowIndex: -1
closePolicy: Popup.CloseOnEscape | Popup.CloseOnPressOutside
function showMenu(rowIndex) {
cellContextMenu.rowIndex = rowIndex
cellContextMenu.popup()
}
CellContextMenuItem {
id: addRowAboveCellMenuItem
itemText: qsTr("Add row above")
itemIcon: StudioTheme.Constants.addrowabove_medium
onTriggered: root.model.insertRow(cellContextMenu.rowIndex)
}
CellContextMenuItem {
id: addRowBelowCellMenuItem
itemText: qsTr("Add row below")
itemIcon: StudioTheme.Constants.addrowbelow_medium
onTriggered: root.model.insertRow(cellContextMenu.rowIndex + 1)
}
CellContextMenuItem {
id: deleteRowCellMenuItem
itemText: qsTr("Delete row")
itemIcon: StudioTheme.Constants.deleterow_medium
onTriggered: root.model.removeRows(cellContextMenu.rowIndex, 1)
}
}
component HeaderDelegate: Rectangle {
id: headerItem
required property int selectedItem
property alias horizontalAlignment: headerText.horizontalAlignment
property alias verticalAlignment: headerText.verticalAlignment
implicitWidth: headerText.implicitWidth
implicitHeight: headerText.implicitHeight
border.width: 1
clip: true
Text {
id: headerText
topPadding: headerView.topPadding
bottomPadding: headerView.bottomPadding
leftPadding: 5
rightPadding: 5
text: display
font: headerTextMetrics.font
color: StudioTheme.Values.themeTextColor
horizontalAlignment: Text.AlignHCenter
verticalAlignment: Text.AlignVCenter
elide: Text.ElideRight
}
states: [
State {
name: "default"
when: index !== selectedItem
PropertyChanges {
target: headerItem
border.color: StudioTheme.Values.themeControlBackgroundInteraction
}
PropertyChanges {
target: headerText
font.bold: false
}
},
State {
name: "selected"
when: index === selectedItem
PropertyChanges {
target: headerItem
border.color: StudioTheme.Values.themeControlBackground
}
PropertyChanges {
target: headerText
font.bold: true
}
}
]
}
component CellContextMenuItem: StudioControls.MenuItem {
id: cellContextMenuItemComponent
property alias itemText: cellContextMenuText.text
property alias itemIcon: cellContextMenuIcon.text
text: ""
implicitWidth: cellContextMenuRow.width
implicitHeight: cellContextMenuRow.height
Row {
id: cellContextMenuRow
property color textColor : cellContextMenuItemComponent.enabled
? cellContextMenuItemComponent.highlighted
? cellContextMenuItemComponent.style.text.selectedText
: cellContextMenuItemComponent.style.text.idle
: cellContextMenuItemComponent.style.text.disabled
spacing: 2 * StudioTheme.Values.contextMenuHorizontalPadding
height: StudioTheme.Values.defaultControlHeight
leftPadding: StudioTheme.Values.contextMenuHorizontalPadding
rightPadding: StudioTheme.Values.contextMenuHorizontalPadding
Text {
id: cellContextMenuIcon
color: cellContextMenuRow.textColor
text: StudioTheme.Constants.addrowabove_medium
font.family: StudioTheme.Constants.iconFont.family
font.pixelSize: StudioTheme.Values.myIconFontSize
anchors.verticalCenter: parent.verticalCenter
}
Text {
id: cellContextMenuText
color: cellContextMenuRow.textColor
anchors.verticalCenter: parent.verticalCenter
}
}
}
EditPropertyDialog {
id: editPropertyDialog
model: root.model
}
StudioControls.Dialog {
id: deleteColumnDialog
property int clickedIndex: -1
title: qsTr("Delete Column")
width: 400
onAccepted: {
root.model.removeColumn(clickedIndex)
}
function popUp(index)
{
deleteColumnDialog.clickedIndex = index
deleteColumnDialog.open()
}
contentItem: ColumnLayout {
spacing: StudioTheme.Values.sectionColumnSpacing
Text {
text: qsTr("Are you sure that you want to delete column \"%1\"?").arg(
root.model.headerData(
deleteColumnDialog.clickedIndex, Qt.Horizontal))
color: StudioTheme.Values.themeTextColor
}
RowLayout {
Layout.alignment: Qt.AlignRight | Qt.AlignVCenter
spacing: StudioTheme.Values.sectionRowSpacing
HelperWidgets.Button {
text: qsTr("Delete")
onClicked: deleteColumnDialog.accept()
}
HelperWidgets.Button {
text: qsTr("Cancel")
onClicked: deleteColumnDialog.reject()
}
}
}
}
}
|