1 files changed, 80 insertions, 0 deletions
diff --git a/styles/triton/ItemDelegate.qml b/styles/triton/ItemDelegate.qml
new file mode 100644
index 00000000..3c913c83
--- /dev/null
+++ b/styles/triton/ItemDelegate.qml
@@ -0,0 +1,80 @@
+/****************************************************************************
+**
+** Copyright (C) 2017 Pelagicore AG
+** Contact: https://www.qt.io/licensing/
+**
+** This file is part of the Triton IVI UI.
+**
+** $QT_BEGIN_LICENSE:GPL-QTAS$
+** Commercial License Usage
+** Licensees holding valid commercial Qt Automotive Suite licenses may use
+** this file in accordance with the commercial license agreement provided
+** with the Software or, alternatively, in accordance with the terms
+** contained in a written agreement between you and The Qt Company.  For
+** licensing terms and conditions see https://www.qt.io/terms-conditions.
+** For further information use the contact form at https://www.qt.io/contact-us.
+**
+** GNU General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU
+** General Public License version 3 or (at your option) any later version
+** approved by the KDE Free Qt Foundation. The licenses are as published by
+** the Free Software Foundation and appearing in the file LICENSE.GPL3
+** included in the packaging of this file. Please review the following
+** information to ensure the GNU General Public License requirements will
+** be met: https://www.gnu.org/licenses/gpl-3.0.html.
+**
+** $QT_END_LICENSE$
+**
+** SPDX-License-Identifier: GPL-3.0
+**
+****************************************************************************/
+
+import QtQuick 2.8
+import QtQuick.Templates 2.1 as T
+import com.pelagicore.styles.triton 1.0
+
+T.ItemDelegate {
+    id: control
+
+    implicitWidth: Math.max(background ? background.implicitWidth : 0,
+                            contentItem.implicitWidth + leftPadding + rightPadding)
+    implicitHeight: Math.max(background ? background.implicitHeight : 0,
+                             Math.max(contentItem.implicitHeight,
+                                      indicator ? indicator.implicitHeight : 0) + topPadding + bottomPadding)
+    baselineOffset: contentItem.y + contentItem.baselineOffset
+
+    spacing: 12
+
+    padding: 12
+    topPadding: padding - 1
+    bottomPadding: padding + 1
+
+    contentItem: Text {
+        leftPadding: !control.mirrored ? (control.indicator ? control.indicator.width : 0) + control.spacing : 0
+        rightPadding: control.mirrored ? (control.indicator ? control.indicator.width : 0) + control.spacing : 0
+
+        text: control.text
+        font: control.font
+        elide: Text.ElideRight
+        visible: control.text
+        horizontalAlignment: Text.AlignLeft
+        verticalAlignment: Text.AlignVCenter
+
+        opacity: enabled ? 1.0 : 0.2
+        color: control.TritonStyle.brightColor
+    }
+
+    background: Rectangle {
+        visible: control.down || control.highlighted || control.visualFocus || control.hovered
+        color: control.down ? TritonStyle.lighter25(TritonStyle.darkColor) :
+               control.hovered ? TritonStyle.lighter50(TritonStyle.darkColor) : TritonStyle.lighter50(TritonStyle.darkColor)
+        Rectangle {
+            width: parent.width
+            height: parent.height
+            visible: control.visualFocus || control.highlighted
+            color: control.TritonStyle.accentColor
+            opacity: control.TritonStyle.theme === TritonStyle.Light ? 0.4 : 0.6
+        }
+
+    }
+}