blob: cbbf65fe87124ed56c50be17cca5b1ec28c4c2b2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
|
/****************************************************************************
**
** Copyright (C) 2019 Luxoft Sweden AB
** Copyright (C) 2018 Pelagicore AG
** Contact: https://www.qt.io/licensing/
**
** This file is part of the Neptune 3 UI.
**
** $QT_BEGIN_LICENSE:GPL-QTAS$
** Commercial License Usage
** Licensees holding valid commercial Qt Automotive Suite licenses may use
** this file in accordance with the commercial license agreement provided
** with the Software or, alternatively, in accordance with the terms
** contained in a written agreement between you and The Qt Company. For
** licensing terms and conditions see https://www.qt.io/terms-conditions.
** For further information use the contact form at https://www.qt.io/contact-us.
**
** GNU General Public License Usage
** Alternatively, this file may be used under the terms of the GNU
** General Public License version 3 or (at your option) any later version
** approved by the KDE Free Qt Foundation. The licenses are as published by
** the Free Software Foundation and appearing in the file LICENSE.GPL3
** included in the packaging of this file. Please review the following
** information to ensure the GNU General Public License requirements will
** be met: https://www.gnu.org/licenses/gpl-3.0.html.
**
** $QT_END_LICENSE$
**
** SPDX-License-Identifier: GPL-3.0
**
****************************************************************************/
import QtQuick 2.6
import shared.utils 1.0
import shared.Sizes 1.0
/*
Displays a child item on the screen which can be dismissed by swiping it to the right.
It will them remain on the right side of the screen, with just a small part of its left
side sticking out so that it can be dragged back into full view.
Usage:
WidgetDrawer {
anchors.left: parent.left
anchors.right: parent.right
height: someHeight
SomeItem {}
}
*/
MouseArea {
id: root
drag.target: root
drag.axis: Drag.XAxis
drag.filterChildren: dragEnabled
drag.minimumX: 0
drag.maximumX: root.width - stickOutWidth
opacity: 0.5 + 0.5*(1 - (root.x - drag.minimumX)/(drag.maximumX - drag.minimumX))
// Whether the drag behavior is enabled.
property bool dragEnabled: true
// how much of it should be sticking out from the right side of the display when
// the widget drawer has been closed
readonly property real stickOutWidth: Sizes.dp(90)
// true if in full view, false if it's tucked away on the right side of the display
property bool open: true
onOpenChanged: d.applyOpenState()
Connections {
target: drag
onActiveChanged: {
if (root.drag.active) {
d.lastX = root.x;
d.direction = 0;
d.dragging = true;
} else {
d.dragging = false;
var delta = Math.abs(d.lastX - d.startX);
if (delta >= d.minimumDrag) {
if (d.direction === 1 && root.open) {
root.open = false;
} else if (d.direction === -1 && !root.open) {
root.open = true;
} else {
d.applyOpenState();
}
} else {
d.applyOpenState();
}
}
}
}
QtObject {
id: d
property real startX
property real lastX
property int direction
property bool dragging: false
readonly property real minimumDrag: Sizes.dp(90)
function applyOpenState() {
if (root.open) {
root.x = root.drag.minimumX;
} else {
root.x = root.drag.maximumX;
}
}
}
onXChanged: {
if (!d.dragging) {
return;
}
if (x > d.lastX) {
if (d.direction !== 1) {
d.direction = 1;
d.startX = x;
}
} else if (d.direction !== -1) {
d.direction = -1;
d.startX = x;
}
d.lastX = x;
}
Behavior on x {
SmoothedAnimation {
easing.type: Easing.InOutQuad
velocity: Sizes.dp(1800)
}
enabled: !d.dragging
}
}
|
