blob: 0e729cf4be59f31b77d70f0a5a7b61959ba73481 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
|
/****************************************************************************
* Copyright (C) 2012 Instituto Nokia de Tecnologia (INdT) *
* *
* This file may be used under the terms of the GNU Lesser *
* General Public License version 2.1 as published by the Free Software *
* Foundation and appearing in the file LICENSE.LGPL included in the *
* packaging of this file. Please review the following information to *
* ensure the GNU Lesser General Public License version 2.1 requirements *
* will be met: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html. *
* *
* This program is distributed in the hope that it will be useful, *
* but WITHOUT ANY WARRANTY; without even the implied warranty of *
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the *
* GNU Lesser General Public License for more details. *
****************************************************************************/
import QtQuick 2.0
import "UiConstants.js" as UiConstants
Rectangle {
id: rootPage
width: UiConstants.PortraitWidth
height: UiConstants.PortraitHeight
color: "#aaa"
clip: true
Image {
anchors.fill: parent
source: "qrc:///mobile/app/bg_image"
}
PanelToggle {
id: panelToggle
anchors {
top: parent.top
topMargin: 32
horizontalCenter: parent.horizontalCenter
}
navigationEnabled: navigationPanel.hasOpennedTabs
onTopSitesSelected: {
rootPage.state = "favorites";
}
onTabsSelected: {
rootPage.state = "navigation";
}
}
TopSitesPanel {
id: topSitesPanel
opacity: 0
anchors {
top: panelToggle.bottom
left: parent.left
right: parent.right
topMargin: 32
}
onUrlSelected: navigationPanel.openUrlInNewTab(UrlTools.fromUserInput(url))
}
TabsPanel {
id: tabsPanel
opacity: 0
anchors {
top: panelToggle.bottom
left: parent.left
right: parent.right
topMargin: 32
}
}
NavigationPanel {
id: navigationPanel
opacity: 0
anchors.fill: parent
onNewTabRequested: urlInputPanel.showForNewTab()
onUrlInputRequested: urlInputPanel.showForCurrentTab()
onWebViewMaximized: {
rootPage.state = "navigationFullScreen";
}
onWebViewMinimized: {
rootPage.state = "navigation";
}
}
Image {
source: "qrc:///mobile/app/side_shadow"
z: 99
anchors {
left: parent.left
verticalCenter: parent.verticalCenter
}
}
Image {
source: "qrc:///mobile/app/side_shadow"
z: 99
mirror: true
anchors {
right: parent.right
verticalCenter: parent.verticalCenter
}
}
Image {
id: plusButton
opacity: 0
source: plusButtonMouseArea.pressed ? "qrc:///mobile/nav/btn_plus_pressed" : "qrc:///mobile/nav/btn_plus_unpressed"
anchors.top: topSitesPanel.bottom
anchors.topMargin: 27
anchors.horizontalCenter: rootPage.horizontalCenter
MouseArea {
id: plusButtonMouseArea
anchors.fill: parent
onClicked: urlInputPanel.showForNewTab()
}
}
UrlInputPanel {
id: urlInputPanel
property bool shouldOpenNewTab: false
function showForNewTab() {
shouldOpenNewTab = true;
_show();
}
function showForCurrentTab() {
shouldOpenNewTab = false;
_show();
}
function _show() {
text = shouldOpenNewTab ? "" : navigationPanel.url;
if (rootPage.state !== "typeNewUrl")
rootPage.previousState = rootPage.state;
rootPage.state = "typeNewUrl";
}
anchors.fill: parent
opacity: 0
onUrlRequested: {
urlInputPanel.unfocusUrlBar();
navigationPanel.state = "";
if (shouldOpenNewTab)
navigationPanel.openUrlInNewTab(url);
else
navigationPanel.openUrl(url);
}
onCancelRequested: {
urlInputPanel.unfocusUrlBar();
rootPage.state = rootPage.previousState;
}
}
property string previousState: ""
// BUG: Qml behaves wrong on n9,it sets panelToggle.topsites.visible to false
// then to true on start up causing a cascade misbehaviour, the workaround
// is to set the state of the root element on Component.onCompleted.
// state: "favorites"
Component.onCompleted: state = "favorites"
states: [
State {
name: "favorites"
PropertyChanges { target: panelToggle; topSitesButtonSelected: true }
PropertyChanges { target: plusButton; opacity: 1 }
PropertyChanges { target: panelToggle; opacity: 1 }
PropertyChanges { target: topSitesPanel; opacity: 1 }
PropertyChanges { target: tabsPanel; opacity: 0 }
PropertyChanges { target: navigationPanel; opacity: 0 }
},
State {
name: "navigation"
PropertyChanges { target: panelToggle; topSitesButtonSelected: false }
PropertyChanges { target: plusButton; opacity: 1 }
PropertyChanges { target: panelToggle; opacity: 1 }
PropertyChanges { target: topSitesPanel; opacity: 0 }
PropertyChanges { target: tabsPanel; opacity: 1 }
PropertyChanges { target: navigationPanel; opacity: 0 }
},
State {
name: "navigationFullScreen"
PropertyChanges { target: panelToggle; topSitesButtonSelected: false }
PropertyChanges { target: plusButton; opacity: 0 }
PropertyChanges { target: panelToggle; opacity: 0 }
PropertyChanges { target: topSitesPanel; opacity: 0 }
PropertyChanges { target: tabsPanel; opacity: 0 }
PropertyChanges { target: navigationPanel; opacity: 1 }
},
State {
name: "typeNewUrl"
PropertyChanges { target: urlInputPanel; opacity: 1 }
PropertyChanges { target: plusButton; opacity: 0 }
PropertyChanges { target: panelToggle; opacity: 0 }
PropertyChanges { target: topSitesPanel; opacity: 0 }
PropertyChanges { target: tabsPanel; opacity: 0 }
PropertyChanges { target: navigationPanel; opacity: 0 }
}
]
transitions: [
Transition {
from: "splash"
AnchorAnimation { duration: 200; easing.type: Easing.InOutQuad }
},
Transition {
to: "typeNewUrl"
PropertyAnimation { property: "opacity"; duration: 200; easing.type: Easing.InCubic }
SequentialAnimation {
PauseAnimation { duration: 300 }
ScriptAction { script: urlInputPanel.focusUrlBar() }
}
},
Transition {
from: "typeNewUrl"
SequentialAnimation {
PauseAnimation { duration: 300 }
PropertyAnimation { property: "opacity"; duration: 200; easing.type: Easing.InCubic }
}
},
Transition {
from: "navigation"
to: "navigationFullScreen"
reversible: true
NumberAnimation { targets: [navigationPanel, panelToggle, plusButton]; property: "opacity"; duration: 200 }
}
]
}
|