Initial import from the monolithic Qt.

This is the beginning of revision history for this module. If you
want to look at revision history older than this, please refer to the
Qt Git wiki for how to use Git history grafting. At the time of
writing, this wiki is located here:

http://qt.gitorious.org/qt/pages/GitIntroductionWithQt

If you have already performed the grafting and you don't see any
history beyond this commit, try running "git log" with the "--follow"
argument.

Branched from the monolithic repo, Qt master branch, at commit
896db169ea224deb96c59ce8af800d019de63f12

1 files changed, 48 insertions, 0 deletions

diff --git a/src/corelib/corelib.pro b/src/corelib/corelib.pro
new file mode 100644
index 0000000000..58d2c7b2c6
--- /dev/null
+++ b/src/corelib/corelib.pro
@@ -0,0 +1,48 @@
+TARGET	   = QtCore
+QPRO_PWD   = $$PWD
+QT         =
+DEFINES   += QT_BUILD_CORE_LIB QT_NO_USING_NAMESPACE
+win32-msvc*|win32-icc:QMAKE_LFLAGS += /BASE:0x67000000
+irix-cc*:QMAKE_CXXFLAGS += -no_prelink -ptused
+
+include(../qbase.pri)
+include(animation/animation.pri)
+include(arch/arch.pri)
+include(concurrent/concurrent.pri)
+include(global/global.pri)
+include(thread/thread.pri)
+include(tools/tools.pri)
+include(io/io.pri)
+include(plugin/plugin.pri)
+include(kernel/kernel.pri)
+include(codecs/codecs.pri)
+include(statemachine/statemachine.pri)
+include(xml/xml.pri)
+
+!qpa:mac|darwin:LIBS_PRIVATE += -framework ApplicationServices
+qpa {
+    contains(QT_CONFIG, coreservices) {
+        LIBS_PRIVATE += -framework CoreServices
+    }
+} else:mac|darwin {
+        LIBS_PRIVATE += -framework CoreFoundation
+}
+mac:lib_bundle:DEFINES += QT_NO_DEBUG_PLUGIN_CHECK
+win32:DEFINES-=QT_NO_CAST_TO_ASCII
+
+QMAKE_LIBS += $$QMAKE_LIBS_CORE
+
+QMAKE_DYNAMIC_LIST_FILE = $$PWD/QtCore.dynlist
+
+contains(DEFINES,QT_EVAL):include(eval.pri)
+
+symbian: {
+    TARGET.UID3=0x2001B2DC
+
+    # Problems using data exports from this DLL mean that we can't page it on releases that don't support
+    # data exports (currently that's any release before Symbian^3)
+    pagingBlock = "$${LITERAL_HASH}ifndef SYMBIAN_DLL_DATA_EXPORTS_SUPPORTED" \
+                  "UNPAGED" \
+                  "$${LITERAL_HASH}endif"
+    MMP_RULES += pagingBlock
+}