Convert features.localserver to QT_[REQUIRE_]CONFIG

Move all the logic into socket.pri and clean-up source
code. Build local socket/server only if feature 'localserver'
was enabled.

Task-number: QTBUG-61672
Change-Id: I9f9d1a262df4bb020c8706c7cb5a66b926e0240f
Reviewed-by: Oswald Buddenhagen <oswald.buddenhagen@qt.io>

1 files changed, 25 insertions, 31 deletions

diff --git a/src/network/socket/socket.pri b/src/network/socket/socket.pri
index 18a8153f56..b2ee1a8054 100644
--- a/src/network/socket/socket.pri
+++ b/src/network/socket/socket.pri
@@ -8,10 +8,6 @@ HEADERS += socket/qabstractsocketengine_p.h \
            socket/qudpsocket.h \
            socket/qtcpserver.h \
            socket/qtcpsocket_p.h \
-           socket/qlocalserver.h \
-           socket/qlocalserver_p.h \
-           socket/qlocalsocket.h \
-           socket/qlocalsocket_p.h \
            socket/qtcpserver_p.h
 
 SOURCES += socket/qabstractsocketengine.cpp \
@@ -19,9 +15,7 @@ SOURCES += socket/qabstractsocketengine.cpp \
            socket/qabstractsocket.cpp \
            socket/qtcpsocket.cpp \
            socket/qudpsocket.cpp \
-           socket/qtcpserver.cpp \
-           socket/qlocalsocket.cpp \
-           socket/qlocalserver.cpp
+           socket/qtcpserver.cpp
 
 # SOCK5 support.
 
@@ -49,42 +43,42 @@ qtConfig(sctp) {
     HEADERS += socket/qnativesocketengine_p.h
 }
 
-unix: {
-    SOURCES += socket/qnativesocketengine_unix.cpp \
-                socket/qlocalsocket_unix.cpp \
-                socket/qlocalserver_unix.cpp
+unix {
+    SOURCES += socket/qnativesocketengine_unix.cpp
+    HEADERS += socket/qnet_unix_p.h
 }
 
-unix:HEADERS += \
-                socket/qnet_unix_p.h
-
 # Suppress deprecation warnings with moc because MS headers have
 # invalid C/C++ code otherwise.
 msvc: QMAKE_MOC_OPTIONS += -D_WINSOCK_DEPRECATED_NO_WARNINGS
 
-win32:!winrt:SOURCES += socket/qnativesocketengine_win.cpp \
-                socket/qlocalsocket_win.cpp \
-                socket/qlocalserver_win.cpp
-
+win32:!winrt:SOURCES += socket/qnativesocketengine_win.cpp
 win32:!winrt:LIBS_PRIVATE += -ladvapi32
 
 winrt {
-    SOURCES += socket/qnativesocketengine_winrt.cpp \
-               socket/qlocalsocket_tcp.cpp \
-               socket/qlocalserver_tcp.cpp
+    SOURCES += socket/qnativesocketengine_winrt.cpp
     HEADERS += socket/qnativesocketengine_winrt_p.h
-
-    DEFINES += QT_LOCALSOCKET_TCP
 }
 
-integrity: {
-    SOURCES -= socket/qlocalsocket_unix.cpp \
-               socket/qlocalserver_unix.cpp
-    SOURCES += socket/qlocalsocket_tcp.cpp \
-               socket/qlocalserver_tcp.cpp \
-	       socket/qnativesocketengine_unix.cpp
-
-    DEFINES += QT_LOCALSOCKET_TCP
+qtConfig(localserver) {
+    HEADERS += socket/qlocalserver.h \
+               socket/qlocalserver_p.h \
+               socket/qlocalsocket.h \
+               socket/qlocalsocket_p.h
+    SOURCES += socket/qlocalsocket.cpp \
+               socket/qlocalserver.cpp
+
+    intergrity|winrt {
+        SOURCES += socket/qlocalsocket_tcp.cpp \
+                   socket/qlocalserver_tcp.cpp
+        DEFINES += QT_LOCALSOCKET_TCP
+    } else: unix {
+        SOURCES += socket/qlocalsocket_unix.cpp \
+                   socket/qlocalserver_unix.cpp
+    } else: win32 {
+        SOURCES += socket/qlocalsocket_win.cpp \
+                   socket/qlocalserver_win.cpp
+    }
 }
 
 qtConfig(system-proxies) {