blob: d52edb3ad271761ccf2cf4e13eaceecf133ba130 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
# Copyright (C) 2024 The Qt Company Ltd.
# SPDX-License-Identifier: BSD-3-Clause
set(CMAKE_Swift_COMPILER_TARGET arm64-apple-xros)
if($CACHE{CMAKE_OSX_SYSROOT} MATCHES "^[a-z]+simulator$")
set(CMAKE_Swift_COMPILER_TARGET "${CMAKE_Swift_COMPILER_TARGET}-simulator")
endif()
cmake_policy(SET CMP0157 NEW)
enable_language(Swift)
# Verify that we have a new enough compiler
if("${CMAKE_Swift_COMPILER_VERSION}" VERSION_LESS 5.9)
message(FATAL_ERROR "Swift 5.9 required for C++ interoperability")
endif()
get_target_property(QT_CORE_INCLUDES Qt6::Core INTERFACE_INCLUDE_DIRECTORIES)
get_target_property(QT_GUI_INCLUDES Qt6::Gui INTERFACE_INCLUDE_DIRECTORIES)
get_target_property(QT_CORE_PRIVATE_INCLUDES Qt6::CorePrivate INTERFACE_INCLUDE_DIRECTORIES)
get_target_property(QT_GUI_PRIVATE_INCLUDES Qt6::GuiPrivate INTERFACE_INCLUDE_DIRECTORIES)
set(target QIOSIntegrationPluginSwift)
# Swift library
set(SWIFT_SOURCES
"${CMAKE_CURRENT_SOURCE_DIR}/qiosapplication.swift"
)
add_library(${target} STATIC ${SWIFT_SOURCES})
set_target_properties(${target} PROPERTIES
Swift_MODULE_NAME ${target})
target_include_directories(${target} PUBLIC
"${CMAKE_CURRENT_SOURCE_DIR}"
"${QT_CORE_INCLUDES}"
"${QT_GUI_INCLUDES}"
"${QT_CORE_PRIVATE_INCLUDES}"
"${QT_GUI_PRIVATE_INCLUDES}"
)
target_compile_options(${target} PUBLIC
$<$<COMPILE_LANGUAGE:Swift>:-cxx-interoperability-mode=default>
$<$<COMPILE_LANGUAGE:Swift>:-Xcc -std=c++17>)
# Swift to C++ bridging header
set(SWIFT_BRIDGING_HEADER "${CMAKE_CURRENT_BINARY_DIR}/qiosswiftintegration.h")
list(TRANSFORM QT_CORE_INCLUDES PREPEND "-I")
list(TRANSFORM QT_GUI_INCLUDES PREPEND "-I")
list(TRANSFORM QT_CORE_PRIVATE_INCLUDES PREPEND "-I")
list(TRANSFORM QT_GUI_PRIVATE_INCLUDES PREPEND "-I")
add_custom_command(
COMMAND
${CMAKE_Swift_COMPILER} -frontend -typecheck
${SWIFT_SOURCES}
-I ${CMAKE_CURRENT_SOURCE_DIR}
${QT_CORE_INCLUDES}
${QT_GUI_INCLUDES}
${QT_CORE_PRIVATE_INCLUDES}
${QT_GUI_PRIVATE_INCLUDES}
-sdk ${CMAKE_OSX_SYSROOT}
-module-name ${target}
-cxx-interoperability-mode=default
-Xcc -std=c++17
-emit-clang-header-path "${SWIFT_BRIDGING_HEADER}"
-target ${CMAKE_Swift_COMPILER_TARGET}
OUTPUT
"${SWIFT_BRIDGING_HEADER}"
DEPENDS
${SWIFT_SOURCES}
)
set(header_target "${target}Header")
add_custom_target(${header_target}
DEPENDS "${SWIFT_BRIDGING_HEADER}"
)
# Make sure the "'__bridge_transfer' casts have no effect when not using ARC"
# warning doesn't break warnings-are-error builds.
target_compile_options(${target} INTERFACE
-Wno-error=arc-bridge-casts-disallowed-in-nonarc)
add_dependencies(${target} ${header_target})
|