Fixed INCLUDEPATH problems for Mobility examples.

While building Mobility examples, we were adding the Mobility
headers install path to INCLUDEPATH.  That's wrong, since we haven't
installed Mobility yet.

On most platforms, this has not caused problems.
On Harmattan, it is quite likely that there are already some Mobility
headers installed, which means that we would incorrectly use those
instead of the ones from the Mobility we're building.

This is similar to the problems fixed by
e81921f362f76c83b4107ec429f5d4ad9e38ed7d and
31e1e2eaf6194c99b5a7a00691798907a89dd750.

Reviewed-by: Alex

1 files changed, 44 insertions, 35 deletions

diff --git a/features/mobility.prf.template b/features/mobility.prf.template
index 136a7340b5..7fbb5657e9 100644
--- a/features/mobility.prf.template
+++ b/features/mobility.prf.template
@@ -1,6 +1,26 @@
+!isEmpty(QT_MOBILITY_BUILD_TREE):CONFIG+=mobility_build
+
+defineTest(qtMobilityAddLibrary) {
+    # If we are currently building Mobility itself, do not add the install
+    # include paths. It can't help since we haven't installed our headers yet,
+    # and it may hurt since incompatible headers may be present from an
+    # earlier build.
+    !mobility_build {
+        INCLUDEPATH -= $${MOBILITY_INCLUDE}/$$1
+        INCLUDEPATH = $${MOBILITY_INCLUDE}/$$1 $$INCLUDEPATH
+    }
+
+    # qtAddLibrary will add $$QMAKE_INCDIR_QT/$$1 to the INCLUDEPATH, which we
+    # don't want, but we want everything else it does.
+    OLD_INCLUDEPATH = $$INCLUDEPATH
+    qtAddLibrary($$1)
+    INCLUDEPATH = $$OLD_INCLUDEPATH
+
+    export(INCLUDEPATH)
+}
 
 !symbian {
-    INCLUDEPATH += $${MOBILITY_INCLUDE}
+    !mobility_build:INCLUDEPATH += $${MOBILITY_INCLUDE}
 } else {
     load(data_caging_paths)
     contains(MOBILITY, contacts|versit|organizer) {
@@ -9,9 +29,13 @@
 
     INCLUDEPATH+=$$MW_LAYER_SYSTEMINCLUDE
 }
-mac: LIBS += -F$${MOBILITY_LIB}
 
-LIBS+= -L$${MOBILITY_LIB}
+!mobility_build {
+    mac: LIBS += -F$${MOBILITY_LIB}
+
+    LIBS+= -L$${MOBILITY_LIB}
+}
+
 QMAKE_RPATHDIR+=$${MOBILITY_LIB}
 
 # versit depends on contacts
@@ -19,12 +43,11 @@ contains(MOBILITY, versit) {
     MOBILITY += contacts
 }
 
-simulator: qtAddLibrary(QtMobilitySimulator)
+simulator: qtMobilityAddLibrary(QtMobilitySimulator)
 
 contains(MOBILITY, bearer) {
     DEFINES += QT_MOBILITY_BEARER
-    INCLUDEPATH += $${MOBILITY_INCLUDE}/QtBearer
-    qtAddLibrary(QtBearer)
+    qtMobilityAddLibrary(QtBearer)
     !equals(QT_MAJOR_VERSION,4)|!equals(QT_MINOR_VERSION, 6) {
         message(Qt Mobility Bearer API is deprecated when using Qt 4.7 or higher.)
         message(Please use source compatible replacement Bearer API in QtNetwork.)
@@ -32,80 +55,66 @@ contains(MOBILITY, bearer) {
 }
 
 #for includes from src/global
-INCLUDEPATH += $${MOBILITY_INCLUDE}/QtMobility
+!mobility_build:INCLUDEPATH += $${MOBILITY_INCLUDE}/QtMobility
 
 contains(MOBILITY, publishsubscribe) {
-    INCLUDEPATH += $${MOBILITY_INCLUDE}/QtPublishSubscribe
-    qtAddLibrary(QtPublishSubscribe)
+    qtMobilityAddLibrary(QtPublishSubscribe)
 }
 
 contains(MOBILITY, location) {
-    INCLUDEPATH += $${MOBILITY_INCLUDE}/QtLocation
-    qtAddLibrary(QtLocation)
+    qtMobilityAddLibrary(QtLocation)
 }
 
 contains(MOBILITY, serviceframework) {
-    INCLUDEPATH += $${MOBILITY_INCLUDE}/QtServiceFramework
-    qtAddLibrary(QtServiceFramework)
+    qtMobilityAddLibrary(QtServiceFramework)
 }
 
 contains(MOBILITY, systeminfo) {
     #QSystemInfo header requires QNetworkInterface
     QT += network
-    INCLUDEPATH += $${MOBILITY_INCLUDE}/QtSystemInfo
-    qtAddLibrary(QtSystemInfo)
+    qtMobilityAddLibrary(QtSystemInfo)
 }
 
 contains(MOBILITY, multimedia) {
     QT += network
     contains(QT_CONFIG, opengl): QT += opengl
-    INCLUDEPATH += $${MOBILITY_INCLUDE}/QtMultimediaKit
-    qtAddLibrary(QtMultimediaKit)
+    qtMobilityAddLibrary(QtMultimediaKit)
 }
 
 contains(MOBILITY, contacts) {
-    INCLUDEPATH += $${MOBILITY_INCLUDE}/QtContacts
-    qtAddLibrary(QtContacts)
+    qtMobilityAddLibrary(QtContacts)
 }
 
 contains(MOBILITY, messaging) {
-    INCLUDEPATH += $${MOBILITY_INCLUDE}/QtMessaging
-    qtAddLibrary(QtMessaging)
+    qtMobilityAddLibrary(QtMessaging)
 }
 
 contains(MOBILITY, versit) {
-    INCLUDEPATH += $${MOBILITY_INCLUDE}/QtVersit
-    qtAddLibrary(QtVersit)
+    qtMobilityAddLibrary(QtVersit)
     contains(MOBILITY, organizer) {
-        INCLUDEPATH += $${MOBILITY_INCLUDE}/QtVersitOrganizer
-        qtAddLibrary(QtVersitOrganizer)
+        qtMobilityAddLibrary(QtVersitOrganizer)
     }
 }
 
 contains(MOBILITY, sensors) {
-    INCLUDEPATH += $${MOBILITY_INCLUDE}/QtSensors
-    qtAddLibrary(QtSensors)
+    qtMobilityAddLibrary(QtSensors)
 }
 
 contains(MOBILITY, feedback) {
-    INCLUDEPATH += $${MOBILITY_INCLUDE}/QtFeedback
-    qtAddLibrary(QtFeedback)
+    qtMobilityAddLibrary(QtFeedback)
 }
 
 contains(MOBILITY, gallery) {
-    INCLUDEPATH += $${MOBILITY_INCLUDE}/QtGallery
-    qtAddLibrary(QtGallery)
+    qtMobilityAddLibrary(QtGallery)
 }
 
 contains(MOBILITY, organizer) {
-    INCLUDEPATH += $${MOBILITY_INCLUDE}/QtOrganizer
-    qtAddLibrary(QtOrganizer)
+    qtMobilityAddLibrary(QtOrganizer)
 }
 
 contains(MOBILITY, connectivity) {
-    INCLUDEPATH += $${MOBILITY_INCLUDE}/QtConnectivity
     INCLUDEPATH += $${QMAKE_INCDIR_QT}/QtNetwork
-    qtAddLibrary(QtConnectivity)
+    qtMobilityAddLibrary(QtConnectivity)
 }
 
 # Add dependency to QtMobility package to all projects besides QtMobility package itself.