2 files changed, 63 insertions, 28 deletions

diff --git a/src/gui/painting/qcoregraphics.mm b/src/gui/painting/qcoregraphics.mm
index e2497eaadb..94ba004c93 100644
--- a/src/gui/painting/qcoregraphics.mm
+++ b/src/gui/painting/qcoregraphics.mm
@@ -47,6 +47,8 @@
 #include <QtCore/qcoreapplication.h>
 #include <QtCore/qoperatingsystemversion.h>
 
+QT_USE_NAMESPACE
+
 QT_BEGIN_NAMESPACE
 
 // ---------------------- Images ----------------------
@@ -124,46 +126,72 @@ QImage qt_mac_toQImage(CGImageRef image)
 
 #ifdef Q_OS_MACOS
 
-static NSImage *qt_mac_cgimage_to_nsimage(CGImageRef image)
+QT_END_NAMESPACE
+
+@implementation NSImage (QtExtras)
++ (instancetype)imageFromQImage:(const QImage &)image
 {
-    NSImage *newImage = [[NSImage alloc] initWithCGImage:image size:NSZeroSize];
-    return newImage;
+    if (image.isNull())
+        return nil;
+
+    QCFType<CGImageRef> cgImage = image.toCGImage();
+    if (!cgImage)
+        return nil;
+
+    // We set up the NSImage using an explicit NSBitmapImageRep, instead of
+    // [NSImage initWithCGImage:size:], as the former allows us to correctly
+    // set the size of the representation to account for the device pixel
+    // ratio of the original image, which in turn will be reflected by the
+    // NSImage.
+    auto nsImage = [[NSImage alloc] initWithSize:NSZeroSize];
+    auto *imageRep = [[NSBitmapImageRep alloc] initWithCGImage:cgImage];
+    imageRep.size = (image.size() / image.devicePixelRatioF()).toCGSize();
+    [nsImage addRepresentation:[imageRep autorelease]];
+    Q_ASSERT(CGSizeEqualToSize(nsImage.size, imageRep.size));
+
+    return [nsImage autorelease];
 }
 
-NSImage *qt_mac_create_nsimage(const QPixmap &pm)
++ (instancetype)imageFromQIcon:(const QIcon &)icon
 {
-    if (pm.isNull())
-        return 0;
-    QImage image = pm.toImage();
-    CGImageRef cgImage = qt_mac_toCGImage(image);
-    NSImage *nsImage = qt_mac_cgimage_to_nsimage(cgImage);
-    nsImage.size = (pm.size() / pm.devicePixelRatioF()).toCGSize();
-    CGImageRelease(cgImage);
-    return nsImage;
+    return [NSImage imageFromQIcon:icon withSize:0];
 }
 
-NSImage *qt_mac_create_nsimage(const QIcon &icon, int defaultSize)
++ (instancetype)imageFromQIcon:(const QIcon &)icon withSize:(int)size
 {
     if (icon.isNull())
         return nil;
 
-    NSImage *nsImage = [[NSImage alloc] init];
-    QList<QSize> availableSizes = icon.availableSizes();
-    if (availableSizes.isEmpty() && defaultSize > 0)
-        availableSizes << QSize(defaultSize, defaultSize);
+    auto nsImage = [[NSImage alloc] initWithSize:NSZeroSize];
+
+    auto availableSizes = icon.availableSizes();
+    if (availableSizes.isEmpty() && size > 0)
+        availableSizes << QSize(size, size);
+
     for (QSize size : qAsConst(availableSizes)) {
-        QPixmap pm = icon.pixmap(size);
-        if (pm.isNull())
+        QImage image = icon.pixmap(size).toImage();
+        if (image.isNull())
             continue;
-        QImage image = pm.toImage();
-        CGImageRef cgImage = qt_mac_toCGImage(image);
-        NSBitmapImageRep *imageRep = [[NSBitmapImageRep alloc] initWithCGImage:cgImage];
-        [nsImage addRepresentation:imageRep];
-        [imageRep release];
-        CGImageRelease(cgImage);
+
+        QCFType<CGImageRef> cgImage = image.toCGImage();
+        if (!cgImage)
+            continue;
+
+        auto *imageRep = [[NSBitmapImageRep alloc] initWithCGImage:cgImage];
+        imageRep.size = (image.size() / image.devicePixelRatioF()).toCGSize();
+        [nsImage addRepresentation:[imageRep autorelease]];
     }
-    return nsImage;
+
+    [nsImage setTemplate:icon.isMask()];
+
+    if (size)
+        nsImage.size = CGSizeMake(size, size);
+
+    return [nsImage autorelease];
 }
+@end
+
+QT_BEGIN_NAMESPACE
 
 QPixmap qt_mac_toQPixmap(const NSImage *image, const QSizeF &size)
 {
diff --git a/src/gui/painting/qcoregraphics_p.h b/src/gui/painting/qcoregraphics_p.h
index ba2cde8325..db012d3cda 100644
--- a/src/gui/painting/qcoregraphics_p.h
+++ b/src/gui/painting/qcoregraphics_p.h
@@ -69,9 +69,16 @@ QT_BEGIN_NAMESPACE
 Q_GUI_EXPORT CGBitmapInfo qt_mac_bitmapInfoForImage(const QImage &image);
 
 #ifdef HAVE_APPKIT
-Q_GUI_EXPORT NSImage *qt_mac_create_nsimage(const QPixmap &pm);
-Q_GUI_EXPORT NSImage *qt_mac_create_nsimage(const QIcon &icon, int defaultSize = 0);
 Q_GUI_EXPORT QPixmap qt_mac_toQPixmap(const NSImage *image, const QSizeF &size);
+
+QT_END_NAMESPACE
+@interface NSImage (QtExtras)
++ (instancetype)imageFromQImage:(const QT_PREPEND_NAMESPACE(QImage) &)image;
++ (instancetype)imageFromQIcon:(const QT_PREPEND_NAMESPACE(QIcon) &)icon;
++ (instancetype)imageFromQIcon:(const QT_PREPEND_NAMESPACE(QIcon) &)icon withSize:(int)size;
+@end
+QT_BEGIN_NAMESPACE
+
 #endif
 Q_GUI_EXPORT CGImageRef qt_mac_toCGImage(const QImage &qImage);
 Q_GUI_EXPORT CGImageRef qt_mac_toCGImageMask(const QImage &qImage);