Add configure option to minimize xcb runtime dependencies

Some of the xcb- libraries we depend upon are not (yet) common across
distributions. This is problematic for binaries that should be working
on different distributions. The patch mitigates this by:

Adding the files from
  libxcb-proto (version 0.1.6), compiled with libxcb-1.5
  xcb-util (version 0.3.9)
  xcb-util-image (version 0.3.9)
  xcb-util-keysyms (version 0.3.9)
  xcb-util-renderutil (version 0.3.8)
  xcb-util-wm (version 0.3.9)

from xcb.freedesktop.org/dist to src/3rdparty/xcb.

Adding a configure option '-qt-xcb' to use the sources instead of
linking to the respective runtime libraries.

Task-number: QTBUG-27803
Change-Id: I6ea87daa382871b2b9072a601511523fa0b9f44b
Reviewed-by: Samuel Rødal <samuel.rodal@digia.com>

1 files changed, 117 insertions, 0 deletions

diff --git a/src/plugins/platforms/xcb/xcb-plugin.pro b/src/plugins/platforms/xcb/xcb-plugin.pro
new file mode 100644
index 0000000000..b7b5650eea
--- /dev/null
+++ b/src/plugins/platforms/xcb/xcb-plugin.pro
@@ -0,0 +1,117 @@
+TARGET = xcb
+
+PLUGIN_TYPE = platforms
+load(qt_plugin)
+
+QT += core-private gui-private platformsupport-private
+
+
+SOURCES = \
+        qxcbclipboard.cpp \
+        qxcbconnection.cpp \
+        qxcbintegration.cpp \
+        qxcbkeyboard.cpp \
+        qxcbmime.cpp \
+        qxcbdrag.cpp \
+        qxcbscreen.cpp \
+        qxcbwindow.cpp \
+        qxcbbackingstore.cpp \
+        qxcbwmsupport.cpp \
+        main.cpp \
+        qxcbnativeinterface.cpp \
+        qxcbcursor.cpp \
+        qxcbimage.cpp \
+        qxlibconvenience.cpp
+
+HEADERS = \
+        qxcbclipboard.h \
+        qxcbconnection.h \
+        qxcbintegration.h \
+        qxcbkeyboard.h \
+        qxcbdrag.h \
+        qxcbmime.h \
+        qxcbobject.h \
+        qxcbscreen.h \
+        qxcbwindow.h \
+        qxcbbackingstore.h \
+        qxcbwmsupport.h \
+        qxcbnativeinterface.h \
+        qxcbcursor.h \
+        qxcbimage.h \
+        qxlibconvenience.h
+
+LIBS += -ldl
+
+# needed by GLX, Xcursor, XLookupString, ...
+contains(QT_CONFIG, xcb-xlib) {
+    DEFINES += XCB_USE_XLIB
+    LIBS += -lX11 -lX11-xcb
+
+    *-maemo* {
+        contains(QT_CONFIG, xinput2) {
+            # XInput2 support for Harmattan.
+            DEFINES += XCB_USE_XINPUT2_MAEMO
+            SOURCES += qxcbconnection_maemo.cpp
+            LIBS += -lXi
+        }
+        DEFINES += XCB_USE_MAEMO_WINDOW_PROPERTIES
+    } else {
+        contains(QT_CONFIG, xinput2) {
+            DEFINES += XCB_USE_XINPUT2
+            SOURCES += qxcbconnection_xi2.cpp
+            LIBS += -lXi
+        }
+    }
+}
+
+# to support custom cursors with depth > 1
+contains(QT_CONFIG, xcb-render) {
+    DEFINES += XCB_USE_RENDER
+    LIBS += -lxcb-render -lxcb-render-util -lXrender
+}
+
+contains(QT_CONFIG, opengl) {
+    contains(QT_CONFIG, opengles2) {
+        DEFINES += XCB_USE_EGL
+        LIBS += -lEGL
+        HEADERS += qxcbeglsurface.h
+
+        # EGL on MeeGo 1.2 Harmattan needs this macro to map EGLNativeDisplayType
+        # and other types to the correct X11 types
+        DEFINES += SUPPORT_X11
+    } else:contains(QT_CONFIG, xcb-xlib) {
+        DEFINES += XCB_USE_GLX
+        HEADERS += qglxintegration.h
+        SOURCES += qglxintegration.cpp
+        LIBS += $$QMAKE_LIBS_DYNLOAD
+        contains(QT_CONFIG, xcb-glx) {
+            DEFINES += XCB_HAS_XCB_GLX
+            LIBS += -lxcb-glx
+        }
+    }
+}
+
+DEFINES += $$QMAKE_DEFINES_XCB
+LIBS += $$QMAKE_LIBS_XCB
+QMAKE_CXXFLAGS += $$QMAKE_CFLAGS_XCB
+
+CONFIG += qpa/genericunixfontdatabase
+
+contains(QT_CONFIG, dbus) {
+DEFINES += XCB_USE_IBUS
+QT += dbus
+LIBS += -ldbus-1
+}
+
+OTHER_FILES += xcb.json README
+
+contains(QT_CONFIG, xcb-qt) {
+    DEFINES += XCB_USE_RENDER
+    XCB_DIR = ../../../3rdparty/xcb
+    INCLUDEPATH += $$XCB_DIR/include $$XCB_DIR/sysinclude
+    LIBS += -lxcb -L ./xcb-static -l xcb-static
+} else {
+    LIBS += -lxcb -lxcb-image -lxcb-keysyms -lxcb-icccm -lxcb-sync -lxcb-xfixes -lxcb-shm -lxcb-randr
+    !contains(DEFINES, QT_NO_SHAPE):LIBS += -lxcb-shape
+}
+