src/3rdparty/gradle/gradle.pro


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32

TEMPLATE = aux
TARGET = dummy # Avoid a conflict with the existing gradle directory
CONFIG -= qt android_install

gradle_files.files = \
    $$PWD/gradlew \
    $$PWD/gradlew.bat \
    $$PWD/gradle.properties
gradle_dirs.files = \
    $$PWD/gradle

gradle_files.path = $$[QT_INSTALL_PREFIX]/src/3rdparty/gradle
gradle_dirs.path = $${gradle_files.path}

INSTALLS += gradle_files gradle_dirs
!prefix_build:!equals(OUT_PWD, $$PWD) {
    # For COPIES to work, files and directory entries need to be separate objects.
    COPIES += gradle_files gradle_dirs
}

!prefix_build:!equals(OUT_PWD, $$PWD) {
    RETURN = $$escape_expand(\\n\\t)
    equals(QMAKE_HOST.os, Windows) {
        RETURN = $$escape_expand(\\r\\n\\t)
    }
    OUT_PATH = $$shell_path($$OUT_PWD)

    QMAKE_POST_LINK += \
        $${QMAKE_COPY} $$shell_path($$PWD/gradlew) $$OUT_PATH $$RETURN \
        $${QMAKE_COPY} $$shell_path($$PWD/gradlew.bat) $$OUT_PATH $$RETURN \
        $${QMAKE_COPY_DIR} $$shell_path($$PWD/gradle) $$OUT_PATH
}