1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
|
/****************************************************************************
**
** Copyright (c) 2011 Nokia Corporation and/or its subsidiary(-ies).
** All rights reserved.
** Contact: Yoann Lopes (yoann.lopes@nokia.com)
**
** This file is part of the MeeSpot project.
**
** Redistribution and use in source and binary forms, with or without
** modification, are permitted provided that the following conditions
** are met:
**
** Redistributions of source code must retain the above copyright notice,
** this list of conditions and the following disclaimer.
**
** Redistributions in binary form must reproduce the above copyright
** notice, this list of conditions and the following disclaimer in the
** documentation and/or other materials provided with the distribution.
**
** Neither the name of Nokia Corporation and its Subsidiary(-ies) nor the names of its
** contributors may be used to endorse or promote products derived from
** this software without specific prior written permission.
**
** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
** FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
** HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED
** TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
** PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
** LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
** NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
** SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
**
** If you have questions regarding the use of this file, please contact
** Nokia at qt-info@nokia.com.
**
****************************************************************************/
import QtQuick 1.1
import com.meego 1.0
import "UIConstants.js" as UI
Item {
id: listItem
signal clicked
signal pressAndHold
property alias pressed: mouseArea.pressed
property alias name: mainText.text
property alias artistAndAlbum: subText.text
property alias duration: timing.text
property alias coverId: coverImage.spotifyId
property bool highlighted: false
property bool starred: false
property bool available: true
property bool pressAndHoldEnabled: true
property bool showIndex: false
property color highlightColor: UI.SPOTIFY_COLOR
property int titleSize: UI.LIST_TILE_SIZE
property string titleFont: UI.FONT_FAMILY_BOLD
property color titleColor: theme.inverted ? UI.LIST_TITLE_COLOR_INVERTED : UI.LIST_TITLE_COLOR
property int subtitleSize: UI.LIST_SUBTILE_SIZE
property string subtitleFont: UI.FONT_FAMILY_LIGHT
property color subtitleColor: theme.inverted ? UI.LIST_SUBTITLE_COLOR_INVERTED : UI.LIST_SUBTITLE_COLOR
property real backgroundOpacity: 0.0
height: UI.LIST_ITEM_HEIGHT
width: parent.width
SequentialAnimation {
id: backAnimation
property bool animEnded: false
running: mouseArea.pressed && listItem.pressAndHoldEnabled
ScriptAction { script: backAnimation.animEnded = false }
PauseAnimation { duration: 200 }
ParallelAnimation {
NumberAnimation { target: background; property: "opacity"; to: 0.4; duration: 300 }
ColorAnimation { target: mainText; property: "color"; to: "black"; duration: 300 }
ColorAnimation { target: subText; property: "color"; to: "black"; duration: 300 }
ColorAnimation { target: timing; property: "color"; to: "black"; duration: 300 }
NumberAnimation { target: iconItem; property: "opacity"; to: 0.2; duration: 300 }
NumberAnimation { target: coverContainer; property: "opacity"; to: 0.2; duration: 300 }
}
PauseAnimation { duration: 100 }
ScriptAction { script: { backAnimation.animEnded = true; listItem.pressAndHold(); } }
onRunningChanged: {
if (!running) {
coverContainer.opacity = available ? 1.0 : 0.2
iconItem.opacity = 1.0
mainText.color = highlighted ? listItem.highlightColor : listItem.titleColor
subText.color = highlighted ? listItem.highlightColor : listItem.subtitleColor
timing.color = highlighted ? listItem.highlightColor : listItem.subtitleColor
}
}
}
onHighlightedChanged: {
mainText.color = highlighted ? listItem.highlightColor : listItem.titleColor
subText.color = highlighted ? listItem.highlightColor : listItem.subtitleColor
timing.color = highlighted ? listItem.highlightColor : listItem.subtitleColor
}
Rectangle {
id: background
anchors.fill: parent
// Fill page porders
anchors.leftMargin: -UI.MARGIN_XLARGE
anchors.rightMargin: -UI.MARGIN_XLARGE
opacity: mouseArea.pressed ? 1.0 : backgroundOpacity
color: "#22FFFFFF"
}
Label {
id: indexText
anchors.left: parent.left
anchors.verticalCenter: parent.verticalCenter
width: listItem.showIndex ? 48 : 0
text: (index + 1) + ". "
font.family: UI.FONT_FAMILY_LIGHT
font.pixelSize: UI.FONT_SMALL
horizontalAlignment: Text.AlignRight
visible: listItem.showIndex
}
Rectangle {
id: coverContainer
width: coverImage.spotifyId.length > 0 ? 64 : 0; height: width
anchors.left: indexText.right
anchors.verticalCenter: parent.verticalCenter
color: "#202020"
opacity: listItem.available ? 1.0 : 0.2
SpotifyImage {
id: coverImage
anchors.fill: parent
}
}
Column {
anchors.left: coverContainer.right
anchors.leftMargin: coverImage.spotifyId.length > 0 ? UI.MARGIN_XLARGE : 0
anchors.right: parent.right
anchors.verticalCenter: parent.verticalCenter
opacity: listItem.available ? 1.0 : 0.3
Item {
height: mainText.height
anchors.left: parent.left
anchors.right: parent.right
Label {
id: mainText
anchors.left: parent.left
anchors.right: iconItem.left
anchors.rightMargin: UI.MARGIN_XLARGE
font.family: listItem.titleFont
font.weight: Font.Bold
font.pixelSize: listItem.titleSize
color: highlighted ? listItem.highlightColor : listItem.titleColor
elide: Text.ElideRight
Behavior on color { ColorAnimation { duration: 200 } }
}
Image {
id: iconItem
anchors.right: parent.right
anchors.bottom: mainText.bottom
anchors.bottomMargin: 2
width: 34; height: width
smooth: true
visible: listItem.starred
source: "image://theme/icon-m-toolbar-favorite-mark-white"
}
}
Item {
height: subText.height
anchors.left: parent.left
anchors.right: parent.right
Label {
id: subText
anchors.left: parent.left
anchors.right: timing.left
anchors.rightMargin: UI.MARGIN_XLARGE
font.family: listItem.subtitleFont
font.pixelSize: listItem.subtitleSize
font.weight: Font.Light
color: highlighted ? listItem.highlightColor : listItem.subtitleColor
elide: Text.ElideRight
visible: text != ""
Behavior on color { ColorAnimation { duration: 200 } }
}
Label {
id: timing
font.family: listItem.subtitleFont
font.weight: Font.Light
font.pixelSize: listItem.subtitleSize
color: highlighted ? listItem.highlightColor : listItem.subtitleColor
anchors.right: parent.right
visible: text != ""
Behavior on color { ColorAnimation { duration: 200 } }
}
}
}
MouseArea {
id: mouseArea;
anchors.fill: parent
onClicked: {
if (!backAnimation.animEnded)
listItem.clicked();
}
}
}
|
