blob: 768b5e6d16810a254ccb35dd4421623f1e9bdcf9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
TEMPLATE = lib
CONFIG += warn_on
CONFIG += qmfclient
equals(QT_MAJOR_VERSION, 4){
TARGET = qmfmessageserver
LIBS += -lqmfclient
}
equals(QT_MAJOR_VERSION, 5){
TARGET = qmfmessageserver5
LIBS += -lqmfclient5
}
target.path += $$QMF_INSTALL_ROOT/lib
QT = core network
!contains(DEFINES,QMF_NO_MESSAGE_SERVICE_EDITOR) {
QT += gui
equals(QT_MAJOR_VERSION, 5): QT += widgets
}
DEFINES += MESSAGESERVER_INTERNAL
DEPENDPATH += .
INCLUDEPATH += . ../qmfclient ../qmfclient/support
LIBS += -L../qmfclient/build
macx:LIBS += -F../qmfclient/build
PUBLIC_HEADERS += qmailauthenticator.h \
qmailmessagebuffer.h \
qmailmessageclassifier.h \
qmailmessageservice.h \
qmailserviceconfiguration.h \
qmailstoreaccountfilter.h \
qmailtransport.h \
qmailheartbeattimer.h
SOURCES += qmailauthenticator.cpp \
qmailmessagebuffer.cpp \
qmailmessageclassifier.cpp \
qmailmessageservice.cpp \
qmailserviceconfiguration.cpp \
qmailstoreaccountfilter.cpp \
qmailtransport.cpp \
qmailheartbeattimer_qtimer.cpp # NB: There are multiple implementations
contains(DEFINES,MESSAGESERVER_PLUGINS) {
PUBLIC_HEADERS += qmailmessageserverplugin.h
SOURCES += qmailmessageserverplugin.cpp
}
HEADERS += $$PUBLIC_HEADERS $$PRIVATE_HEADERS
equals(QT_MAJOR_VERSION, 4): header_files.path=$$QMF_INSTALL_ROOT/include/qmfmessageserver
equals(QT_MAJOR_VERSION, 5): header_files.path=$$QMF_INSTALL_ROOT/include/qmfmessageserver5
header_files.files=$$PUBLIC_HEADERS
INSTALLS += header_files
unix: {
CONFIG += create_pc create_prl
QMAKE_PKGCONFIG_LIBDIR = $$target.path
QMAKE_PKGCONFIG_INCDIR = $$header_files.path
QMAKE_PKGCONFIG_DESTDIR = pkgconfig
}
include(../../../common.pri)
|