blob: 4ba67b8e0f54efbcd46c83be4ac1a5686f9dbda5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Adapted from doc/doc.pri in Qt Creator.
QDOC_BIN = $$[QT_INSTALL_BINS]/qdoc3
win32:QDOC_BIN = $$replace(QDOC_BIN, "/", "\\")
unix {
QDOC = SRCDIR=$$PWD OUTDIR=$$OUT_PWD/doc/html QT_MOBILITY_SOURCE_PATH=$$QT_MOBILITY_SOURCE_PATH $$QDOC_BIN
HELPGENERATOR = $$[QT_INSTALL_BINS]/qhelpgenerator
} else {
QDOC = set SRCDIR=$$PWD&& set OUTDIR=$$OUT_PWD/doc/html&& set QT_MOBILITY_SOURCE_PATH=$$QT_MOBILITY_SOURCE_PATH&& $$QDOC_BIN
# Always run qhelpgenerator inside its own cmd; this is a workaround for
# an unusual bug which causes qhelpgenerator.exe to do nothing
HELPGENERATOR = cmd /C $$replace($$list($$[QT_INSTALL_BINS]/qhelpgenerator.exe), "/", "\\")
}
QHP_FILE = $$OUT_PWD/doc/html/simulator.qhp
QCH_FILE = $$OUT_PWD/doc/simulator.qch
unix {
html_docs.commands = $$QDOC $$PWD/simulator.qdocconf
} else {
html_docs.commands = \"$$QDOC $$PWD/simulator.qdocconf\"
}
html_docs.depends += $$PWD/simulator.qdoc $$PWD/scripting.qdoc $$PWD/simulator.qdocconf $$PWD/qt-defines.qdocconf $$PWD/qt-html-templates.qdocconf
html_docs.files = $$QHP_FILE
qch_docs.commands = $$HELPGENERATOR -o $$QCH_FILE $$QHP_FILE
qch_docs.depends += html_docs
qch_docs.files = $$QCH_FILE
unix:!macx {
qch_docs.path = $$PREFIX/doc
qch_docs.CONFIG += no_check_exist
INSTALLS += qch_docs
}
macx {
DOC_DIR = "$${OUT_PWD}/bin/Simulator.app/Contents/Resources/doc"
cp_docs.commands = mkdir -p \"$${DOC_DIR}\" ; $${QMAKE_COPY} \"$${QCH_FILE}\" \"$${DOC_DIR}\"
cp_docs.depends += qch_docs
docs.depends = cp_docs
QMAKE_EXTRA_TARGETS += html_docs qch_docs cp_docs docs
}
!macx {
docs.depends = qch_docs
QMAKE_EXTRA_TARGETS += html_docs qch_docs docs
}
OTHER_FILES = $$PWD/simulator.qdoc \
$$PWD/scripting.qdoc \
$$PWD/simulator.qdocconf
|