blob: 62476008b3791f825b2867a03e50c38faf94c653 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
TEMPLATE = lib
CONFIG += static
TARGET = $$qtLibraryTarget(preprocessor)
include(../../config.pri)
INCLUDEPATH = $$ANGLE_DIR/src/compiler/preprocessor/new
DEFINES += _SECURE_SCL=0
FLEX_SOURCES = \
$$ANGLE_DIR/src/compiler/preprocessor/new/Tokenizer.l
BISON_SOURCES = \
$$ANGLE_DIR/src/compiler/preprocessor/new/ExpressionParser.y
HEADERS += \
$$ANGLE_DIR/src/compiler/preprocessor/new/Diagnostics.h \
$$ANGLE_DIR/src/compiler/preprocessor/new/DirectiveHandler.h \
$$ANGLE_DIR/src/compiler/preprocessor/new/DirectiveParser.h \
$$ANGLE_DIR/src/compiler/preprocessor/new/ExpressionParser.h \
$$ANGLE_DIR/src/compiler/preprocessor/new/Input.h \
$$ANGLE_DIR/src/compiler/preprocessor/new/Lexer.h \
$$ANGLE_DIR/src/compiler/preprocessor/new/Macro.h \
$$ANGLE_DIR/src/compiler/preprocessor/new/MacroExpander.h \
$$ANGLE_DIR/src/compiler/preprocessor/new/numeric_lex.h \
$$ANGLE_DIR/src/compiler/preprocessor/new/pp_utils.h \
$$ANGLE_DIR/src/compiler/preprocessor/new/Preprocessor.h \
$$ANGLE_DIR/src/compiler/preprocessor/new/SourceLocation.h \
$$ANGLE_DIR/src/compiler/preprocessor/new/Token.h \
$$ANGLE_DIR/src/compiler/preprocessor/new/Tokenizer.h
SOURCES += \
$$ANGLE_DIR/src/compiler/preprocessor/new/Diagnostics.cpp \
$$ANGLE_DIR/src/compiler/preprocessor/new/DirectiveHandler.cpp \
$$ANGLE_DIR/src/compiler/preprocessor/new/DirectiveParser.cpp \
$$ANGLE_DIR/src/compiler/preprocessor/new/Input.cpp \
$$ANGLE_DIR/src/compiler/preprocessor/new/Lexer.cpp \
$$ANGLE_DIR/src/compiler/preprocessor/new/Macro.cpp \
$$ANGLE_DIR/src/compiler/preprocessor/new/MacroExpander.cpp \
$$ANGLE_DIR/src/compiler/preprocessor/new/Preprocessor.cpp \
$$ANGLE_DIR/src/compiler/preprocessor/new/Token.cpp
# NOTE: 'win_flex' and 'bison' can be found in qt5/gnuwin32/bin
flex.commands = $$addGnuPath(win_flex) --noline --nounistd --outfile=${QMAKE_FILE_BASE}.cpp ${QMAKE_FILE_NAME}
flex.output = ${QMAKE_FILE_BASE}.cpp
flex.input = FLEX_SOURCES
flex.dependency_type = TYPE_C
flex.variable_out = GENERATED_SOURCES
QMAKE_EXTRA_COMPILERS += flex
bison.commands = $$addGnuPath(bison) --no-lines --skeleton=yacc.c --output=${QMAKE_FILE_BASE}.cpp ${QMAKE_FILE_NAME}
bison.output = ${QMAKE_FILE_BASE}.cpp
bison.input = BISON_SOURCES
bison.dependency_type = TYPE_C
bison.variable_out = GENERATED_SOURCES
QMAKE_EXTRA_COMPILERS += bison
|