summaryrefslogtreecommitdiffstats
path: root/src/tools/bootstrap
diff options
context:
space:
mode:
Diffstat (limited to 'src/tools/bootstrap')
-rw-r--r--src/tools/bootstrap/bootstrap.pri76
-rw-r--r--src/tools/bootstrap/bootstrap.pro127
2 files changed, 203 insertions, 0 deletions
diff --git a/src/tools/bootstrap/bootstrap.pri b/src/tools/bootstrap/bootstrap.pri
new file mode 100644
index 0000000000..f48c8c12ff
--- /dev/null
+++ b/src/tools/bootstrap/bootstrap.pri
@@ -0,0 +1,76 @@
+CONFIG += console qtinc
+CONFIG -= qt
+build_all:!build_pass {
+ CONFIG -= build_all
+ CONFIG += release
+}
+CONFIG -= app_bundle
+
+DEFINES += \
+ QT_BOOTSTRAPPED \
+ QT_LITE_UNICODE \
+ QT_TEXTCODEC \
+ QT_NO_CAST_FROM_ASCII \
+ QT_NO_CAST_TO_ASCII \
+ QT_NO_CODECS \
+ QT_NO_DATASTREAM \
+ QT_NO_GEOM_VARIANT \
+ QT_NO_LIBRARY \
+ QT_NO_QOBJECT \
+ QT_NO_STL \
+ QT_NO_SYSTEMLOCALE \
+ QT_NO_TEXTSTREAM \
+ QT_NO_THREAD \
+ QT_NO_UNICODETABLES \
+ QT_NO_USING_NAMESPACE \
+ QT_NO_DEPRECATED
+
+win32:DEFINES += QT_NODLL
+
+INCLUDEPATH += $$QT_BUILD_TREE/include \
+ $$QT_BUILD_TREE/include/QtCore \
+ $$QT_BUILD_TREE/include/QtXml \
+ $$QT_SOURCE_TREE/src/xml
+DEPENDPATH += $$INCLUDEPATH \
+ $$QT_SOURCE_TREE/src/corelib/global \
+ $$QT_SOURCE_TREE/src/corelib/kernel \
+ $$QT_SOURCE_TREE/src/corelib/tools \
+ $$QT_SOURCE_TREE/src/corelib/io \
+ $$QT_SOURCE_TREE/src/corelib/codecs \
+ $$QT_SOURCE_TREE/src/xml
+
+hpux-acc*|hpuxi-acc* {
+ LIBS += $$QT_BUILD_TREE/src/tools/bootstrap/libbootstrap.a
+} else {
+ contains(CONFIG, debug_and_release_target) {
+ CONFIG(debug, debug|release) {
+ QMAKE_LIBDIR += $$QT_BUILD_TREE/src/tools/bootstrap/debug
+ } else {
+ QMAKE_LIBDIR += $$QT_BUILD_TREE/src/tools/bootstrap/release
+ }
+ } else {
+ QMAKE_LIBDIR += $$QT_BUILD_TREE/src/tools/bootstrap
+ }
+ LIBS += -lbootstrap
+}
+!contains(QT_CONFIG, zlib):!contains(QT_CONFIG, no-zlib):!cross_compile {
+ symbian:LIBS_PRIVATE += -llibz
+ else:if(unix|win32-g++*):LIBS_PRIVATE += -lz
+ else:LIBS += zdll.lib
+}
+win32:LIBS += -luser32
+
+mac {
+ CONFIG -= incremental
+ LIBS += -framework CoreServices
+}
+
+# Make dummy "sis" and "freeze" target to keep recursive "make sis/freeze" working.
+sis_target.target = sis
+sis_target.commands =
+sis_target.depends = first
+QMAKE_EXTRA_TARGETS += sis_target
+freeze_target.target = freeze
+freeze_target.commands =
+freeze_target.depends = first
+QMAKE_EXTRA_TARGETS += freeze_target
diff --git a/src/tools/bootstrap/bootstrap.pro b/src/tools/bootstrap/bootstrap.pro
new file mode 100644
index 0000000000..50ae2cff16
--- /dev/null
+++ b/src/tools/bootstrap/bootstrap.pro
@@ -0,0 +1,127 @@
+TEMPLATE = lib
+TARGET = bootstrap
+CONFIG += staticlib
+
+CONFIG += console qtinc
+CONFIG -= qt
+build_all:!build_pass {
+ CONFIG -= build_all
+ CONFIG += release
+}
+mac:CONFIG -= app_bundle incremental
+
+DEFINES += \
+ QT_BOOTSTRAPPED \
+ QT_LITE_UNICODE \
+ QT_NO_CAST_FROM_ASCII \
+ QT_NO_CAST_TO_ASCII \
+ QT_NO_CODECS \
+ QT_NO_DATASTREAM \
+ QT_NO_GEOM_VARIANT \
+ QT_NO_LIBRARY \
+ QT_NO_QOBJECT \
+ QT_NO_STL \
+ QT_NO_SYSTEMLOCALE \
+ QT_NO_TEXTSTREAM \
+ QT_NO_THREAD \
+ QT_NO_UNICODETABLES \
+ QT_NO_USING_NAMESPACE \
+ QT_NO_DEPRECATED
+
+win32:DEFINES += QT_NODLL
+
+INCLUDEPATH += $$QT_BUILD_TREE/include \
+ $$QT_BUILD_TREE/include/QtCore \
+ $$QT_BUILD_TREE/include/QtXml
+
+DEPENDPATH += $$INCLUDEPATH \
+ ../../corelib/global \
+ ../../corelib/kernel \
+ ../../corelib/tools \
+ ../../corelib/io \
+ ../../corelib/codecs \
+ ../../xml
+
+SOURCES += \
+ ../../corelib/codecs/qisciicodec.cpp \
+ ../../corelib/codecs/qlatincodec.cpp \
+ ../../corelib/codecs/qsimplecodec.cpp \
+ ../../corelib/codecs/qtextcodec.cpp \
+ ../../corelib/codecs/qtsciicodec.cpp \
+ ../../corelib/codecs/qutfcodec.cpp \
+ ../../corelib/global/qglobal.cpp \
+ ../../corelib/global/qmalloc.cpp \
+ ../../corelib/global/qnumeric.cpp \
+ ../../corelib/io/qabstractfileengine.cpp \
+ ../../corelib/io/qbuffer.cpp \
+ ../../corelib/io/qdatastream.cpp \
+ ../../corelib/io/qdir.cpp \
+ ../../corelib/io/qdiriterator.cpp \
+ ../../corelib/io/qfile.cpp \
+ ../../corelib/io/qfileinfo.cpp \
+ ../../corelib/io/qfilesystementry.cpp \
+ ../../corelib/io/qfilesystemengine.cpp \
+ ../../corelib/io/qfsfileengine.cpp \
+ ../../corelib/io/qfsfileengine_iterator.cpp \
+ ../../corelib/io/qiodevice.cpp \
+ ../../corelib/io/qtemporaryfile.cpp \
+ ../../corelib/io/qtextstream.cpp \
+ ../../corelib/io/qurl.cpp \
+ ../../corelib/kernel/qmetatype.cpp \
+ ../../corelib/kernel/qvariant.cpp \
+ ../../corelib/kernel/qsystemerror.cpp \
+ ../../corelib/tools/qbitarray.cpp \
+ ../../corelib/tools/qbytearray.cpp \
+ ../../corelib/tools/qbytearraymatcher.cpp \
+ ../../corelib/tools/qdatetime.cpp \
+ ../../corelib/tools/qhash.cpp \
+ ../../corelib/tools/qlist.cpp \
+ ../../corelib/tools/qlocale.cpp \
+ ../../corelib/tools/qlocale_tools.cpp \
+ ../../corelib/tools/qmap.cpp \
+ ../../corelib/tools/qregexp.cpp \
+ ../../corelib/tools/qstring.cpp \
+ ../../corelib/tools/qstringlist.cpp \
+ ../../corelib/tools/qvector.cpp \
+ ../../corelib/tools/qvsnprintf.cpp \
+ ../../corelib/xml/qxmlutils.cpp \
+ ../../corelib/xml/qxmlstream.cpp \
+ ../../xml/dom/qdom.cpp \
+ ../../xml/sax/qxml.cpp
+
+unix:SOURCES += ../../corelib/io/qfilesystemengine_unix.cpp \
+ ../../corelib/io/qfilesystemiterator_unix.cpp \
+ ../../corelib/io/qfsfileengine_unix.cpp
+
+win32:SOURCES += ../../corelib/io/qfilesystemengine_win.cpp \
+ ../../corelib/io/qfilesystemiterator_win.cpp \
+ ../../corelib/io/qfsfileengine_win.cpp \
+ ../../corelib/plugin/qsystemlibrary.cpp \
+
+mac: OBJECTIVE_SOURCES += ../../corelib/tools/qlocale_mac.mm
+else:symbian:SOURCES += ../../corelib/tools/qlocale_symbian.cpp
+else:unix:SOURCES += ../../corelib/tools/qlocale_unix.cpp
+else:win32:SOURCES += ../../corelib/tools/qlocale_win.cpp
+
+macx: {
+ QMAKE_MACOSX_DEPLOYMENT_TARGET = 10.4 #enables weak linking for 10.4 (exported)
+ SOURCES += ../../corelib/io/qfilesystemengine_mac.cpp
+ SOURCES += ../../corelib/kernel/qcore_mac.cpp
+ LIBS += -framework CoreServices
+}
+
+if(contains(QT_CONFIG, zlib)|cross_compile):include(../../3rdparty/zlib.pri)
+else:include(../../3rdparty/zlib_dependency.pri)
+
+lib.CONFIG = dummy_install
+INSTALLS += lib
+
+# Make dummy "sis" and "freeze" target to keep recursive "make sis/freeze" working.
+sis_target.target = sis
+sis_target.commands =
+sis_target.depends = first
+QMAKE_EXTRA_TARGETS += sis_target
+freeze_target.target = freeze
+freeze_target.commands =
+freeze_target.depends = first
+QMAKE_EXTRA_TARGETS += freeze_target
generated by cgit v1.2.3 (git 2.25.1) at 2024-05-03 15:26:50 +0000