blob: ec11c497b9dda838a88f3d1783c65f3c2ad5b7b7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
|
/****************************************************************************
**
** Copyright (C) 2019 Luxoft Sweden AB
** Copyright (C) 2018 Pelagicore AG
** Contact: https://www.qt.io/licensing/
**
** This file is part of the Neptune 3 UI.
**
** $QT_BEGIN_LICENSE:GPL-QTAS$
** Commercial License Usage
** Licensees holding valid commercial Qt Automotive Suite licenses may use
** this file in accordance with the commercial license agreement provided
** with the Software or, alternatively, in accordance with the terms
** contained in a written agreement between you and The Qt Company. For
** licensing terms and conditions see https://www.qt.io/terms-conditions.
** For further information use the contact form at https://www.qt.io/contact-us.
**
** GNU General Public License Usage
** Alternatively, this file may be used under the terms of the GNU
** General Public License version 3 or (at your option) any later version
** approved by the KDE Free Qt Foundation. The licenses are as published by
** the Free Software Foundation and appearing in the file LICENSE.GPL3
** included in the packaging of this file. Please review the following
** information to ensure the GNU General Public License requirements will
** be met: https://www.gnu.org/licenses/gpl-3.0.html.
**
** $QT_END_LICENSE$
**
** SPDX-License-Identifier: GPL-3.0
**
****************************************************************************/
import QtQuick 2.8
import QtQuick.Controls 2.3
import shared.controls 1.0
import shared.utils 1.0
import shared.Style 1.0
import shared.Sizes 1.0
import "../controls"
import "../assets"
Control {
id: root
property bool wifiEnabled: false
property string selectedWiFiStatus: "Disconnected" //Disconnected, Connecting, Connected or Disconnecting
property string selectedWiFiSSID: ""
property bool _wifiSelected: selectedWiFiStatus !== "Disconnected"
property string _selectedWiFiStatusText: selectedWiFiStatus === "Disconnected" ? "Disconnecting" : selectedWiFiStatus
property Item rootItem
property var wifiAccessPointsList
signal connectToWiFiClicked ( string ssid )
signal disconnectFromWiFiClicked ( string ssid )
signal backButtonClicked()
signal passwordProvided( string ssid, string password )
signal connectionCancelled()
onConnectToWiFiClicked: flickable.contentY = 0
contentItem: Flickable {
id: flickable
width: parent.width
height: parent.height
clip: true
flickableDirection: Flickable.VerticalFlick
interactive: contentHeight > height
contentHeight: column1.height
ScrollIndicator.vertical: ScrollIndicator { }
Column {
id:column1
Item {
id: listHeader
width: Sizes.dp(720)
height: Sizes.dp(94)
ToolButton {
id: backButton
objectName: "backButton"
anchors.left: parent.left
anchors.leftMargin: Sizes.dp(13.5)
anchors.verticalCenter: parent.verticalCenter
icon.name: LayoutMirroring.enabled ? "ic_forward" : "ic_back"
onClicked: root.backButtonClicked()
}
Label {
id: headerLabel
width: Sizes.dp(600)
anchors.horizontalCenter: parent.horizontalCenter
anchors.verticalCenter: parent.verticalCenter
horizontalAlignment: Text.AlignHCenter
font.pixelSize: Sizes.fontSizeS
elide: Text.ElideRight
text: qsTr("Wi-Fi")
}
Rectangle {
id: headerDivider
width: parent.width
height: Sizes.dp(1)
anchors.bottom: parent.bottom
color: "grey"
}
}
Item {
id: spacing0
width: parent.width
height: Sizes.dp(53)
}
SwitchDelegate {
text: qsTr("Wi-Fi Enabled")
width: root.width
checked: root.wifiEnabled
onToggled: root.wifiEnabled = checked
}
Item {
width: root.width
height: root.wifiEnabled && root._wifiSelected ? activeWiFi.height + spacing1.height : 0.0
clip: true
opacity: root.wifiEnabled && root._wifiSelected ? 1.0 : 0.4
Behavior on height { NumberAnimation { duration: 200; easing.type: Easing.InOutQuad } }
Behavior on opacity { NumberAnimation { duration: 200; easing.type: Easing.InOutQuad } }
visible: height > 0.0
Column {
width: parent.width
Item {
id: spacing1
width: parent.width
height: Sizes.dp(40)
}
ListItemBasic {
id: activeWiFi
text: root.selectedWiFiSSID
subText: root._selectedWiFiStatusText
width: parent.width
dividerVisible: false
accessoryDelegateComponent1: Button {
implicitHeight: contentItem.implicitHeight + topPadding + bottomPadding
implicitWidth: contentItem.implicitWidth + leftPadding + rightPadding
leftPadding: Sizes.dp(30)
rightPadding: Sizes.dp(30)
topPadding: Sizes.dp(8)
bottomPadding: Sizes.dp(8)
text: qsTr("Disconnect")
enabled: root.selectedWiFiStatus !== "Disconnecting"
font.pixelSize: Sizes.fontSizeS
onClicked: root.disconnectFromWiFiClicked( root.selectedWiFiSSID )
}
}
}
}
Item {
width: root.width
height: root.wifiEnabled ? contentColumn2.height : 0.0
clip: true
opacity: root.wifiEnabled ? 1.0 : 0.4
Behavior on height { NumberAnimation { duration: 200; easing.type: Easing.InOutQuad } }
Behavior on opacity { NumberAnimation { duration: 200; easing.type: Easing.InOutQuad } }
visible: height > 0.0
Column {
id: contentColumn2
width: parent.width
Item {
id: spacing2
width: root.width
height: Sizes.dp(40)
}
ListView {
id: wifiListView
width: root.width
height: Sizes.dp(96) * count
interactive: false
model: wifiAccessPointsList
delegate: ListItem {
width: root.width
height: Sizes.dp(96)
icon.source: {
if (model.modelData.strength >= 80) {
return Assets.icon("ic-wifi-signal-4");
} else if (model.modelData.strength >= 60) {
return Assets.icon("ic-wifi-signal-3");
} else if (model.modelData.strength >= 40) {
return Assets.icon("ic-wifi-signal-2");
} else if (model.modelData.strength >= 20) {
return Assets.icon("ic-wifi-signal-1");
} else {
return Assets.icon("ic-wifi-signal-0");
}
}
text: model.modelData.ssid
secondaryText: model.modelData.connected ? qsTr("Connected") : ""
rightToolSymbol: model.modelData.security != 0 ? "ic_secured_connection" : ""
dividerVisible: index !== wifiListView.count - 1
onClicked: root.connectToWiFiClicked(model.modelData.ssid)
}
}
Item {
id: spacing3
width: root.width
height: Sizes.dp(40)
}
/* TODO: The backend is not ready yet for hidden networks
ListItem {
id: manualConnection
rightToolSymbol: "ic-next-level"
dividerVisible: false
onClicked: {
var pos = mapToItem(root.rootItem, width/2, height/2);
wifiPopup.ssid = ""
wifiPopup.password = ""
wifiPopup.manual = true
wifiPopup.originItemX = pos.x;
wifiPopup.originItemY = pos.y;
wifiPopup.popupY = Sizes.dp(Math.round(Config.centerConsoleHeight/2 - 410))
wifiPopup.visible = true;
}
}
*/
}
}
}
}
}
|
