summaryrefslogtreecommitdiffstats
path: root/src/plugins/platforms/ios/qioscontext.mm
blob: 00629a84ab404497e464d140f629fb9b12881398 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
/****************************************************************************
**
** Copyright (C) 2013 Digia Plc and/or its subsidiary(-ies).
** Contact: http://www.qt-project.org/legal
**
** This file is part of the plugins of the Qt Toolkit.
**
** $QT_BEGIN_LICENSE:LGPL$
** Commercial License Usage
** Licensees holding valid commercial Qt licenses may use this file in
** accordance with the commercial license agreement provided with the
** Software or, alternatively, in accordance with the terms contained in
** a written agreement between you and Digia.  For licensing terms and
** conditions see http://qt.digia.com/licensing.  For further information
** use the contact form at http://qt.digia.com/contact-us.
**
** GNU Lesser General Public License Usage
** Alternatively, this file may be used under the terms of the GNU Lesser
** General Public License version 2.1 as published by the Free Software
** Foundation and appearing in the file LICENSE.LGPL included in the
** packaging of this file.  Please review the following information to
** ensure the GNU Lesser General Public License version 2.1 requirements
** will be met: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
**
** In addition, as a special exception, Digia gives you certain additional
** rights.  These rights are described in the Digia Qt LGPL Exception
** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
**
** GNU General Public License Usage
** Alternatively, this file may be used under the terms of the GNU
** General Public License version 3.0 as published by the Free Software
** Foundation and appearing in the file LICENSE.GPL included in the
** packaging of this file.  Please review the following information to
** ensure the GNU General Public License version 3.0 requirements will be
** met: http://www.gnu.org/copyleft/gpl.html.
**
**
** $QT_END_LICENSE$
**
****************************************************************************/

#include "qioscontext.h"
#include "qioswindow.h"

#include <dlfcn.h>

#include <QtGui/QOpenGlContext>

#import <OpenGLES/EAGL.h>
#import <QuartzCore/CAEAGLLayer.h>

QIOSContext::QIOSContext(QOpenGLContext *context)
    : QPlatformOpenGLContext()
    , m_eaglContext([[EAGLContext alloc] initWithAPI:kEAGLRenderingAPIOpenGLES2])
{
    // Start out with the requested format
    QSurfaceFormat format = context->format();

    format.setRenderableType(QSurfaceFormat::OpenGLES);
    format.setMajorVersion(2);
    format.setMinorVersion(0);

    // Even though iOS internally double-buffers its rendering, we
    // report single-buffered here since the buffer remains unchanged
    // when swapping unlesss you manually clear it yourself.
    format.setSwapBehavior(QSurfaceFormat::SingleBuffer);

    m_format = format;
}

QIOSContext::~QIOSContext()
{
    if ([EAGLContext currentContext] == m_eaglContext)
        doneCurrent();

    [m_eaglContext release];
}

QSurfaceFormat QIOSContext::format() const
{
    return m_format;
}

bool QIOSContext::makeCurrent(QPlatformSurface *surface)
{
    Q_ASSERT(surface && surface->surface()->surfaceType() == QSurface::OpenGLSurface);

    [EAGLContext setCurrentContext:m_eaglContext];
    glBindFramebuffer(GL_FRAMEBUFFER, defaultFramebufferObject(surface));

    // Ensures render buffers are set up and match the size of the window
    return defaultColorRenderbuffer(surface) != 0;
}

void QIOSContext::doneCurrent()
{
    [EAGLContext setCurrentContext:nil];
}

void QIOSContext::swapBuffers(QPlatformSurface *surface)
{
    Q_ASSERT(surface && surface->surface()->surfaceType() == QSurface::OpenGLSurface);

    [EAGLContext setCurrentContext:m_eaglContext];
    glBindRenderbuffer(GL_RENDERBUFFER, defaultColorRenderbuffer(surface));
    [m_eaglContext presentRenderbuffer:GL_RENDERBUFFER];
}

GLuint QIOSContext::defaultFramebufferObject(QPlatformSurface *surface) const
{
    return static_cast<QIOSWindow *>(surface)->framebufferObject(*this);
}

GLuint QIOSContext::defaultColorRenderbuffer(QPlatformSurface *surface) const
{
    return static_cast<QIOSWindow *>(surface)->colorRenderbuffer(*this);
}

QFunctionPointer QIOSContext::getProcAddress(const QByteArray& functionName)
{
    return reinterpret_cast<QFunctionPointer>(dlsym(RTLD_NEXT, functionName.constData()));
}

EAGLContext *QIOSContext::nativeContext() const
{
    return m_eaglContext;
}