Re-order the sub-dirs to catch real culprits before things they break

A failure in testlib is apt to imply misleading failures elsewhere, so
catch those first. Likewise, broken tools or corelib break
everything. Put the rest of the list in alphabetic order.

Restructure auto.pro to use conditional SUBDIRS += (in the right
order) instead of setting SUBDIRS to a full list and then doing
conditional SUBDIRS -= for most entries. This more closely matches the
way the generated cmake config does things, although it still doesn't
regenerate cleanly.

Change-Id: Idc15326c3534eb4fdce55394269f2dfbc17fcd99
Reviewed-by: Alexandru Croitor <alexandru.croitor@qt.io>

1 files changed, 28 insertions, 40 deletions

diff --git a/tests/auto/auto.pro b/tests/auto/auto.pro
index c9d1da8649..04725c16b5 100644
--- a/tests/auto/auto.pro
+++ b/tests/auto/auto.pro
@@ -4,51 +4,39 @@ TEMPLATE = subdirs
 # b88acae7a8e773c307e44f84da037d01d19e60f7 in qt5.
 boot2qt:qtConfig(private_tests): return()
 
-SUBDIRS += \
-    corelib \
-    dbus \
-    gui \
-    network \
-    opengl \
-    sql \
-    testlib \
-    tools \
-    xml \
-    concurrent \
-    other \
-    widgets \
-    printsupport \
-    cmake \
-    installed_cmake
-
-installed_cmake.depends = cmake
-
-uikit: SUBDIRS  = corelib gui
-
-cross_compile:                              SUBDIRS -= tools cmake installed_cmake
-else:!qtConfig(process):                    SUBDIRS -= tools
-winrt|!qtHaveModule(opengl):                SUBDIRS -= opengl
-!qtHaveModule(gui):                         SUBDIRS -= gui
-!qtHaveModule(widgets):                     SUBDIRS -= widgets
-!qtHaveModule(printsupport):                SUBDIRS -= printsupport
-!qtHaveModule(concurrent):                  SUBDIRS -= concurrent
-winrt|!qtHaveModule(network):               SUBDIRS -= network
-!qtHaveModule(dbus):                        SUBDIRS -= dbus
-!qtHaveModule(xml):                         SUBDIRS -= xml
-!qtHaveModule(sql):                         SUBDIRS -= sql
+uikit {
+    SUBDIRS = corelib
+    qtHaveModule(gui): SUBDIRS += gui
+    return()
+}
 
-# Disable the QtDBus tests if we can't connect to the session bus
-!cross_compile:qtHaveModule(dbus) {
-    !system("dbus-send --session --type=signal / local.AutotestCheck.Hello >$$QMAKE_SYSTEM_NULL_DEVICE 2>&1") {
+# Order by dependency [*], then alphabetic. [*] If bugs in part A of
+# our source would break tests of part B, then test A before B.
+SUBDIRS += testlib
+qtConfig(process):!cross_compile: SUBDIRS += tools
+SUBDIRS += corelib
+!cross_compile: SUBDIRS += cmake
+qtHaveModule(concurrent): SUBDIRS += concurrent
+# QTBUG-63915: boot2qt fails dbus
+qtHaveModule(dbus):!cross_compile:!boot2qt {
+    # Disable the QtDBus tests if we can't connect to the session bus
+    system("dbus-send --session --type=signal / local.AutotestCheck.Hello >$$QMAKE_SYSTEM_NULL_DEVICE 2>&1") {
+        SUBDIRS += dbus
+    } else {
         qtConfig(dbus-linked): \
             error("QtDBus is enabled but session bus is not available. Please check the installation.")
         else: \
             warning("QtDBus is enabled with runtime support, but session bus is not available. Skipping QtDBus tests.")
-        SUBDIRS -= dbus
     }
 }
+qtHaveModule(gui): SUBDIRS += gui
+qtHaveModule(network):!winrt: SUBDIRS += network
+qtHaveModule(opengl):!winrt: SUBDIRS += opengl
+qtHaveModule(printsupport): SUBDIRS += printsupport
+qtHaveModule(sql): SUBDIRS += sql
+qtHaveModule(widgets): SUBDIRS += widgets
+qtHaveModule(xml): SUBDIRS += xml
+!cross_compile: SUBDIRS += installed_cmake
+SUBDIRS += other
 
-# QTBUG-63915
-boot2qt: {
-    SUBDIRS -= dbus
-}
+installed_cmake.depends = cmake