blob: 0c7b83878e69fc58c9168410652f1b0834cc18c4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
|
/****************************************************************************
**
** Copyright (C) 2021 The Qt Company Ltd.
** Contact: https://www.qt.io/licensing/
**
** This file is part of Qt Creator.
**
** Commercial License Usage
** Licensees holding valid commercial Qt licenses may use this file in
** accordance with the commercial license agreement provided with the
** Software or, alternatively, in accordance with the terms contained in
** a written agreement between you and The Qt Company. For licensing terms
** and conditions see https://www.qt.io/terms-conditions. For further
** information use the contact form at https://www.qt.io/contact-us.
**
** GNU General Public License Usage
** Alternatively, this file may be used under the terms of the GNU
** General Public License version 3 as published by the Free Software
** Foundation with exceptions as appearing in the file LICENSE.GPL3-EXCEPT
** included in the packaging of this file. Please review the following
** information to ensure the GNU General Public License requirements will
** be met: https://www.gnu.org/licenses/gpl-3.0.html.
**
****************************************************************************/
import QtQuick 2.15
import QtQuick.Controls 2.15 as Controls
import QtQuick.Layouts 1.15
import QtQuickDesignerTheme 1.0
import StudioControls 1.0 as StudioControls
import StudioTheme 1.0 as StudioTheme
Item {
id: section
property alias caption: label.text
property alias labelColor: label.color
property alias sectionHeight: header.height
property alias sectionBackgroundColor: header.color
property alias sectionFontSize: label.font.pixelSize
property alias showTopSeparator: topSeparator.visible
property alias showArrow: arrow.visible
property alias showLeftBorder: leftBorder.visible
property alias spacing: column.spacing
property int leftPadding: StudioTheme.Values.sectionLeftPadding
property int rightPadding: 0
property int topPadding: StudioTheme.Values.sectionHeadSpacerHeight
property int bottomPadding: StudioTheme.Values.sectionHeadSpacerHeight
property bool expanded: true
property int level: 0
property int levelShift: 10
property bool hideHeader: false
property bool collapsible: true
property bool expandOnClick: true // if false, toggleExpand signal will be emitted instead
property bool addTopPadding: true
property bool addBottomPadding: true
property bool dropEnabled: false
property bool highlight: false
property bool useDefaulContextMenu: true
clip: true
Connections {
id: connection
target: section
enabled: section.useDefaulContextMenu
function onShowContextMenu() { contextMenu.popup() }
}
Connections {
target: Controller
function onCollapseAll() {
if (collapsible) {
if (section.expandOnClick)
section.expanded = false
else
section.collapse()
}
}
function onExpandAll() {
if (section.expandOnClick)
section.expanded = true
else
section.expand()
}
}
signal drop(var drag)
signal dropEnter(var drag)
signal dropExit()
signal showContextMenu()
signal toggleExpand()
signal expand()
signal collapse()
DropArea {
id: dropArea
enabled: section.dropEnabled
anchors.fill: parent
onEntered: (drag)=> section.dropEnter(drag)
onDropped: (drag)=> section.drop(drag)
onExited: section.dropExit()
}
Rectangle {
id: header
height: section.hideHeader ? 0 : StudioTheme.Values.sectionHeadHeight
visible: !section.hideHeader
anchors.left: parent.left
anchors.right: parent.right
color: section.highlight ? StudioTheme.Values.themeInteraction
: Qt.lighter(StudioTheme.Values.themeSectionHeadBackground, 1.0
+ (0.2 * section.level))
Item {
StudioControls.Menu {
id: contextMenu
StudioControls.MenuItem {
text: qsTr("Expand All")
onTriggered: Controller.expandAll()
}
StudioControls.MenuItem {
text: qsTr("Collapse All")
onTriggered: Controller.collapseAll()
}
}
}
Image {
id: arrow
width: 8
height: 4
source: "image://icons/down-arrow"
anchors.left: parent.left
anchors.leftMargin: 4 + (section.level * section.levelShift)
anchors.verticalCenter: parent.verticalCenter
}
Controls.Label {
id: label
anchors.verticalCenter: parent.verticalCenter
color: StudioTheme.Values.themeTextColor
x: 22 + (section.level * section.levelShift)
font.pixelSize: StudioTheme.Values.myFontSize
font.capitalization: Font.AllUppercase
}
MouseArea {
id: mouseArea
anchors.fill: parent
acceptedButtons: Qt.LeftButton | Qt.RightButton
onClicked: function(mouse) {
if (mouse.button === Qt.LeftButton) {
if (!section.collapsible && section.expanded)
return
transition.enabled = true
if (section.expandOnClick)
section.expanded = !section.expanded
else
section.toggleExpand()
} else {
section.showContextMenu()
}
}
}
}
Rectangle {
id: topSeparator
height: 1
anchors.left: parent.left
anchors.right: parent.right
anchors.rightMargin: 5 + section.leftPadding
anchors.leftMargin: 5 - section.leftPadding
visible: false
color: StudioTheme.Values.themeControlOutline
}
default property alias __content: column.children
readonly property alias contentItem: column
implicitHeight: Math.round(column.height + header.height + topSpacer.height + bottomSpacer.height)
Item {
id: topSpacer
height: section.addTopPadding && column.height > 0 ? section.topPadding : 0
anchors.top: header.bottom
}
Column {
id: column
anchors.left: parent.left
anchors.leftMargin: section.leftPadding
anchors.right: parent.right
anchors.rightMargin: section.rightPadding
anchors.top: topSpacer.bottom
}
Rectangle {
id: leftBorder
visible: false
width: 1
height: parent.height - bottomPadding
color: header.color
}
Item {
id: bottomSpacer
height: section.addBottomPadding && column.height > 0 ? section.bottomPadding : 0
anchors.top: column.bottom
}
states: [
State {
name: "Collapsed"
when: !section.expanded
PropertyChanges {
target: section
implicitHeight: header.height
}
PropertyChanges {
target: arrow
rotation: -90
}
}
]
transitions: Transition {
id: transition
enabled: false
NumberAnimation {
properties: "implicitHeight,rotation"
duration: 120
easing.type: Easing.OutCubic
}
}
}
|