1 files changed, 46 insertions, 0 deletions
diff --git a/src/src.pro b/src/src.pro
new file mode 100644
index 0000000..b2b9f6d
--- /dev/null
+++ b/src/src.pro
@@ -0,0 +1,46 @@
+TEMPLATE = lib
+TARGET = fibers
+
+HEADERS += fiber.h
+SOURCES += fiber.cpp
+
+INCLUDEPATH += .
+DEPENDPATH += .
+
+contains(QMAKE_CXX,g++) {
+    win32 {
+        # will fail for 64 bit win!
+        SOURCES += \
+            backend/switchstack_gcc_32_win.cpp \
+            backend/initializestack_32.cpp
+    }
+
+    mac {
+        CONFIG(x86_64) {
+            SOURCES += \
+                backend/switchstack_gcc_64_linux_mac.s \
+                backend/initializestack_64_linux_mac.cpp
+        } else {
+            SOURCES += \
+                backend/switchstack_gcc_32_linux_mac.s \
+                backend/initializestack_32.cpp
+        }
+    }
+    !win32:!mac {
+        contains(QMAKE_CFLAGS,-m64) {
+            SOURCES += \
+                backend/switchstack_gcc_64_linux_mac.s \
+                backend/initializestack_64_linux_mac.cpp
+        } else {
+            SOURCES += \
+                backend/switchstack_gcc_32_linux_mac.s \
+                backend/initializestack_32.cpp
+        }
+    }
+}
+win32:contains(QMAKE_CXX,cl) {
+    # will fail for 64 bit win!
+    SOURCES += \
+        backend/switchstack_msvc_32.cpp \
+        backend/initializestack_32.cpp
+}