Add a simple unlit textured material

This is useful for backgrounds or other simple texturing use cases
where lighting is not desired.

Also includes a texture coordinate offset property so the texture
coordinates can easily be animated.

C++ version to follow later.

Change-Id: I8f6eba1ce28402bf59a18989884640018f473320
Reviewed-by: Paul Lemire <paul.lemire@kdab.com>

8 files changed, 179 insertions, 1 deletions

diff --git a/src/quick3d/imports/render/defaults/defaults.pri b/src/quick3d/imports/render/defaults/defaults.pri
index 8bfe8f126..cd658cf2a 100644
--- a/src/quick3d/imports/render/defaults/defaults.pri
+++ b/src/quick3d/imports/render/defaults/defaults.pri
@@ -15,4 +15,5 @@ QML_FILES = \
     $$PWD/qml/PerVertexColorMaterial.qml \
     $$PWD/qml/SkyboxEntity.qml \
     $$PWD/qml/GoochMaterial.qml \
-    $$PWD/qml/PhongAlphaMaterial.qml
+    $$PWD/qml/PhongAlphaMaterial.qml \
+    $$PWD/qml/TextureMaterial.qml
diff --git a/src/quick3d/imports/render/defaults/qml/TextureMaterial.qml b/src/quick3d/imports/render/defaults/qml/TextureMaterial.qml
new file mode 100644
index 000000000..fbe9afb29
--- /dev/null
+++ b/src/quick3d/imports/render/defaults/qml/TextureMaterial.qml
@@ -0,0 +1,112 @@
+/****************************************************************************
+**
+** Copyright (C) 2015 Klaralvdalens Datakonsult AB (KDAB).
+** Contact: http://www.qt-project.org/legal
+**
+** This file is part of the Qt3D module of the Qt Toolkit.
+**
+** $QT_BEGIN_LICENSE:LGPL3$
+** Commercial License Usage
+** Licensees holding valid commercial Qt licenses may use this file in
+** accordance with the commercial license agreement provided with the
+** Software or, alternatively, in accordance with the terms contained in
+** a written agreement between you and The Qt Company. For licensing terms
+** and conditions see http://www.qt.io/terms-conditions. For further
+** information use the contact form at http://www.qt.io/contact-us.
+**
+** GNU Lesser General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU Lesser
+** General Public License version 3 as published by the Free Software
+** Foundation and appearing in the file LICENSE.LGPLv3 included in the
+** packaging of this file. Please review the following information to
+** ensure the GNU Lesser General Public License version 3 requirements
+** will be met: https://www.gnu.org/licenses/lgpl.html.
+**
+** GNU General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU
+** General Public License version 2.0 or later as published by the Free
+** Software Foundation and appearing in the file LICENSE.GPL included in
+** the packaging of this file. Please review the following information to
+** ensure the GNU General Public License version 2.0 requirements will be
+** met: http://www.gnu.org/licenses/gpl-2.0.html.
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+import Qt3D 2.0
+import Qt3D.Renderer 2.0
+
+Material {
+    id: root
+    property Texture2D texture: Texture2D {}
+    property alias textureOffset: texCoordOffset.offset
+
+    ShaderProgram {
+        id: gl3Shader
+        vertexShaderCode: loadSource("qrc:/shaders/gl3/unlittexture.vert")
+        fragmentShaderCode: loadSource("qrc:/shaders/gl3/unlittexture.frag")
+    }
+
+    ShaderProgram {
+        id: gl2es2Shader
+        vertexShaderCode: loadSource("qrc:/shaders/es2/unlittexture.vert")
+        fragmentShaderCode: loadSource("qrc:/shaders/es2/unlittexture.frag")
+    }
+
+    effect: Effect {
+        parameters: [
+            Parameter {
+                name: "diffuseTexture"
+                value: root.texture
+            },
+            Parameter {
+                id: texCoordOffset
+                property vector2d offset: Qt.vector2d(0, 0)
+                name: "texCoordOffset"
+                value: offset
+            }
+
+        ]
+
+        techniques: [
+            // OpenGL 3.1
+            Technique {
+                openGLFilter {
+                    api: OpenGLFilter.Desktop
+                    profile: OpenGLFilter.Core
+                    majorVersion: 3
+                    minorVersion: 1
+                }
+                renderPasses: RenderPass {
+                    shaderProgram: gl3Shader
+                }
+            },
+
+            // GL 2 Technique
+            Technique {
+                openGLFilter {
+                    api: OpenGLFilter.Desktop
+                    majorVersion: 2
+                    minorVersion: 0
+                }
+                renderPasses: RenderPass {
+                    shaderProgram: gl2es2Shader
+                }
+            },
+
+            // ES 2 Technique
+            Technique {
+                openGLFilter {
+                    api: OpenGLFilter.ES
+                    profile: OpenGLFilter.None
+                    majorVersion: 2
+                    minorVersion: 0
+                }
+                renderPasses: RenderPass {
+                    shaderProgram: gl2es2Shader
+                }
+            }
+        ]
+    }
+}
diff --git a/src/quick3d/imports/render/qt3dquick3drendererplugin.cpp b/src/quick3d/imports/render/qt3dquick3drendererplugin.cpp
index bb01333f8..d9c2dff3a 100644
--- a/src/quick3d/imports/render/qt3dquick3drendererplugin.cpp
+++ b/src/quick3d/imports/render/qt3dquick3drendererplugin.cpp
@@ -130,6 +130,7 @@ static const struct {
     { "NormalDiffuseSpecularMapMaterial", 2, 0 },
     { "PerVertexColorMaterial", 2, 0 },
     { "GoochMaterial", 2, 0 },
+    { "TextureMaterial", 2, 0 },
     // FrameGraphs
     { "ForwardRenderer", 2, 0 },
     // Entities
diff --git a/src/render/render.qrc b/src/render/render.qrc
index 0675f9662..2cd716dad 100644
--- a/src/render/render.qrc
+++ b/src/render/render.qrc
@@ -57,5 +57,9 @@
         <file>shaders/gl3/phongalpha.vert</file>
         <file>shaders/es2/phongalpha.frag</file>
         <file>shaders/es2/phongalpha.vert</file>
+        <file>shaders/gl3/unlittexture.vert</file>
+        <file>shaders/gl3/unlittexture.frag</file>
+        <file>shaders/es2/unlittexture.frag</file>
+        <file>shaders/es2/unlittexture.vert</file>
     </qresource>
 </RCC>
diff --git a/src/render/shaders/es2/unlittexture.frag b/src/render/shaders/es2/unlittexture.frag
new file mode 100644
index 000000000..66752ed32
--- /dev/null
+++ b/src/render/shaders/es2/unlittexture.frag
@@ -0,0 +1,11 @@
+#define FP highp
+
+uniform sampler2D diffuseTexture;
+
+varying FP vec3 position;
+varying FP vec2 texCoord;
+
+void main()
+{
+    gl_FragColor = texture2D( diffuseTexture, texCoord );
+}
diff --git a/src/render/shaders/es2/unlittexture.vert b/src/render/shaders/es2/unlittexture.vert
new file mode 100644
index 000000000..050b2b7e2
--- /dev/null
+++ b/src/render/shaders/es2/unlittexture.vert
@@ -0,0 +1,17 @@
+attribute vec3 vertexPosition;
+attribute vec2 vertexTexCoord;
+
+varying vec3 position;
+varying vec2 texCoord;
+
+uniform mat4 modelView;
+uniform mat4 mvp;
+uniform vec2 texCoordOffset;
+
+void main()
+{
+    texCoord = vertexTexCoord + texCoordOffset;
+    position = vec3( modelView * vec4( vertexPosition, 1.0 ) );
+
+    gl_Position = mvp * vec4( vertexPosition, 1.0 );
+}
diff --git a/src/render/shaders/gl3/unlittexture.frag b/src/render/shaders/gl3/unlittexture.frag
new file mode 100644
index 000000000..8abbeee8f
--- /dev/null
+++ b/src/render/shaders/gl3/unlittexture.frag
@@ -0,0 +1,13 @@
+#version 150 core
+
+uniform sampler2D diffuseTexture;
+
+in vec3 position;
+in vec2 texCoord;
+
+out vec4 fragColor;
+
+void main()
+{
+    fragColor = texture( diffuseTexture, texCoord );
+}
diff --git a/src/render/shaders/gl3/unlittexture.vert b/src/render/shaders/gl3/unlittexture.vert
new file mode 100644
index 000000000..4aaa10a8f
--- /dev/null
+++ b/src/render/shaders/gl3/unlittexture.vert
@@ -0,0 +1,19 @@
+#version 150 core
+
+in vec3 vertexPosition;
+in vec2 vertexTexCoord;
+
+out vec3 position;
+out vec2 texCoord;
+
+uniform mat4 modelView;
+uniform mat4 mvp;
+uniform vec2 texCoordOffset;
+
+void main()
+{
+    texCoord = vertexTexCoord + texCoordOffset;
+    position = vec3( modelView * vec4( vertexPosition, 1.0 ) );
+
+    gl_Position = mvp * vec4( vertexPosition, 1.0 );
+}