blob: 0dabe5fc07b3be6ecd7940e1667c4b64f2618b3c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
TARGET = qscene3ds
include(../../qpluginbase.pri)
include(../../../../pkg.pri)
HEADERS += qgl3dsloader.h \
qgl3dsscene.h \
qgl3dsscenehandler.h \
qgl3dsmesh.h
SOURCES += main.cpp \
qgl3dsloader.cpp \
qgl3dsscene.cpp \
qgl3dsscenehandler.cpp \
qgl3dsmesh.cpp
# See the README in the root dir re this code
package {
macx:CONFIG(qt_framework, qt_framework|qt_no_framework) {
LIBS += -framework Qt3D -F../../../threed
INCLUDEPATH += ../../../threed/Qt3D.framework/Versions/1/Headers
} else {
win32 {
CONFIG(debug, debug|release) {
TARGET = $$member(TARGET, 0)d
LIBS += ..\\..\\..\\threed\\debug\\Qt3Dd.lib
} else {
LIBS += ..\\..\\..\\threed\\release\\Qt3D.lib
}
} else {
LIBS += -L../../../threed -lQt3D
}
INCLUDEPATH += ../../../../include/Qt3D
}
target.path = $$QT3D_INSTALL_PLUGINS/sceneformats]
INSTALLS += target
} else {
CONFIG += qt3d
DESTDIR = $$QT3D_INSTALL_PLUGINS/sceneformats
}
system_3ds {
!isEmpty(QMAKE_INCDIR_3DS):INCLUDEPATH += $$QMAKE_INCDIR_3DS
!isEmpty(QMAKE_LIBDIR_3DS):LIBS += -L$$QMAKE_LIBDIR_3DS
!isEmpty(QMAKE_LIBS_3DS):LIBS += -l$$QMAKE_LIBS_3DS
else {
win32:LIBS += -llib3ds-1_3
else:LIBS += -l3ds
}
} else {
include(../../../../3rdparty/lib3ds/lib3ds.pri)
}
|