blob: a9c8d3f1e524c179ff87558be615b666061a9a18 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
|
requires(linux:!android|win32-msvc2013:!winrt|win32-msvc2015:!winrt|macos|win32-g++*)
TEMPLATE = subdirs
include(config.pri)
SUBDIRS += plugins
copydata.file = copydata.pro
copydata.depends = plugins
# HACK: CI does not have appman in dependency list, which is why
# we are not building the executable to avoid failing integration tests.
qtHaveModule(appman_main-private) {
message("Module appman_main-private found.")
SUBDIRS += src
copydata.depends += src
} else {
message("Module appman_main-private not found. Custom executable won't be build.")
}
SUBDIRS += copydata
# Install all required files
qml.files = apps imports sysui styles am-config.yaml Main.qml
qml.path = $$INSTALL_PREFIX/triton
INSTALLS += qml
OTHER_FILES += $$files($$PWD/*.qml, true)
OTHER_FILES += $$PWD/plugins.yaml.in
OTHER_FILES += .qmake.conf
PLUGINS_DIR = $$OUT_PWD/qml
QMAKE_SUBSTITUTES += $$PWD/plugins.yaml.in
|
