1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
|
isEmpty(LLVM_INSTALL_DIR):LLVM_INSTALL_DIR=$$(LLVM_INSTALL_DIR)
LLVM_INSTALL_DIR = $$clean_path($$LLVM_INSTALL_DIR)
!isEmpty(LLVM_INSTALL_DIR):!exists($$LLVM_INSTALL_DIR) {
error("Explicitly given LLVM_INSTALL_DIR does not exist: $$LLVM_INSTALL_DIR")
}
defineReplace(llvmWarningOrError) {
warningText = $$1
errorText = $$2
isEmpty(errorText): errorText = $$warningText
isEmpty(LLVM_INSTALL_DIR): warning($$warningText)
else: error($$errorText)
return(false)
}
# Expected input: "3.9.1", "5.0.0svn", "5.0.1git-81029f14223"
defineReplace(extractVersion) { return($$replace(1, ^(\\d+\\.\\d+\\.\\d+).*$, \\1)) }
defineReplace(extractMajorVersion) { return($$replace(1, ^(\\d+)\\.\\d+\\.\\d+.*$, \\1)) }
defineReplace(extractMinorVersion) { return($$replace(1, ^\\d+\\.(\\d+)\\.\\d+.*$, \\1)) }
defineReplace(extractPatchVersion) { return($$replace(1, ^\\d+\\.\\d+\\.(\\d+).*$, \\1)) }
defineTest(versionIsAtLeast) {
actual_major_version = $$extractMajorVersion($$1)
actual_minor_version = $$extractMinorVersion($$1)
actual_patch_version = $$extractPatchVersion($$1)
required_min_major_version = $$2
required_min_minor_version = $$3
required_min_patch_version = $$4
isEqual(actual_major_version, $$required_min_major_version) {
isEqual(actual_minor_version, $$required_min_minor_version) {
isEqual(actual_patch_version, $$required_min_patch_version): return(true)
greaterThan(actual_patch_version, $$required_min_patch_version): return(true)
}
greaterThan(actual_minor_version, $$required_min_minor_version): return(true)
}
greaterThan(actual_major_version, $$required_min_major_version): return(true)
return(false)
}
defineTest(versionIsEqual) {
actual_major_version = $$extractMajorVersion($$1)
actual_minor_version = $$extractMinorVersion($$1)
required_min_major_version = $$2
required_min_minor_version = $$3
isEqual(actual_major_version, $$required_min_major_version) {
isEqual(actual_minor_version, $$required_min_minor_version) {
return(true)
}
}
return(false)
}
defineReplace(findLLVMVersionFromLibDir) {
libdir = $$1
version_dirs = $$files($$libdir/clang/*)
for (version_dir, version_dirs) {
fileName = $$basename(version_dir)
version = $$find(fileName, ^(\\d+\\.\\d+\\.\\d+)$)
!isEmpty(version): return($$version)
}
}
defineReplace(findClangLibInLibDir) {
libdir = $$1
exists($${libdir}/libclang.so*)|exists($${libdir}/libclang.dylib) {
return("-lclang")
} else {
exists ($${libdir}/libclang.*) {
return("-llibclang")
} else {
exists ($${libdir}/liblibclang.dll.a) {
return("-llibclang.dll")
}
}
}
}
defineReplace(splitFlags) {
flags = $$1
inside_quotes = 0
starting_substr = $$str_member($$flags, 0, 0)
equals(starting_substr, "\"") {
inside_quotes = 1
}
flags_temp = $$split(flags, "\"")
for (flag, flags_temp) {
equals(inside_quotes, 0) {
inside_quotes = 1
flag ~= s,-I\S*,,
flag ~= s,/D\S*,,
flag ~= s,/Z\S*,,
result += $$split(flag, " ")
} else {
inside_quotes = 0
starting_substr = $$str_member($$flag, 0, 0)
!equals(starting_substr, "/") {
starting_substr = $$str_member($$flag, 0, 1)
!equals(starting_substr, "-I") {
result += "\"$$flag\""
}
}
}
}
return($$result)
}
CLANGTOOLING_LIBS=-lclangTooling -lclangIndex -lclangFrontend -lclangParse -lclangSerialization \
-lclangSema -lclangEdit -lclangAnalysis -lclangDriver -lclangDynamicASTMatchers \
-lclangASTMatchers -lclangToolingCore -lclangAST -lclangLex -lclangBasic
win32:CLANGTOOLING_LIBS += -lversion
BIN_EXTENSION =
win32: BIN_EXTENSION = .exe
isEmpty(LLVM_INSTALL_DIR) {
unix {
llvm_config = $$system(which llvm-config-7)
}
isEmpty(llvm_config) {
llvm_config = llvm-config
}
} else {
exists($$LLVM_INSTALL_DIR/bin/llvm-config-7$$BIN_EXTENSION) {
llvm_config = $$system_quote($$LLVM_INSTALL_DIR/bin/llvm-config-7)
} else {
llvm_config = $$system_quote($$LLVM_INSTALL_DIR/bin/llvm-config)
requires(exists($$llvm_config$$BIN_EXTENSION))
}
}
output = $$system($$llvm_config --version, lines)
LLVM_VERSION = $$extractVersion($$output)
!isEmpty(LLVM_VERSION) {
versionIsAtLeast($$LLVM_VERSION, 7, 0, 0): {
CLANGFORMAT_LIBS=-lclangFormat -lclangToolingInclusions -lclangToolingCore -lclangRewrite -lclangLex -lclangBasic
win32:CLANGFORMAT_LIBS += -lversion
} else:versionIsAtLeast($$LLVM_VERSION, 6, 0, 0): {
CLANGFORMAT_LIBS=-lclangFormat -lclangToolingCore -lclangRewrite -lclangLex -lclangBasic
win32:CLANGFORMAT_LIBS += -lversion
}
}
isEmpty(LLVM_VERSION) {
$$llvmWarningOrError(\
"Cannot determine clang version. Set LLVM_INSTALL_DIR to build the Clang Code Model",\
"LLVM_INSTALL_DIR does not contain a valid llvm-config, candidate: $$llvm_config")
} else:!versionIsAtLeast($$LLVM_VERSION, 6, 0, 0): {
# CLANG-UPGRADE-CHECK: Adapt minimum version numbers.
$$llvmWarningOrError(\
"LLVM/Clang version >= 6.0.0 required, version provided: $$LLVM_VERSION")
LLVM_VERSION =
} else {
# CLANG-UPGRADE-CHECK: Remove suppression if this warning is resolved.
gcc {
# GCC6 shows full version (6.4.0), while GCC7 and up show only major version (8)
GCC_VERSION = $$system("$$QMAKE_CXX -dumpversion")
GCC_MAJOR_VERSION = $$section(GCC_VERSION, ., 0, 0)
# GCC8 warns about memset/memcpy for types with copy ctor. Clang has some of these.
greaterThan(GCC_MAJOR_VERSION, 7):QMAKE_CXXFLAGS += -Wno-class-memaccess
}
LLVM_LIBDIR = $$quote($$system($$llvm_config --libdir, lines))
LLVM_BINDIR = $$quote($$system($$llvm_config --bindir, lines))
LLVM_INCLUDEPATH = $$system($$llvm_config --includedir, lines)
msvc {
# CLANG-UPGRADE-CHECK: Remove suppression if this warning is resolved.
# Suppress unreferenced formal parameter warnings
QMAKE_CXXFLAGS += -wd4100
LLVM_STATIC_LIBS_STRING += $$system($$llvm_config --libnames, lines)
} else {
LLVM_STATIC_LIBS_STRING += $$system($$llvm_config --libs, lines)
}
LLVM_STATIC_LIBS_STRING += $$system($$llvm_config --system-libs, lines)
LLVM_STATIC_LIBS = $$split(LLVM_STATIC_LIBS_STRING, " ")
LIBCLANG_MAIN_HEADER = $$LLVM_INCLUDEPATH/clang-c/Index.h
!exists($$LIBCLANG_MAIN_HEADER) {
$$llvmWarningOrError(\
"Cannot find libclang's main header file, candidate: $$LIBCLANG_MAIN_HEADER")
}
!exists($$LLVM_LIBDIR) {
$$llvmWarningOrError("Cannot detect lib dir for clang, candidate: $$LLVM_LIBDIR")
}
!exists($$LLVM_BINDIR) {
$$llvmWarningOrError("Cannot detect bin dir for clang, candidate: $$LLVM_BINDIR")
}
CLANG_LIB = $$findClangLibInLibDir($$LLVM_LIBDIR)
isEmpty(CLANG_LIB) {
$$llvmWarningOrError("Cannot find Clang shared library in $$LLVM_LIBDIR")
}
!contains(QMAKE_DEFAULT_LIBDIRS, $$LLVM_LIBDIR): LIBCLANG_LIBS = -L$${LLVM_LIBDIR}
LIBCLANG_LIBS += $${CLANG_LIB}
QTC_ENABLE_CLANG_LIBTOOLING=$$(QTC_ENABLE_CLANG_LIBTOOLING)
!isEmpty(QTC_ENABLE_CLANG_LIBTOOLING) {
!contains(QMAKE_DEFAULT_LIBDIRS, $$LLVM_LIBDIR): LIBTOOLING_LIBS = -L$${LLVM_LIBDIR}
LIBTOOLING_LIBS += $$CLANGTOOLING_LIBS $$LLVM_STATIC_LIBS
} else {
warning("Clang LibTooling is disabled. Set QTC_ENABLE_CLANG_LIBTOOLING to enable it.")
}
CLANGFORMAT_LIBS = -L$${LLVM_LIBDIR} $$CLANGFORMAT_LIBS $$LLVM_STATIC_LIBS
contains(QMAKE_DEFAULT_INCDIRS, $$LLVM_INCLUDEPATH): LLVM_INCLUDEPATH =
# Remove unwanted flags. It is a workaround for linking.
# It is not intended for cross compiler linking.
LLVM_CXXFLAGS *= $$system($$llvm_config --cxxflags, lines)
LLVM_CXXFLAGS ~= s,-fno-exceptions,
LLVM_CXXFLAGS ~= s,-std=c++11,
LLVM_CXXFLAGS ~= s,-std=c++0x,
LLVM_CXXFLAGS ~= s,-O\S*,
LLVM_CXXFLAGS ~= s,/O\S*,
LLVM_CXXFLAGS ~= s,/W4,
LLVM_CXXFLAGS ~= s,/EH\S*,
LLVM_CXXFLAGS ~= s,/M\S*,
LLVM_CXXFLAGS ~= s,/G\S*,
LLVM_CXXFLAGS ~= s,-Werror=\S*,
LLVM_CXXFLAGS ~= s,-Wcovered-switch-default,
LLVM_CXXFLAGS ~= s,-Wnon-virtual-dtor,
LLVM_CXXFLAGS ~= s,-Woverloaded-virtual,
LLVM_CXXFLAGS ~= s,-fPIC,
LLVM_CXXFLAGS ~= s,-pedantic,
LLVM_CXXFLAGS ~= s,-Wstring-conversion,
# split-dwarf needs objcopy which does not work via icecc out-of-the-box
LLVM_CXXFLAGS ~= s,-gsplit-dwarf,
LLVM_CXXFLAGS = $$splitFlags($$LLVM_CXXFLAGS)
LLVM_IS_COMPILED_WITH_RTTI = $$system($$llvm_config --has-rtti, lines)
unix:!disable_external_rpath:!contains(QMAKE_DEFAULT_LIBDIRS, $${LLVM_LIBDIR}) {
!macos: QMAKE_LFLAGS += -Wl,-z,origin
QMAKE_LFLAGS += -Wl,-rpath,$$shell_quote($${LLVM_LIBDIR})
}
}
|
