blob: faac908357673542922583121802720fe4349f5f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
include(../../../features/utils.pri)
INCLUDEPATH += ../../../src/messaging
INCLUDEPATH += ../../../src/global
TEMPLATE = lib
CONFIG += plugin
TARGET = $$mobilityPluginTarget(declarative_messaging)
TARGETPATH = QtMobility/messaging
PLUGIN_TYPE = declarative
include(../../../common.pri)
QT += declarative
SOURCES += \
qdeclarativemessagefilter.cpp \
qdeclarativemessagemodel.cpp \
plugin.cpp
HEADERS += \
qdeclarativemessagefilter.h \
qdeclarativemessagemodel.h
CONFIG += mobility
MOBILITY += messaging
target.path = $$[QT_INSTALL_IMPORTS]/$$TARGETPATH
qmldir.files += $$PWD/qmldir
qmldir.path += $$[QT_INSTALL_IMPORTS]/$$TARGETPATH
INSTALLS += qmldir
# QMF libraries must be located at $QMF_LIBDIR
simulator|contains(qmf_enabled, yes) {
mac {
QMAKE_LFLAGS += -F$$(QMF_LIBDIR)
LIBS += -framework qmfclient
} else {
maemo6:meego {
CONFIG += link_pkgconfig
PKGCONFIG += qmfclient
} else {
LIBS += -L$$(QMF_LIBDIR) -l$$mobilityPluginTarget(qmfclient)
}
}
}
symbian {
# In Symbian, a library should enjoy _largest_ possible capability set.
TARGET.CAPABILITY = ALL -TCB
# Allow writable DLL data
TARGET.EPOCALLOWDLLDATA = 1
# Target UID, makes every Symbian app unique
TARGET.UID3 = $$mobilityUID(0x20031601)
# Specifies what files shall be deployed: the plugin itself and the qmldir file.
importFiles.sources = $$DESTDIR/declarative_messaging$${QT_LIBINFIX}.dll qmldir
importFiles.path = $$QT_IMPORTS_BASE_DIR/$$TARGETPATH
DEPLOYMENT = importFiles
}
|
