blob: 111259aa4b52275e59ffe12dbf98def338681b15 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
|
/****************************************************************************
**
** Copyright (C) 2019 Luxoft Sweden AB
** Copyright (C) 2018 Pelagicore AG
** Contact: https://www.qt.io/licensing/
**
** This file is part of the Neptune 3 UI.
**
** $QT_BEGIN_LICENSE:GPL-QTAS$
** Commercial License Usage
** Licensees holding valid commercial Qt Automotive Suite licenses may use
** this file in accordance with the commercial license agreement provided
** with the Software or, alternatively, in accordance with the terms
** contained in a written agreement between you and The Qt Company. For
** licensing terms and conditions see https://www.qt.io/terms-conditions.
** For further information use the contact form at https://www.qt.io/contact-us.
**
** GNU General Public License Usage
** Alternatively, this file may be used under the terms of the GNU
** General Public License version 3 or (at your option) any later version
** approved by the KDE Free Qt Foundation. The licenses are as published by
** the Free Software Foundation and appearing in the file LICENSE.GPL3
** included in the packaging of this file. Please review the following
** information to ensure the GNU General Public License requirements will
** be met: https://www.gnu.org/licenses/gpl-3.0.html.
**
** $QT_END_LICENSE$
**
** SPDX-License-Identifier: GPL-3.0
**
****************************************************************************/
import QtQuick 2.10
import QtLocation 5.9
import QtPositioning 5.14
import QtQuick.Controls 2.13
import shared.animations 1.0
import shared.Style 1.0
import shared.Sizes 1.0
import "../helpers" 1.0
Item {
id: root
property alias mapCenter: mainMap.center
property alias mapZoomLevel: mainMap.zoomLevel
property alias mapTilt: mainMap.tilt
property alias mapBearing: mainMap.bearing
property alias mapReady: mainMap.mapReady
property alias activeMapType: mainMap.activeMapType
property alias supportedMapTypes: mainMap.supportedMapTypes
property var path
property var mapPlugin
property string nextTurnDistanceMeasuredIn
property real nextTurnDistance
property string naviGuideDirection
state: "initial"
states: [
State {
// just a map w/o any additional items in it
name: "initial"
PropertyChanges {
target: posMarker
coordinate: QtPositioning.coordinate()
rotation: 0.0
visible: false
}
PropertyChanges {
target: destMarker
visible: false
coordinate: QtPositioning.coordinate()
}
PropertyChanges {
target: pathView
visible: false
path: []
}
},
State {
name: "demo_driving"
PropertyChanges {
target: posMarker
coordinate: root.mapCenter
rotation: 0.0
visible: true
}
PropertyChanges {
target: destMarker
visible: true
coordinate: root.path[root.path.length - 1]
}
PropertyChanges {
target: pathView
visible: true
path: root.path
}
PropertyChanges {
target: instructions
visible: root.naviGuideDirection !== ""
}
}
]
Map {
id: mainMap
anchors.fill: parent
enabled: false
Behavior on tilt { DefaultSmoothedAnimation {} }
zoomLevel: 10
plugin: root.mapPlugin
copyrightsVisible: false
MapPolyline {
id: pathView
line.color: Style.accentColor
line.width: Sizes.dp(8)
smooth: true
opacity: Style.opacityHigh
}
MapQuickItem {
id: destMarker
anchorPoint: Qt.point(markerImage.width * 0.5, markerImage.height * 0.8)
sourceItem: Image {
id: markerImage
source: Qt.resolvedUrl("../assets/pin-destination.png")
width: Sizes.dp(69.5) // half size of the source
height: Sizes.dp(80.5)
}
}
Item {
id: instructions
visible: false
anchors.top: posMarker.bottom
anchors.topMargin: Sizes.dp(100)
anchors.horizontalCenter: posMarker.horizontalCenter
width: Sizes.dp(660)
height: Sizes.dp(100)
Rectangle {
anchors.fill: parent
opacity: 0.5
color: Style.theme === Style.Dark ? "black" : "white"
radius: 10
}
Label {
width: Sizes.dp(400)
height: Sizes.dp(100)
anchors.verticalCenter: parent.verticalCenter
anchors.left: parent.left
anchors.leftMargin: Sizes.dp(30)
opacity: 0.9
font.pixelSize: Sizes.fontSizeXL
font.bold: true
verticalAlignment: Text.AlignVCenter
text: qsTr("Next turn: ") + root.nextTurnDistance
+ " " + root.nextTurnDistanceMeasuredIn
}
Image {
anchors.verticalCenter: parent.verticalCenter
anchors.right: parent.right
anchors.rightMargin: Sizes.dp(30)
source: root.naviGuideDirection !== ""
? Helper.localAsset(root.naviGuideDirection, Style.theme)
: ""
}
}
MapQuickItem {
id: posMarker
anchorPoint: Qt.point(posImage.width * 0.5, posImage.height * 0.5)
sourceItem: Image {
id: posImage
source: Qt.resolvedUrl("../assets/pin-your-position.png")
width: Sizes.dp(58) // half size of the source
height: Sizes.dp(67.5)
}
}
}
}
|