blob: 63a8d88d6eaf44ff26dc80474de2a9b2b484d27c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
include(../../../features/utils.pri)
INCLUDEPATH += ../../../src/publishsubscribe
DEPENDPATH += ../../../src/publishsubscribe
INCLUDEPATH += ../../../src/global
TEMPLATE = lib
CONFIG += plugin
TARGET = $$mobilityPluginTarget(declarative_publishsubscribe)
TARGETPATH = QtMobility/publishsubscribe
PLUGIN_TYPE = declarative
DEFINES += QT_MAKEDLL
include(../../../common.pri)
# support headers/sources for dynamic properties
include(../common/dynamicproperties.pri)
QT += declarative
SOURCES += publishsubscribe.cpp \
qdeclarativevaluespacepublisher.cpp \
qdeclarativevaluespacepublishermetaobject.cpp \
qdeclarativevaluespacesubscriber.cpp
HEADERS += \
qdeclarativevaluespacepublisher_p.h \
qdeclarativevaluespacepublishermetaobject_p.h \
qdeclarativevaluespacesubscriber_p.h
CONFIG += mobility
MOBILITY += publishsubscribe
target.path = $$[QT_INSTALL_IMPORTS]/$$TARGETPATH
qmldir.files += $$PWD/qmldir
qmldir.path += $$[QT_INSTALL_IMPORTS]/$$TARGETPATH
INSTALLS += qmldir
symbian {
# In Symbian, a library should enjoy _largest_ possible capability set.
TARGET.CAPABILITY = ALL -TCB
# Allow writable DLL data
TARGET.EPOCALLOWDLLDATA = 1
# Target UID, makes every Symbian app unique
TARGET.UID3 = $$mobilityUID(0x20021322)
# Specifies what files shall be deployed: the plugin itself and the qmldir file.
importFiles.sources = $$DESTDIR/declarative_publishsubscribe$${QT_LIBINFIX}.dll qmldir
importFiles.path = $$QT_IMPORTS_BASE_DIR/$$TARGETPATH
DEPLOYMENT = importFiles
}
|
