tests/auto/qmimedatabase/qmimedatabase-xml/qmimedatabase-xml.pro


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

include(../../../../mimetypes-nolibs.pri)
LIBS += -L$$OUT_PWD/../../../../src/mimetypes -lQtMimeTypes

TEMPLATE = app

TARGET = tst_qmimedatabase-xml

QT       += testlib

QT       -= widgets gui

CONFIG   += console
CONFIG   -= app_bundle

CONFIG += depend_includepath

SOURCES += tst_qmimedatabase-xml.cpp
HEADERS += ../tst_qmimedatabase.h

contains(QMAKE_CXX, --sysroot): {
    unix:!symbian {
        maemo5 {
            DEFINES += SRCDIR='"\\"/opt/usr/lib/QtMimeTypes-tests/\\""'
        } else {
            DEFINES += SRCDIR='"\\"/usr/lib/QtMimeTypes-tests/\\""'
        }
    }
} else {
    DEFINES += SRCDIR='"\\"$$PWD/../\\""'

    QMAKE_EXTRA_TARGETS += check
    check.depends = $$TARGET
    check.commands = ./$$TARGET -xunitxml -o $${TARGET}.xml
}

QMAKE_CXXFLAGS += -W -Wall -Wextra -Werror -Wshadow -Wno-long-long -Wnon-virtual-dtor

unix:!symbian {
    maemo5 {
        target.path = /opt/usr/lib/QtMimeTypes-tests/qmimedatabase-xml
    } else {
        target.path = /usr/lib/QtMimeTypes-tests/qmimedatabase-xml
    }
    INSTALLS += target
}