blob: ec4b1e237e41b51a6f2f6b6215e97e35c8b4486f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
|
# #####################################################################
# Versit-Organizer Import/Export
# #####################################################################
TEMPLATE = lib
TARGET = QtVersitOrganizer
include(../../common.pri)
DEFINES += QT_BUILD_VERSIT_ORGANIZER_LIB QT_MAKEDLL QT_ASCII_CAST_WARNINGS
qtAddLibrary(QtVersit)
qtAddLibrary(QtOrganizer)
# Note, these need to go at the front of INCLUDEPATH, in case there
# are QtVersit/QtOrganizer headers already installed on the system
INCLUDEPATH = . \
../versit \
../organizer \
../organizer/requests \
../organizer/filters \
../organizer/details \
../organizer/items \
$$INCLUDEPATH
# Input
PUBLIC_HEADERS += \
qversitorganizerhandler.h \
qversitorganizerexporter.h \
qversitorganizerimporter.h \
qversittimezonehandler.h
# Private Headers
PRIVATE_HEADERS += \
qversitorganizerexporter_p.h \
qversitorganizerimporter_p.h \
qversitorganizerdefs_p.h \
qversitorganizerpluginloader_p.h \
timezones_p.h
# Implementation
SOURCES += \
qversitorganizerexporter.cpp \
qversitorganizerexporter_p.cpp \
qversitorganizerimporter.cpp \
qversitorganizerimporter_p.cpp \
qversitorganizerhandler.cpp \
qversitorganizerpluginloader_p.cpp \
timezones_p.cpp
HEADERS += \
$$PUBLIC_HEADERS \
$$PRIVATE_HEADERS
symbian {
TARGET.UID3 = 0x200315FB
TARGET.EPOCALLOWDLLDATA = 1
TARGET.CAPABILITY = ALL -TCB
LIBS += -lefsrv
VERSIT_ORGANIZER_DEPLOYMENT.sources = QtVersitOrganizer.dll
VERSIT_ORGANIZER_DEPLOYMENT.path = /sys/bin
DEPLOYMENT += VERSIT_ORGANIZER_DEPLOYMENT
}
maemo5|maemo6 {
CONFIG += create_pc create_prl
QMAKE_PKGCONFIG_DESCRIPTION = Qt Mobility - Versit API for Organizer
pkgconfig.path = $$QT_MOBILITY_LIB/pkgconfig
pkgconfig.files = QtVersitOrganizer.pc
INSTALLS += pkgconfig
}
CONFIG += middleware
include(../../features/deploy.pri)
|