blob: 72bee8e5cb23794d9197d479e85eb6a6bfe22f5d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
|
# #####################################################################
# Contacts Mobility API
# #####################################################################
TEMPLATE = lib
# Target gets fixed up in common.pri
TARGET = QtContacts
DEFINES += QT_BUILD_CONTACTS_LIB QT_MAKEDLL\
QT_ASCII_CAST_WARNINGS
include(../../common.pri)
include(details/details.pri)
include(engines/engines.pri)
include(filters/filters.pri)
include(requests/requests.pri)
# Input
PUBLIC_HEADERS += \
qcontact.h \
qcontactabstractrequest.h \
qcontactaction.h \
qcontactactiondescriptor.h \
qcontactactionfactory.h \
qcontactactiontarget.h \
qcontactchangeset.h \
qcontactdetail.h \
qcontactdetaildefinition.h \
qcontactdetailfielddefinition.h \
qcontactfetchhint.h \
qcontactfilter.h \
qcontactid.h \
qcontactmanager.h \
qcontactmanagerengine.h \
qcontactmanagerenginefactory.h \
qcontactobserver.h \
qcontactrelationship.h \
qcontactsortorder.h \
qtcontactsglobal.h \
qtcontacts.h
# Private Headers
PRIVATE_HEADERS += \
qcontact_p.h \
qcontactabstractrequest_p.h \
qcontactactiondescriptor_p.h \
qcontactactionmanager_p.h \
qcontactactiontarget_p.h \
qcontactchangeset_p.h \
qcontactdetail_p.h \
qcontactdetaildefinition_p.h \
qcontactdetailfielddefinition_p.h \
qcontactfetchhint_p.h \
qcontactfilter_p.h \
qcontactid_p.h \
qcontactmanager_p.h \
qcontactmanagerenginev2wrapper_p.h \
qcontactrelationship_p.h \
qcontactsortorder_p.h
SOURCES += \
qcontact.cpp \
qcontactabstractrequest.cpp \
qcontactaction.cpp \
qcontactactiondescriptor.cpp \
qcontactactionfactory.cpp \
qcontactactionmanager_p.cpp \
qcontactactiontarget.cpp \
qcontactchangeset.cpp \
qcontactdetail.cpp \
qcontactdetaildefinition.cpp \
qcontactdetailfielddefinition.cpp \
qcontactfetchhint.cpp \
qcontactfilter.cpp \
qcontactid.cpp \
qcontactmanager_p.cpp \
qcontactmanager.cpp \
qcontactmanagerengine.cpp \
qcontactmanagerenginefactory.cpp \
qcontactmanagerenginev2wrapper_p.cpp \
qcontactobserver.cpp \
qcontactrelationship.cpp \
qcontactsortorder.cpp
HEADERS += \
$$PUBLIC_HEADERS \
$$PRIVATE_HEADERS
maemo5 {
isEmpty(CONTACTS_DEFAULT_ENGINE): CONTACTS_DEFAULT_ENGINE=maemo5
}
maemo6|meego {
isEmpty(CONTACTS_DEFAULT_ENGINE): CONTACTS_DEFAULT_ENGINE=tracker
}
wince* {
isEmpty(CONTACTS_DEFAULT_ENGINE): CONTACTS_DEFAULT_ENGINE=wince
}
symbian {
isEmpty(CONTACTS_DEFAULT_ENGINE): CONTACTS_DEFAULT_ENGINE=symbian
TARGET.EPOCALLOWDLLDATA = 1
TARGET.CAPABILITY = ALL -TCB
TARGET.UID3 = 0x2002AC7A
LIBS += -lefsrv
### Contacts
# Main library
CONTACTS_DEPLOYMENT.sources = QtContacts.dll
CONTACTS_DEPLOYMENT.path = /sys/bin
DEPLOYMENT += CONTACTS_DEPLOYMENT
}
simulator {
isEmpty(CONTACTS_DEFAULT_ENGINE): CONTACTS_DEFAULT_ENGINE=simulator
SOURCES += contactconnection_simulator.cpp engines/qcontactmemorybackenddata_simulator.cpp
HEADERS += contactconnection_simulator_p.h engines/qcontactmemorybackenddata_simulator_p.h
INCLUDEPATH += ../mobilitysimulator
qtAddLibrary(QtMobilitySimulator)
}
!isEmpty(CONTACTS_DEFAULT_ENGINE): DEFINES += Q_CONTACTS_DEFAULT_ENGINE=$$CONTACTS_DEFAULT_ENGINE
CONFIG += middleware
include(../../features/deploy.pri)
|
