blob: ed98d0ad2d08526f378c97f699e0a4eab867b8cf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
TEMPLATE = lib
TARGET = QtAppManCommon
MODULE = appman_common
load(am-config)
QT = core core-private network concurrent
qtHaveModule(geniviextras):QT *= geniviextras
android:QT *= androidextras
qtHaveModule(dbus):QT *= dbus
qtHaveModule(qml):QT *= qml qml-private
linux:LIBS += -ldl
versionAtLeast(QT.geniviextras.VERSION, 1.1.0) {
DEFINES += AM_GENIVIEXTRAS_LAZY_INIT
}
CONFIG *= static internal_module
CONFIG -= create_cmake
include($$SOURCE_DIR/3rdparty/libyaml.pri)
contains(DEFINES, "AM_USE_LIBBACKTRACE"):include($$SOURCE_DIR/3rdparty/libbacktrace.pri)
contains(DEFINES, "AM_USE_STACKWALKER"):include($$SOURCE_DIR/3rdparty/stackwalker.pri)
SOURCES += \
exception.cpp \
utilities.cpp \
qtyaml.cpp \
startuptimer.cpp \
unixsignalhandler.cpp \
processtitle.cpp \
crashhandler.cpp \
logging.cpp \
dbus-utilities.cpp \
configcache.cpp
qtHaveModule(qml):SOURCES += \
qml-utilities.cpp \
HEADERS += \
global.h \
error.h \
exception.h \
utilities.h \
qtyaml.h \
startuptimer.h \
unixsignalhandler.h \
processtitle.h \
crashhandler.h \
logging.h \
configcache.h \
configcache_p.h
qtHaveModule(qml):HEADERS += \
qml-utilities.h \
qtHaveModule(dbus):HEADERS += \
dbus-utilities.h \
load(qt_module)
|