Long Live Dragon3!

A.k.a. Qt 3D Studio Runtime 2.0

Change-Id: I459564fe47dc3d4b294346a42b1b387c21bb4088
Reviewed-by: Qt CI Bot <qt_ci_bot@qt-project.org>
Reviewed-by: Andy Nichols <andy.nichols@qt.io>

1 files changed, 77 insertions, 0 deletions

diff --git a/res/effectlib/fresnelLayer.glsllib b/res/effectlib/fresnelLayer.glsllib
new file mode 100644
index 0000000..69a4786
--- /dev/null
+++ b/res/effectlib/fresnelLayer.glsllib
@@ -0,0 +1,77 @@
+float simpleFresnel( in vec3 N, in float ior, float fresnelPower )
+{
+    float F = ((1.0-ior) * (1.0-ior)) / ((1.0+ior) * (1.0+ior));
+    float fresnelGlancingAngle = clamp( 1.0 - dot(viewDir, N), 0.0, 1.0 );
+    float ratio = F + (1.0 - F) * pow(fresnelGlancingAngle, fresnelPower);
+
+    return ratio;
+}
+
+// PKC : A variation on the simple Schlick approach that also handles the characteristic
+// "dip" that metals exhibit.  The dip is very mild or virtually nonexisting in dielectrics,
+// but shows up in metals because of their strong incident reflectivity, and also allows for
+// colored metals like gold or copper to show their Fresnel hue shift as well because certain
+// components will have different baseline responses.
+vec3 pseudoFresnel( in vec3 N, in vec3 ior, float fresnelPower )
+{
+    vec3 F0 = ((vec3(1.0)-ior) * (vec3(1.0)-ior)) / ((vec3(1.0)+ior) * (vec3(1.0)+ior));
+
+    float fresnelGlancingAngle = clamp( 1.0 - dot(viewDir, N), 0.0, 1.0 );
+
+    float fresCurve = pow(fresnelGlancingAngle, fresnelPower);
+    vec3 dipCurve = F0 * sin( 3.1415926535 * fresCurve ) * 0.31830988618;
+
+    vec3 retCol = (vec3(1.0) - F0) * fresCurve;
+    retCol += F0 - dipCurve;
+    return clamp(retCol, 0.0, 1.0);
+}
+
+// look here: http://en.wikipedia.org/wiki/Fresnel_equations
+float fresnel( in float eta1, in float eta2, in float cosTheta1 )
+{
+  float etaInv = eta1 / eta2;
+  float cosTheta2 = 1.0f - ( 1.0f - cosTheta1 * cosTheta1 ) * ( etaInv * etaInv );
+  if ( 0.0f <= cosTheta2 )
+  {
+    cosTheta2 = sqrt( cosTheta2 );
+    float n1t1 = eta1 * cosTheta1;
+    float n1t2 = eta1 * cosTheta2;
+    float n2t1 = eta2 * cosTheta1;
+    float n2t2 = eta2 * cosTheta2;
+    float rs = ( n1t1 - n2t2 ) / ( n1t1 + n2t2 );
+    float rp = ( n1t2 - n2t1 ) / ( n1t2 + n2t1 );
+    float f = 0.5f * ( rs * rs + rp * rp );
+    return( clamp( f, 0.0, 1.0 ) );
+  }
+  else
+  {
+    return( 1.0f );
+  }
+}
+
+// we assume, light rays run through air with ior == 1.0f
+// with eta = eta2 / eta1, we have
+//  - when hitting a front face: eta2 == ior, eta1 == 1.0f => eta = ior
+//  - when hitting a back face : eta2 == 1.0f, eta1 == ior => eta = 1.0f / ior
+vec3 fresnel( in vec3 N, in vec3 ior )
+{
+  float cosTheta1 = dot( N, viewDir );
+  if ( gl_FrontFacing )
+  {
+    return( vec3( fresnel( 1.0f, ior[0], cosTheta1 ), fresnel( 1.0f, ior[1], cosTheta1 ), fresnel( 1.0f, ior[2], cosTheta1 ) ) );
+  }
+  else
+  {
+    return( vec3( fresnel( ior[0], 1.0f, cosTheta1 ), fresnel( ior[1], 1.0f, cosTheta1 ), fresnel( ior[2], 1.0f, cosTheta1 ) ) );
+  }
+}
+
+vec4 fresnelLayer( in vec3 N, in vec3 ior, in float weight, in vec3 layercolor, in vec4 layer, in vec4 base, in float alpha )
+{
+  vec3 refl = reflect( -viewDir, N );
+  float reflWt = clamp( dot( surfNormal, refl ) + 1.0, 0.0, 1.0 );
+
+  vec3 fresColor = reflWt * weight * layercolor * pseudoFresnel( N, ior, 5.0 );
+
+  return( vec4( mix( base.rgb, layer.rgb, fresColor ), mix(alpha, 1.0, luminance(fresColor)) ) );
+}