1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
load(qt_build_config)
MODULE_VERSION = 5.12.0
SOURCE_DIR=$$PWD
BUILD_DIR=$$shadowed($$PWD)
QMAKEFEATURES=$$SOURCE_DIR/qmake-features
# Load the am-coverage feature in every pro file
# This makes sure we compile everything with coverage data
# when the coverage target gets executed
!win32: CONFIG += am-coverage
# Qt 5.9 is still missing this function, so we inject it here
# TODO: remove this once 5.9 is not relevant anymore
!defined(versionAtLeast, test): {
defineTest(versionAtLeast) {
LEFT_VERSION = $$eval($$1)
LEFT_VERSION_MAJOR = $$section(LEFT_VERSION, ., 0, 0)
LEFT_VERSION_MINOR = $$section(LEFT_VERSION, ., 1, 1)
LEFT_VERSION_PATCH = $$section(LEFT_VERSION, ., 2, 2)
RIGHT_VERSION = $$2
RIGHT_VERSION_MAJOR = $$section(RIGHT_VERSION, ., 0, 0)
RIGHT_VERSION_MINOR = $$section(RIGHT_VERSION, ., 1, 1)
RIGHT_VERSION_PATCH = $$section(RIGHT_VERSION, ., 2, 2)
greaterThan(LEFT_VERSION_MAJOR, $$RIGHT_VERSION_MAJOR) {
return(true)
} else:equals(LEFT_VERSION_MAJOR, $$RIGHT_VERSION_MAJOR):greaterThan(LEFT_VERSION_MINOR, $$RIGHT_VERSION_MINOR) {
return(true)
} else:equals(LEFT_VERSION_MAJOR, $$RIGHT_VERSION_MAJOR):equals(LEFT_VERSION_MINOR, $$RIGHT_VERSION_MINOR):!lessThan(LEFT_VERSION_PATCH, $$RIGHT_VERSION_PATCH) {
return(true)
}
return(false)
}
}
|