Separate out the time, zone, date code from corelib/tools/

We'll be adding calendar code here as well, and tools/ was getting
rather crowded, so it looks like time to move out a reasonably
coherent sub-bundle of it all.

Change-Id: I7e8030f38c31aa307f519dd918a43fc44baa6aa1
Reviewed-by: Lars Knoll <lars.knoll@qt.io>
 
 

1 files changed, 34 insertions, 0 deletions

diff --git a/src/corelib/time/time.pri b/src/corelib/time/time.pri
new file mode 100644
index 0000000000..bacb7e875d
--- /dev/null
+++ b/src/corelib/time/time.pri
@@ -0,0 +1,34 @@
+# Qt time / date / zone / calendar module
+
+HEADERS += \
+        time/qdatetime.h \
+        time/qdatetime_p.h
+
+SOURCES += time/qdatetime.cpp
+
+qtConfig(timezone) {
+    HEADERS += \
+        time/qtimezone.h \
+        time/qtimezoneprivate_p.h \
+        time/qtimezoneprivate_data_p.h
+    SOURCES += \
+        time/qtimezone.cpp \
+        time/qtimezoneprivate.cpp
+    !nacl:darwin: {
+        SOURCES += time/qtimezoneprivate_mac.mm
+    } else: android:!android-embedded: {
+        SOURCES += time/qtimezoneprivate_android.cpp
+    } else: unix: {
+        SOURCES += time/qtimezoneprivate_tz.cpp
+        qtConfig(icu): SOURCES += time/qtimezoneprivate_icu.cpp
+    } else: qtConfig(icu): {
+        SOURCES += time/qtimezoneprivate_icu.cpp
+    } else: win32: {
+        SOURCES += time/qtimezoneprivate_win.cpp
+    }
+}
+
+qtConfig(datetimeparser) {
+    HEADERS += time/qdatetimeparser_p.h
+    SOURCES += time/qdatetimeparser.cpp
+}