1 files changed, 37 insertions, 0 deletions
diff --git a/tests/manual/examples/widgets/tools/plugandpaint/app/app.pro b/tests/manual/examples/widgets/tools/plugandpaint/app/app.pro
new file mode 100644
index 0000000000..e5ff02ecf2
--- /dev/null
+++ b/tests/manual/examples/widgets/tools/plugandpaint/app/app.pro
@@ -0,0 +1,37 @@
+#! [0]
+TARGET = plugandpaint
+DESTDIR = ..
+
+QT += widgets
+
+HEADERS        = interfaces.h \
+                 mainwindow.h \
+                 paintarea.h \
+                 plugindialog.h
+SOURCES        = main.cpp \
+                 mainwindow.cpp \
+                 paintarea.cpp \
+                 plugindialog.cpp
+
+LIBS           = -L../plugins
+
+macx-xcode {
+    LIBS += -lpnp_basictools$($${QMAKE_XCODE_LIBRARY_SUFFIX_SETTING})
+} else {
+    android {
+        LIBS += -lpnp_basictools_$${QT_ARCH}
+    } else {
+        LIBS += -lpnp_basictools
+    }
+    if(!debug_and_release|build_pass):CONFIG(debug, debug|release) {
+        mac:LIBS = $$member(LIBS, 0) $$member(LIBS, 1)_debug
+        win32:LIBS = $$member(LIBS, 0) $$member(LIBS, 1)d
+    }
+}
+#! [0]
+
+# install
+target.path = $$[QT_INSTALL_EXAMPLES]/widgets/tools/plugandpaint
+INSTALLS += target
+
+CONFIG += install_ok  # Do not cargo-cult this!