blob: bdbf2892efbe344d47d94c323d799513ebde9857 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
|
/****************************************************************************
**
** Copyright (C) 2017-2018 Pelagicore AG
** Contact: https://www.qt.io/licensing/
**
** This file is part of the Neptune 3 IVI UI.
**
** $QT_BEGIN_LICENSE:GPL-QTAS$
** Commercial License Usage
** Licensees holding valid commercial Qt Automotive Suite licenses may use
** this file in accordance with the commercial license agreement provided
** with the Software or, alternatively, in accordance with the terms
** contained in a written agreement between you and The Qt Company. For
** licensing terms and conditions see https://www.qt.io/terms-conditions.
** For further information use the contact form at https://www.qt.io/contact-us.
**
** GNU General Public License Usage
** Alternatively, this file may be used under the terms of the GNU
** General Public License version 3 or (at your option) any later version
** approved by the KDE Free Qt Foundation. The licenses are as published by
** the Free Software Foundation and appearing in the file LICENSE.GPL3
** included in the packaging of this file. Please review the following
** information to ensure the GNU General Public License requirements will
** be met: https://www.gnu.org/licenses/gpl-3.0.html.
**
** $QT_END_LICENSE$
**
** SPDX-License-Identifier: GPL-3.0
**
****************************************************************************/
import QtQuick 2.11
import shared.controls 1.0
import shared.utils 1.0
import shared.animations 1.0
import shared.Sizes 1.0
/*!
\qmltype ApplicationCCWindow
\inqmlmodule application.windows
\inherits NeptuneWindow
\since 5.12
\brief The application center console window of a Neptune 3 application.
The application center console window of a Neptune 3 application is displayed on the Center Console.
This component also provides APIs for interacting with system UI and for positioning
the application's visual elements.
See \l{Neptune 3 UI Application Development} for best practices on how to use the APIs.
\section2 Example Usage
The following example uses \l{ApplicationCCWindow} as a root element:
\qml
import QtQuick 2.10
import application.windows 1.0
ApplicationCCWindow {
id: root
Background {
anchors.fill: parent
}
Content {
x: root.exposedRect.x
y: root.exposedRect.x
width: root.exposedRect.width
height: root.exposedRect.height
}
}
\endqml
*/
NeptuneWindow {
id: root
// A window can be occluded by some other UI elements such as floating widgets, virtual keyboards
// etc. In such cases you will want to relayout to that the important content is contained within
// exposedRect boundaries.
/*!
\qmlproperty rect ApplicationCCWindow::exposedRect
\readonly
This property holds the area of the window that is exposed to the user (ie, not blocked or
occluded by other UI elements)
*/
readonly property rect exposedRect: Qt.rect(0, d.exposedRectTopMargin, d.currentWidth, d.exposedRectHeight)
/*!
\qmlproperty int ApplicationCCWindow::targetHeight
\readonly
This property holds the target height of the application. This property will be updated
when the neptune state is being changed.
*/
readonly property int targetHeight: neptuneState === "Maximized" ? root.height : d.widgetHeight;
/*!
\qmlproperty int ApplicationCCWindow::currentHeight
This property holds the current height of the application.
*/
property int currentHeight
/*!
\qmlproperty string ApplicationCCWindow::neptuneState
This property holds the current state of the application. The valid values for neptuneState are
(Maximized, Widget1Row, Widget2Rows or Widget3Rows)
*/
property string neptuneState
QtObject {
id: d
property real exposedRectTopMargin: 0
Behavior on exposedRectTopMargin {DefaultNumberAnimation{}}
property real exposedRectBottomMargin: 0
Behavior on exposedRectBottomMargin {DefaultNumberAnimation{}}
property int widgetHeight: 0
property int currentWidth: 0
property int exposedRectHeight: Math.min(root.currentHeight, root.height - exposedRectBottomMargin - exposedRectTopMargin);
}
onWindowPropertyChanged: {
switch (name) {
case "exposedRectBottomMargin":
d.exposedRectBottomMargin = value;
break;
case "exposedRectTopMargin":
d.exposedRectTopMargin = value;
break;
case "neptuneWidgetHeight":
d.widgetHeight = value;
break;
case "neptuneCurrentWidth":
d.currentWidth = value;
break;
case "neptuneCurrentHeight":
root.currentHeight = value;
break;
case "neptuneState":
root.neptuneState = value;
break;
case "performanceMonitorEnabled":
monitorOverlay.fpsVisible = value;
break;
}
}
MonitorOverlay {
id: monitorOverlay
x: root.exposedRect.x
y: root.exposedRect.y
width: root.exposedRect.width - Sizes.dp(100)
height: root.exposedRect.height - Sizes.dp(50)
fpsVisible: false
window: root
z: 9999
}
}
|
