blob: 41d81b8afc11ff8f915bd5137e66561cbe43ded5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
# Qt dialogs module
HEADERS += \
dialogs/qcolordialog.h \
dialogs/qcolordialog_p.h \
dialogs/qfscompleter_p.h \
dialogs/qdialog.h \
dialogs/qdialog_p.h \
dialogs/qerrormessage.h \
dialogs/qfiledialog.h \
dialogs/qfiledialog_p.h \
dialogs/qfontdialog.h \
dialogs/qfontdialog_p.h \
dialogs/qinputdialog.h \
dialogs/qmessagebox.h \
dialogs/qprogressdialog.h \
dialogs/qsidebar_p.h \
dialogs/qfilesystemmodel.h \
dialogs/qfilesystemmodel_p.h \
dialogs/qfileinfogatherer_p.h \
dialogs/qwizard.h
!qpa:mac {
OBJECTIVE_SOURCES += dialogs/qfiledialog_mac.mm \
dialogs/qfontdialog_mac.mm \
dialogs/qnspanelproxy_mac.mm
# Compile qcolordialog_mac.mm with exception support, disregarding the -no-exceptions
# configure option. (qcolordialog_mac needs to catch exceptions thrown by cocoa)
EXCEPTION_SOURCES = dialogs/qcolordialog_mac.mm
exceptions_compiler.commands = $$QMAKE_CXX -c
exceptions_compiler.commands += $(CXXFLAGS) $(INCPATH) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
exceptions_compiler.commands += -fexceptions
exceptions_compiler.dependency_type = TYPE_C
exceptions_compiler.output = ${QMAKE_VAR_OBJECTS_DIR}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJ)}
exceptions_compiler.input = EXCEPTION_SOURCES
exceptions_compiler.variable_out = OBJECTS
exceptions_compiler.name = compiling[exceptopns] ${QMAKE_FILE_IN}
silent:exceptions_compiler.commands = @echo compiling[exceptopns] ${QMAKE_FILE_IN} && $$exceptions_compiler.commands
QMAKE_EXTRA_COMPILERS += exceptions_compiler
}
win32 {
qpa:DEFINES += QT_NO_PRINTDIALOG
HEADERS += dialogs/qwizard_win_p.h \
dialogs/qfiledialog_win_p.h
SOURCES += dialogs/qdialogsbinarycompat_win.cpp \
dialogs/qfiledialog_win.cpp \
dialogs/qwizard_win.cpp
!win32-borland:!wince*: LIBS += -lshell32 # the filedialog needs this library
}
wince*|symbian: FORMS += dialogs/qfiledialog_embedded.ui
else: FORMS += dialogs/qfiledialog.ui
INCLUDEPATH += $$PWD
SOURCES += \
dialogs/qcolordialog.cpp \
dialogs/qdialog.cpp \
dialogs/qerrormessage.cpp \
dialogs/qfiledialog.cpp \
dialogs/qfontdialog.cpp \
dialogs/qinputdialog.cpp \
dialogs/qmessagebox.cpp \
dialogs/qprogressdialog.cpp \
dialogs/qsidebar.cpp \
dialogs/qfilesystemmodel.cpp \
dialogs/qfileinfogatherer.cpp \
dialogs/qwizard.cpp \
symbian:contains(QT_CONFIG, s60) {
LIBS += -lCommonDialogs
SOURCES += dialogs/qfiledialog_symbian.cpp \
dialogs/qcolordialog_symbian.cpp
}
RESOURCES += dialogs/qmessagebox.qrc
# Compensate for lack of platform defines in Symbian3
symbian: DEFINES += SYMBIAN_VERSION_$$upper($$replace(SYMBIAN_VERSION,\\.,_))
|