blob: 996b90c8469347c213da2564ae3ce403e552396a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
INCLUDEPATH += ../../../src/sensors
INCLUDEPATH += ../../../src/global
TEMPLATE = lib
CONFIG += plugin
TARGET = $$qtLibraryTarget(declarative_sensors)
TARGETPATH = QtMobility/sensors
PLUGIN_TYPE = declarative
include(../../../common.pri)
QT += declarative
SOURCES += sensors.cpp
CONFIG += mobility
MOBILITY += sensors
target.path = $$[QT_INSTALL_IMPORTS]/$$TARGETPATH
qmldir.files += $$PWD/qmldir
qmldir.path += $$[QT_INSTALL_IMPORTS]/$$TARGETPATH
INSTALLS += qmldir
symbian {
# In Symbian, a library should enjoy _largest_ possible capability set.
TARGET.CAPABILITY = ALL -TCB
# Allow writable DLL data
TARGET.EPOCALLOWDLLDATA = 1
# Target UID, makes every Symbian app unique
TARGET.UID3 = 0x20021324
# Specifies what files shall be deployed: the plugin itself and the qmldir file.
importFiles.sources = $$DESTDIR/declarative_sensors$${QT_LIBINFIX}.dll qmldir
importFiles.path = $$QT_IMPORTS_BASE_DIR/$$TARGETPATH
DEPLOYMENT = importFiles
}
|