blob: c7d2a2d5aee955ce0173528de229bd33f083d6c9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
include (../config.pri)
INCLUDEPATH += \
$$ANGLE_DIR/src \
$$ANGLE_DIR/include
LIBS = $$QMAKE_LIBS_CORE $$QMAKE_LIBS_GUI
# DirectX is included in the Windows 8 Kit, but everything else requires the DX SDK.
win32-msvc2012 {
FXC = fxc.exe
} else {
DX_DIR = $$(DXSDK_DIR)
isEmpty(DX_DIR) {
error("Cannot determine DirectX SDK location. Please set DXSDK_DIR environment variable.")
}
DXINC_DIR = $${DX_DIR}Include
contains(QT_ARCH, x86_64) {
DXLIB_DIR = $${DX_DIR}Lib\\x64
} else {
DXLIB_DIR = $${DX_DIR}Lib\\x86
}
equals(QMAKE_TARGET.arch, x86_64) {
FXC = \"$${DX_DIR}Utilities\\bin\\x64\\fxc.exe\"
} else {
FXC = \"$${DX_DIR}Utilities\\bin\\x86\\fxc.exe\"
}
msvc {
# Unfortunately MinGW cannot use the DirectX headers from the DX SDK because d3d11shader.h uses
# buffer annotation macros (eg: __out, __in) which are not defined in the MinGW copy of
# specstrings_strict.h
INCLUDEPATH += $$DXINC_DIR
# Similarly we want the MinGW linker to use the import libraries shipped with the compiler
# instead of those from the SDK which cause a crash on startup.
LIBS += -L\"$$DXLIB_DIR\"
}
}
HEADERS += \
$$ANGLE_DIR/src/common/angleutils.h \
$$ANGLE_DIR/src/common/debug.h \
$$ANGLE_DIR/src/common/RefCountObject.h \
$$ANGLE_DIR/src/common/version.h
SOURCES += \
$$ANGLE_DIR/src/common/debug.cpp \
$$ANGLE_DIR/src/common/RefCountObject.cpp
|