1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
|
/****************************************************************************
**
** Copyright (C) 2019 Luxoft Sweden AB
** Copyright (C) 2018 Pelagicore AG
** Contact: https://www.qt.io/licensing/
**
** This file is part of the Neptune 3 IVI UI.
**
** $QT_BEGIN_LICENSE:GPL-QTAS$
** Commercial License Usage
** Licensees holding valid commercial Qt Automotive Suite licenses may use
** this file in accordance with the commercial license agreement provided
** with the Software or, alternatively, in accordance with the terms
** contained in a written agreement between you and The Qt Company. For
** licensing terms and conditions see https://www.qt.io/terms-conditions.
** For further information use the contact form at https://www.qt.io/contact-us.
**
** GNU General Public License Usage
** Alternatively, this file may be used under the terms of the GNU
** General Public License version 3 or (at your option) any later version
** approved by the KDE Free Qt Foundation. The licenses are as published by
** the Free Software Foundation and appearing in the file LICENSE.GPL3
** included in the packaging of this file. Please review the following
** information to ensure the GNU General Public License requirements will
** be met: https://www.gnu.org/licenses/gpl-3.0.html.
**
** $QT_END_LICENSE$
**
** SPDX-License-Identifier: GPL-3.0
**
****************************************************************************/
import QtQuick 2.8
import QtQuick.Controls 2.3
import shared.utils 1.0
import shared.animations 1.0
import "../panels" 1.0
import "../controls" 1.0
import shared.Style 1.0
import shared.Sizes 1.0
Item {
id: root
property var store
signal flickableAreaClicked()
onStateChanged: {
//reset flickable
nextListFlickable.contentY = 0;
}
Item {
id: nextListFlickableItem
width: parent.width
height: (parent.height - artAndTitleBackground.height - progressBarBlock.height)
anchors.bottom: parent.bottom
opacity: 0
visible: opacity > 0
clip: true
Flickable {
id: nextListFlickable
anchors.fill: parent
contentWidth: parent.width
contentHeight: (nextList.height + musicTools.height + Sizes.dp(20))
ScrollIndicator.vertical: ScrollIndicator { }
Column {
id: nextListContent
Item { //spacer
width: nextListFlickable.width
height: musicTools.height
}
MusicPlayQueuePanel { //playing queue
id: nextList
width: nextListFlickable.width
height: (listView.count * Sizes.dp(104))
listView.model: store.musicPlaylist
listView.interactive: false
onItemClicked: {
store.musicPlaylist.currentIndex = index;
store.player.play();
}
}
Item { //spacer
width: nextListFlickable.width
height: Sizes.dp(20)
}
}
}
}
Rectangle {
id: artAndTitleBackground
height: Sizes.dp(260)
width: parent.width
color: Style.offMainColor
MouseArea {
//prevent clicking on list items when the list
//is scrolled under the header component
//should go to maximized state instead
anchors.fill: parent
enabled: (nextListFlickable.contentY > 0)
onClicked: {
root.flickableAreaClicked();
}
}
}
Image {
id: nextListShadow
opacity: 0
width: parent.width
height: sourceSize.height
anchors.top: artAndTitleBackground.bottom
source: Style.image("panel-inner-shadow")
}
AlbumArtPanel {
id: artAndTitlesBlock
height: Sizes.dp(180)
width: parent.width
anchors.verticalCenter: parent.verticalCenter
anchors.verticalCenterOffset: 0
songModel: store.musicPlaylist
currentIndex: store.musicPlaylist.currentIndex
currentSongTitle: store.currentEntry ? root.store.currentEntry.title : ""
currentArtisName: store.currentEntry ? root.store.currentEntry.artist : ""
parentStateMaximized: state === "Maximized"
mediaReady: store.searchAndBrowseModel.count > 0
musicPlaying: store.playing
onPlayClicked: store.playSong()
onPreviousClicked: store.previousSong()
onNextClicked: store.nextSong()
Connections {
target: store
onSongModelPopulated: { artAndTitlesBlock.populateModel(); }
}
}
MusicProgress {
id: progressBarBlock
width: Sizes.dp(880)
height: Sizes.dp(50)
anchors.horizontalCenter: parent.horizontalCenter
anchors.top: artAndTitlesBlock.bottom
anchors.topMargin: Sizes.dp(50)
opacity: 0
visible: opacity > 0
value: store.currentTrackPosition
progressText: store.elapsedTime + " / " + store.totalTime
onUpdatePosition: store.updatePosition(value)
}
MusicTools {
id: musicTools
anchors.top: progressBarBlock.bottom
anchors.right: progressBarBlock.right
onShuffleClicked: store.shuffleSong()
onRepeatClicked: store.repeatSong()
}
states: [
State {
name: "Widget1Row"
},
State {
name: "Widget2Rows"
PropertyChanges { target: root; height: Sizes.dp(550) }
PropertyChanges { target: artAndTitlesBlock; anchors.verticalCenterOffset: Sizes.dp(-62) }
PropertyChanges { target: progressBarBlock; anchors.verticalCenterOffset: Sizes.dp(138) }
PropertyChanges { target: progressBarBlock; opacity: 1 }
PropertyChanges { target: musicTools; opacity: 1 }
},
State {
name: "Widget3Rows"
PropertyChanges { target: root; height: Sizes.dp(840) }
PropertyChanges { target: nextListFlickableItem; opacity: 1 }
PropertyChanges { target: artAndTitlesBlock; anchors.verticalCenterOffset: Sizes.dp(-271) - Math.min(Sizes.dp(20), nextListFlickable.contentY / 6) }
PropertyChanges { target: progressBarBlock; anchors.verticalCenterOffset: Sizes.dp(-71) - Math.min(Sizes.dp(60), nextListFlickable.contentY / 2) }
PropertyChanges { target: progressBarBlock; opacity: 1 - Math.max(0, Math.min(1, nextListFlickable.contentY / 140)) }
PropertyChanges { target: musicTools; opacity: 1 - Math.max(0, Math.min(1, nextListFlickable.contentY / 140))}
PropertyChanges { target: nextListShadow; opacity: 0 + Math.max(0, Math.min(1, nextListFlickable.contentY / 140))}
},
State {
name: "Maximized"
PropertyChanges { target: root; height: Sizes.dp(660) - Sizes.dp(224) }
PropertyChanges { target: artAndTitleBackground; opacity: 0 } //todo: do something else here because it is blocking the gray background.
PropertyChanges { target: artAndTitlesBlock; anchors.verticalCenterOffset: Sizes.dp(-110) }
PropertyChanges { target: progressBarBlock; anchors.verticalCenterOffset: Sizes.dp(90) }
PropertyChanges { target: progressBarBlock; opacity: 1 }
PropertyChanges { target: musicTools; opacity: 1 }
}
]
transitions: [
Transition {
from: "Maximized"
DefaultNumberAnimation { targets: [progressBarBlock, musicTools, nextListFlickable, nextListFlickableItem, artAndTitlesBlock, root]; properties: "width, height, opacity, anchors.verticalCenterOffset" }
SequentialAnimation {
PauseAnimation { duration: 200 }
DefaultNumberAnimation { target: artAndTitleBackground ; property: "opacity" }
}
},
Transition {
DefaultNumberAnimation { targets: [progressBarBlock, musicTools, nextListFlickable, nextListFlickableItem, artAndTitlesBlock, root]; properties: "width, height, opacity, anchors.verticalCenterOffset" }
}
]
}
|
