1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
|
include(../staticconfig.pri)
TEMPLATE = subdirs
#ServiceFramework examples
contains(mobility_modules,serviceframework) {
SUBDIRS += filemanagerplugin \
bluetoothtransferplugin \
notesmanagerplugin \
servicebrowser \
sfwecho
#These examples do not work on Symbian yet
!symbian:SUBDIRS+= sfw-notes
contains(QT_CONFIG, declarative) {
SUBDIRS += declarative-sfw-dialer declarative-sfw-notes
}
}
#BearerManagement examples
contains(mobility_modules,bearer) {
SUBDIRS += bearermonitor bearercloud
}
#Location examples
contains(mobility_modules,location) {
SUBDIRS += logfilepositionsource
!wince* {
SUBDIRS += landmarkbrowser
}
equals(QT_MAJOR_VERSION, 4):lessThan(QT_MINOR_VERSION, 7) {
contains(mobility_modules,bearer) {
SUBDIRS += flickrdemo \
mapsdemo
}
} else {
SUBDIRS += flickrdemo \
mapsdemo
}
contains(QT_CONFIG, declarative) {
SUBDIRS += declarative-location
}
}
#Contacts examples
contains(mobility_modules,contacts) {
SUBDIRS += samplephonebook
}
#Publish and Subscribe examples
contains(mobility_modules,publishsubscribe) {
!wince*{
SUBDIRS += publish-subscribe
contains(QT_CONFIG, declarative) {
SUBDIRS += battery-charge
sources.files += battery-charge/battery-subscriber
}
}
}
#System Information
contains(mobility_modules,systeminfo) {
SUBDIRS += sysinfo \
qsystemalignedtimer
contains(QT_CONFIG, declarative) {
SUBDIRS += declarative-systeminfo
}
}
#Multimedia
contains(mobility_modules,multimedia) {
SUBDIRS += \
radio \
camera \
slideshow \
audiorecorder \
audiodevices \
audioinput \
audiooutput \
videographicsitem \
videowidget
contains(QT_CONFIG, declarative) {
SUBDIRS += declarative-camera
}
}
#Messaging examples
contains(qmf_enabled,yes)|wince*|win32|symbian|maemo5|maemo6 {
contains(mobility_modules,messaging) {
!win32-g++ {
SUBDIRS += writemessage
!symbian:SUBDIRS += querymessages
contains(mobility_modules,contacts) {
SUBDIRS += keepintouch
}
# MessagingEx lives in tests for some reason
maemo5|maemo6:SUBDIRS += ../tests/manual/messagingex
contains(QT_CONFIG, declarative) {
SUBDIRS += \
declarative-messages
}
}
}
}
# Sensors API examples
contains(mobility_modules,sensors) {
SUBDIRS += sensors
}
contains(mobility_modules,gallery) {
SUBDIRS += \
documentproperties \
mediabrowser
contains(QT_CONFIG, declarative) {
SUBDIRS += \
declarative-music-browser
}
}
# Organizer API examples
contains(mobility_modules, organizer) {
SUBDIRS += calendardemo \
todo
contains(mobility_modules,versit):contains(QT_CONFIG, declarative) {
SUBDIRS += \
qmlorganizer
}
}
# Feedback API examples
contains(mobility_modules, feedback) {
SUBDIRS += hapticsplayer hapticsquare # this not a good UI for mobile screens at the moment
}
# Connectivity
contains(mobility_modules,connectivity):!win32 {
SUBDIRS += \
annotatedurl \
btchat \
btfiletransfer \
btscanner \
ndefeditor
contains(QT_CONFIG, declarative):SUBDIRS += declarative-connectivity
}
sources.path = $$QT_MOBILITY_EXAMPLES
INSTALLS += sources
|