blob: 2f4c47d84fe3dfddd6d0bd327683ea0d586e9d8a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
TEMPLATE = app
TARGET = snowshoe
QT += declarative
SOURCES += \
main.cpp \
BrowserObject.cpp \
BrowserWindow.cpp \
MainView.cpp \
DeclarativeDesktopWebView.cpp \
TripleClickMonitor.cpp
HEADERS += \
BrowserObject.h \
BrowserWindow.h \
MainView.h \
DeclarativeDesktopWebView.h \
TripleClickMonitor.h
RESOURCES += \
snowshoe.qrc
MOC_DIR = .moc/
RCC_DIR = .rcc/
OBJECTS_DIR = .obj/
WEBKIT_SOURCE_DIR = $$(WEBKIT_SOURCE_DIR)
isEmpty(WEBKIT_SOURCE_DIR) {
error(Please set WEBKIT_SOURCE_DIR environment variable)
} else {
message(Using WebKit source from $$WEBKIT_SOURCE_DIR)
}
WEBKIT_BUILD_DIR = $$(WEBKIT_BUILD_DIR)
isEmpty(WEBKIT_BUILD_DIR) {
WEBKIT_BUILD_DIR = $$WEBKIT_SOURCE_DIR/WebKitBuild/Release
}
message(Using WebKit build from $$WEBKIT_BUILD_DIR)
INCLUDEPATH += $$WEBKIT_SOURCE_DIR/Source/
INCLUDEPATH += $$WEBKIT_SOURCE_DIR/Source/WebKit2/UIProcess/API/qt
INCLUDEPATH += $$WEBKIT_SOURCE_DIR/Source/WebKit2/UIProcess/API/C
INCLUDEPATH += $$WEBKIT_SOURCE_DIR/Source/WebKit2/UIProcess/API/cpp
INCLUDEPATH += $$WEBKIT_SOURCE_DIR/Source/WebKit/qt/Api
INCLUDEPATH += $$WEBKIT_BUILD_DIR/include/
INCLUDEPATH += $$WEBKIT_BUILD_DIR/include/WebKit2
# WebKit needs to be the first, just in case the Qt build contains already a QtWebKit.
QMAKE_LFLAGS = -L$$WEBKIT_BUILD_DIR/lib $$QMAKE_LFLAGS
macx {
LIBS += -framework QtWebKit
} else {
# Make sure that again the custom WebKit is the first in the rpath otherwise it will not pick the right one.
unix : QMAKE_RPATHDIR = $$WEBKIT_BUILD_DIR/lib $$QMAKE_RPATHDIR
LIBS += -lQtWebKit
}
OTHER_FILES += \
qml/main.qml \
qml/Tab.qml \
qml/TabWidget.qml \
qml/TabWidget.js \
qml/UrlEdit.qml \
qml/UrlBar.qml \
qml/PageWidget.qml
|