blob: b8c7535ac2112e11e3163e1ca8608d298c329654 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
#version 150 core
// TODO: Replace with a uniform block
uniform vec4 lightPosition;
uniform vec3 lightIntensity;
// TODO: Replace with a struct
uniform vec3 ka; // Ambient reflectivity
uniform float shininess; // Specular shininess factor
uniform sampler2D diffuseTexture;
uniform sampler2D specularTexture;
in vec3 position;
in vec3 normal;
in vec2 texCoord;
out vec4 fragColor;
vec3 adsModel( const in vec3 pos, const in vec3 n )
{
// Calculate the vector from the light to the fragment
vec3 s = normalize( vec3( lightPosition ) - pos );
// Calculate the vector from the fragment to the eye position
// (origin since this is in "eye" or "camera" space)
vec3 v = normalize( -pos );
// Reflect the light beam using the normal at this fragment
vec3 r = reflect( -s, n );
// Calculate the diffuse component
float diffuse = max( dot( s, n ), 0.0 );
// Calculate the specular component
float specular = 0.0;
if ( dot( s, n ) > 0.0 )
specular = ( shininess / ( 8.0 * 3.14 ) ) * pow( max( dot( r, v ), 0.0 ), shininess );
// Lookup diffuse and specular factors
vec3 diffuseColor = texture( diffuseTexture, texCoord ).rgb;
vec3 specularColor = texture( specularTexture, texCoord ).rgb;
// Combine the ambient, diffuse and specular contributions
return lightIntensity * ( ( ka + diffuse ) * diffuseColor + specular * specularColor );
}
void main()
{
fragColor = vec4( adsModel( position, normalize( normal ) ), 1.0 );
}
|