1 files changed, 144 insertions, 0 deletions
diff --git a/sources/pyside2/doc/codesnippets/doc/src/snippets/qmacnativewidget/main.mm b/sources/pyside2/doc/codesnippets/doc/src/snippets/qmacnativewidget/main.mm
new file mode 100644
index 000000000..36d6927ee
--- /dev/null
+++ b/sources/pyside2/doc/codesnippets/doc/src/snippets/qmacnativewidget/main.mm
@@ -0,0 +1,144 @@
+/****************************************************************************
+**
+** Copyright (C) 2016 The Qt Company Ltd.
+** Contact: https://www.qt.io/licensing/
+**
+** This file is part of the documentation of PySide2.
+**
+** $QT_BEGIN_LICENSE:BSD$
+** Commercial License Usage
+** Licensees holding valid commercial Qt licenses may use this file in
+** accordance with the commercial license agreement provided with the
+** Software or, alternatively, in accordance with the terms contained in
+** a written agreement between you and The Qt Company. For licensing terms
+** and conditions see https://www.qt.io/terms-conditions. For further
+** information use the contact form at https://www.qt.io/contact-us.
+**
+** BSD License Usage
+** Alternatively, you may use this file under the terms of the BSD license
+** as follows:
+**
+** "Redistribution and use in source and binary forms, with or without
+** modification, are permitted provided that the following conditions are
+** met:
+**   * Redistributions of source code must retain the above copyright
+**     notice, this list of conditions and the following disclaimer.
+**   * Redistributions in binary form must reproduce the above copyright
+**     notice, this list of conditions and the following disclaimer in
+**     the documentation and/or other materials provided with the
+**     distribution.
+**   * Neither the name of The Qt Company Ltd nor the names of its
+**     contributors may be used to endorse or promote products derived
+**     from this software without specific prior written permission.
+**
+**
+** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
+** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
+** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
+** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
+** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
+** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
+** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
+** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+#include <QtGui/QtGui>
+#include <QtGui/qmacnativewidget_mac.h>
+#ifdef QT_MAC_USE_COCOA
+#import <Cocoa/Cocoa.h>
+#else
+#include <Carbon/Carbon.h>
+#endif
+
+int main(int argc, char **argv)
+{
+    QApplication app(argc, argv);
+#ifdef QT_MAC_USE_COCOA
+//![0]
+    NSAutoreleasePool *pool = [[NSAutoreleasePool alloc] init];
+    NSWindow *window = [[NSWindow alloc] initWithContentRect:NSMakeRect(200, app.desktop()->height() - 200, 239, 200)
+                        styleMask:NSTitledWindowMask | NSClosableWindowMask
+                                  | NSMiniaturizableWindowMask | NSResizableWindowMask
+                        backing:NSBackingStoreBuffered defer:NO];
+
+    QMacNativeWidget *nativeWidget = new QMacNativeWidget();
+    nativeWidget->move(0, 0);
+    nativeWidget->setPalette(QPalette(Qt::red));
+    nativeWidget->setAutoFillBackground(true);
+    QVBoxLayout *layout = new QVBoxLayout();
+    QPushButton *pushButton = new QPushButton("An Embedded Qt Button!", nativeWidget);
+    pushButton->setAttribute(Qt::WA_LayoutUsesWidgetRect); // Don't use the layout rect calculated from QMacStyle.
+    layout->addWidget(pushButton);
+    nativeWidget->setLayout(layout);
+
+    // Adjust Cocoa layouts
+    NSView *nativeWidgetView = reinterpret_cast<NSView *>(nativeWidget->winId());
+    NSView *contentView = [window contentView];
+    [contentView setAutoresizesSubviews:YES];
+    [nativeWidgetView setAutoresizingMask:NSViewWidthSizable | NSViewHeightSizable];
+    [nativeWidgetView setAutoresizesSubviews:YES];
+    NSView *pushButtonView = reinterpret_cast<NSView *>(pushButton->winId());
+    [pushButtonView setAutoresizingMask:NSViewWidthSizable];
+
+    // Add the nativeWidget to the window.
+    [contentView addSubview:nativeWidgetView positioned:NSWindowAbove relativeTo:nil];
+    nativeWidget->show();
+    pushButton->show();
+
+    // Show the window.
+    [window makeKeyAndOrderFront:window];
+    [pool release];
+//![0]
+#else
+//![1]
+    Rect contentRect;
+    SetRect(&contentRect, 200, 200, 400, 400);
+    HIWindowRef windowRef;
+    CreateNewWindow(kDocumentWindowClass, kWindowStandardDocumentAttributes | kWindowCompositingAttribute | kWindowStandardHandlerAttribute | kWindowLiveResizeAttribute, &contentRect, &windowRef);
+    HIViewRef contentView = 0;
+    GetRootControl(windowRef, &contentView);
+
+    QMacNativeWidget *nativeWidget = new QMacNativeWidget();
+    nativeWidget->move(0, 0);
+    nativeWidget->setPalette(QPalette(Qt::red));
+    nativeWidget->setAutoFillBackground(true);
+    QVBoxLayout *layout = new QVBoxLayout();
+    QPushButton *pushButton = new QPushButton("An Embedded Qt Button!", nativeWidget);
+    pushButton->setAttribute(Qt::WA_LayoutUsesWidgetRect); // Don't use the layout rect calculated from QMacStyle.
+    layout->addWidget(pushButton);
+    nativeWidget->setLayout(layout);
+    HIViewRef nativeWidgetView = reinterpret_cast<HIViewRef>(nativeWidget->winId());
+    // Add the nativeWidget to the window.
+    HIViewAddSubview(contentView, nativeWidgetView);
+
+    // Adjust Carbon layouts
+    HILayoutInfo layoutInfo;
+    layoutInfo.version = kHILayoutInfoVersionZero;
+    HIViewGetLayoutInfo(nativeWidgetView, &layoutInfo);
+
+    layoutInfo.binding.top.toView = contentView;
+    layoutInfo.binding.top.kind = kHILayoutBindTop;
+    layoutInfo.binding.left.toView = contentView;
+    layoutInfo.binding.left.kind = kHILayoutBindLeft;
+    layoutInfo.binding.right.toView = contentView;
+    layoutInfo.binding.right.kind = kHILayoutBindRight;
+    layoutInfo.binding.bottom.toView = contentView;
+    layoutInfo.binding.bottom.kind = kHILayoutBindBottom;
+
+    HIViewSetLayoutInfo(nativeWidgetView, &layoutInfo);
+    HIViewApplyLayout(nativeWidgetView);
+
+    pushButton->show();
+    nativeWidget->show();
+    // Show the window.
+    ShowWindow(windowRef);
+//![1]
+#endif
+    return app.exec(); // gives us the same behavior in both
+}